Excel/Excel-Seriendokument

Hallo und guten Morgen!
Ich stehe gerade vor einem kleinen Problemchen. Ich habe ein wunderschönes Formular in Excel, was ich mit Daten aus einer anderen Exceltabelle füllen muss. Pro Datensatz werden 4 Zellen (B:E)in das Excelformular geschrieben (A1;B4;D7;F2). Dies benötige ich nur zum Ausdruck. Sollte dies also per VBA einfach umsetzbar sein bin ich dafür natürlich auch offen.
Dann müsste es in "normaler Menschensprache" so aussehen:
Schreibe Zellwert aus Tabelle2!B2 in Tabelle1!A1
Schreibe Zellwert aus Tabelle2!C2 in Tabelle1!B4
Schreibe Zellwert aus Tabelle2!D2 in Tabelle1!D7
Schreibe Zellwert aus Tabelle2!E2 in Tabelle1!F2
Drucke Tabelle1 (1 Blatt) auf dem Standard-Drucker.
Lösche die Werte in Tabelle1 Zellen A1;B4;D7;F2
Schreibe Zellwert aus Tabelle2!B3 in Tabelle1!A1
Schreibe Zellwert aus Tabelle2!C3 in Tabelle1!B4
Schreibe Zellwert aus Tabelle2!D3 in Tabelle1!D7
Schreibe Zellwert aus Tabelle2!E3 in Tabelle1!F2
.
.
.
Da es sich um recht viele Datensätze handelt wäre es händisch etwas schwierig.
Kann mir da jemand kurz helfen? Vielen Dank!

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Martin,
meine Lösung:


Sub Drucken_Datensaetze()
Dim wksData As Worksheet
Dim wksForm As Worksheet
Dim lngData As Long
If MsgBox("Formblatt mit Datensätzen aus Tabelle2 drucken?", vbYesNo) = vbYes Then
Set wksData = Worksheets("Tabelle2") 'Tabelle mit Daten
Set wksForm = Worksheets("Tabelle1") 'zu druckendes Formblatt
With wksData
'Zeilen im Daten-Tabellenblatt abarbeiten
For lngData = 2 To .Cells(.Rows.Count, 1).End(xlUp).Row
wksForm.Range("A1").Value = .Cells(lngData, 2).Value 'Wert aus Spalte B
wksForm.Range("B4").Value = .Cells(lngData, 3).Value 'Wert aus Spalte C
wksForm.Range("D7").Value = .Cells(lngData, 4).Value 'Wert aus Spalte D
wksForm.Range("F2").Value = .Cells(lngData, 5).Value 'Wert aus Spalte E
'      wksForm.PrintPreview
wksForm.PrintOut
Next
End With
'Inhalte der Eintragsfelder im Formblatt löschen
wksForm.Range("A1").ClearContents
wksForm.Range("B4").ClearContents
wksForm.Range("D7").ClearContents
wksForm.Range("F2").ClearContents
MsgBox "Ausdruck fertig"
End If
End Sub

Die Namen der Tabeelnblätter muss du ggf. anpassen.
Gruß
Franz

Beliebteste Forumthreads (12 Monate)

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

299 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Excel/Excel-Seriendokument

2 Beiträge zum Forumthread Beiträge zu diesem Forumthread

299 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread