Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1032to1036
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Bestimmte Werte aus vielen Dateien zusammenfassen

Bestimmte Werte aus vielen Dateien zusammenfassen
12.12.2008 09:29:00
Rene
Hallo!
Ich bin noch ganz frisch hier und hoffe, dass ihr mir evtl weiterhelfen könnt.
Ich habe sehr viele einzelne Excel-Dateien, die alle gleich aufgebaut sind. Daraus muss ich eine Zusammenfassung erstellen.
Die Dateien bestehen aus vielen Tabellen, wovon aber nur Tabelle "2008" abgefragt werden soll. Dort befinden sich Formeln von denen ich die Werte benötige. in den verbundenen Zellen BCD3 der Name, BCD4 Vorname, B-I5 der Ort, I6 die Gehaltsgruppe. Zusätzlich benötige ich noch die Werte aus B10, C10, D10 und E10.
Wenn möglich sollen all diese Werte in eine neuen Tabelle kopiert werden.
Wäre toll, wenn mir jemand helfen könnte!
Grüsse Rene

5
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Bestimmte Werte aus vielen Dateien zusammenfassen
12.12.2008 10:14:00
Tino
Hallo,
versuche es mal mit diesem Code, Pfad wo die Dateien liegen musst Du anpassen, eventuell auch den Dateifilter erweitern.
Modul Modul1
Option Explicit 
 
Sub SucheDatei() 
Dim Fso, Ordner, varDatei 
Dim SucheDatei As String, DateiName As String, strPfad As String 
Dim strFormel As String 
Dim lngRow As Long, A As Long 
 
SucheDatei = ".xls" 'Filter für Dateisuche, hier nur *.xls Dateien 
lngRow = 2 'erste Einfügezeile 
strPfad = "J:\1 Forum\Temp" 'Pfad angeben 
 
Set Fso = CreateObject("Scripting.FileSystemObject") 
Set Ordner = Fso.getfolder(strPfad) 
For Each varDatei In Ordner.Files 
 If varDatei Like "*" & SucheDatei & "*" Then 
    DateiName = Right$(varDatei, Len(varDatei) - InStrRev(varDatei, "\")) 
    DateiName = "'" & Replace(varDatei, DateiName, "[" & DateiName & "]2008'!") 
     
    'BCD3 der Name, BCD4 Vorname, B-I5 der Ort********************** 
    For A = 1 To 3 
        strFormel = DateiName & Cells(2 + A, 2).Address(, , xlR1C1) 
        Cells(lngRow, A) = ExecuteExcel4Macro(strFormel) 
    Next A 
     
    'Wert I6******************************************************** 
    strFormel = DateiName & Range("I6").Address(, , xlR1C1) 
    Cells(lngRow, 4) = ExecuteExcel4Macro(strFormel) 
     
    'Werte aus B10, C10, D10 und E10******************************** 
    For A = 1 To 4 
        strFormel = DateiName & Cells(10, 1 + A).Address(, , xlR1C1) 
        Cells(lngRow, 4 + A) = ExecuteExcel4Macro(strFormel) 
    Next A 
     
    lngRow = lngRow + 1 
  
 End If 
Next varDatei 
 
End Sub 
 


Gruß Tino

Anzeige
AW: Bestimmte Werte aus vielen Dateien zusammenfas
12.12.2008 10:18:21
Rene
Vielen Dank schonmal! Werd es direkt mal ausprobieren :-)
AW: Bestimmte Werte aus vielen Dateien zusammenfas
05.01.2009 14:48:00
Rene
Hallihallo!
Wünsche euch allen erstmal ein frohes neues Jahr!
Der Code den mir Tino bereitgestellt hat funktioniert super! Danke nochmal dafür!!! :-)
Jetzt würde ein Kollege von mir den Code auch gerne benutzten, er hat jedoch seine Dateien in vielen Unterverzeichnissen (A, B, C,...) liegen. Kann ich den Code so abändern, dass Unterverzeichnisse bei der Suche miteinbezogen werden?
Wäre echt klasse wenn mir jemand weiterhelfen könnte!
Viele Grüße
René
AW: Bestimmte Werte aus vielen Dateien zusammenfas
05.01.2009 15:19:30
Tino
Hallo,
teste mal diese Version.
Option Explicit
Dim Liste() As String, iCount As Integer
Sub SucheDatei()
Dim Fso, ordner, varDatei
Dim SucheDatei As String, DateiName As String, strPfad As String
Dim strFormel As String
Dim lngRow As Long, A As Long
Dim i As Integer
 
SucheDatei = ".xls" 'Filter für Dateisuche, hier nur *.xls Dateien 
lngRow = 2 'erste Einfügezeile 
strPfad = "J:\1 Forum" 'Pfad angeben, wo die Unterordner enthalten sind 

'Auch dieser Ordner kann Dateien enthalten 
    Redim Preserve Liste(iCount)
    Liste(iCount) = strPfad
    iCount = iCount + 1

Listordner (strPfad)

Set Fso = CreateObject("Scripting.FileSystemObject")

For i = Lbound(Liste) To Ubound(Liste)
 Set ordner = Fso.getfolder(Liste(i))
    For Each varDatei In ordner.Files
     If varDatei Like "*" & SucheDatei & "*" Then
        DateiName = Right$(varDatei, Len(varDatei) - InStrRev(varDatei, "\"))
        DateiName = "'" & Replace(varDatei, DateiName, "[" & DateiName & "]2008'!")
         
        'BCD3 der Name, BCD4 Vorname, B-I5 der Ort********************** 
        For A = 1 To 3
            strFormel = DateiName & Cells(2 + A, 2).Address(, , xlR1C1)
            Cells(lngRow, A) = ExecuteExcel4Macro(strFormel)
        Next A
         
        'Wert I6******************************************************** 
        strFormel = DateiName & Range("I6").Address(, , xlR1C1)
        Cells(lngRow, 4) = ExecuteExcel4Macro(strFormel)
         
        'Werte aus B10, C10, D10 und E10******************************** 
        For A = 1 To 4
            strFormel = DateiName & Cells(10, 1 + A).Address(, , xlR1C1)
            Cells(lngRow, 4 + A) = ExecuteExcel4Macro(strFormel)
        Next A
         
        lngRow = lngRow + 1
      
     End If
    Next varDatei
 Next i

Erase Liste: iCount = 0

End Sub

Sub Listordner(sPfad As String)
Dim Fso, ordner, UnterOrdner
Set Fso = CreateObject("Scripting.FileSystemObject")
Set ordner = Fso.getfolder(sPfad)
    
    For Each UnterOrdner In ordner.subfolders
        Redim Preserve Liste(iCount)
        Liste(iCount) = UnterOrdner.Path
        iCount = iCount + 1
        Listordner (UnterOrdner)
    Next

End Sub


Gruß Tino

Anzeige
AW: Bestimmte Werte aus vielen Dateien zusammenfas
05.01.2009 16:06:00
Tino
Hallo,
wollte noch hinzufügen, der Beitrag ist im Archiv,
vielleicht wäre es besser einen neuen Beitrag aufzumachen mit einem Link auf diesem.
Sonst bekommt keiner etwas mit und ich bin auch nicht immer da. ;-)
Gruß Tino

299 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige