Formel mit kkleinste

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Jean,
ich habe die Formel etwas abgeändert, jetzt funktioniert sie auch mit dem hinunterziehen.
Den Formelteil "Zeile" habe ich jetzt auch auf die Spalte B geändert und somit passen sich jetzt alle Bereiche durch das Hinunterziehen neu an.
Tabelle1

	A	B	C	D	E	F	G	H
1		Auswahl	Kostennummer
2
3		x	101					gewünschtes
4		x	102					Ergebnis
5			103				101	101
6			104				103	102
7							106	105
8		x	105				202	201
9			106				206	205
10			107

Formeln der Tabelle

Zelle	Formel
G5	{=WENN(SUMME(N(B$1:B$999="x"))<ZEILE(A1); "";INDEX(C:C;KKLEINSTE(WENN(B$1:B$999="x";ZEILE(B$1:B$999)); ZEILE(A1))))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Servus, Walter

Hallo Andreas,
... kann ich versuchen Dir zu geben. Ich glaube aber, dass Walter ein klares Unterstatement abgegeben hat. Wer diese Art Formel nicht verstanden hat, kann sie sie auch kaum selber korrekt anwenden und entsprechend so modifizieren, wie er es Dir und Jean gegenüber getan hat.
Das "Problem" ist lediglich nur, dass man ein Vielfaches der Zeit braucht, um so eine Formel jemanden zu erklären, als diese (wenn man sie verstanden hat) selbst anzuwenden.
Ich versuche Dir deshalb hier nachfolgend auch nur Hilfe zur Selbsthilfe zu geben. Die Formel G5 besteht im Wesentlichen aus zwei Formelhauptteilen. Der Kern davon ist ... INDEX(C:C;KKLEINSTE(WENN(B$1:B$999="x";ZEILE(A$1:A$999)); ZEILE(A1))) während der erste Formelteil: =WENN(SUMME(N(B$1:B$999="x"))... lediglich ein Zusatz um umschöne Fehlerergebnisse (wie sie im nachfolgenden Beipiel ab Zeile 8 entstehen) durch ein "" abzufangen.
Wenn Du den zu untersuchenden Bereich auf nur bis zur Zeile 9 einschränkst und die beiden Formelteile zunächst für sich betrachtest, wird es einfacher, noch dazu wenn Du aus dem Kernformelteil nur wiederum dessen Kern erkennst. (Die Funktion INDEX() bedarf sicherlich keiner zusätzlichen Interpretation meinerseits). Diesen entsprechenden Formelteil hab ich Dir in D5 herausgezogen. Dieser ermittelt für das erste Auftreten x in Spalte B die Zeilennummer (hier die 3) dessen. Wenn Du nun fragst, warum bzw. wie das? Dann markiere mal in der Eingabezeile der Formel den darin befindlichen Formelteil B$1:B$9="x" mit der Taste [F9] . Dadurch erhältst Du die Formel wie in E5. Und wenn Du in D5 den Formelteil WENN(B$1:B$9="x";ZEILE(A$1:A$9)) markierst, bzw. in der Formel E5 den Teil WENN({FALSCH;FALSCH;WAHR;WAHR;FALSCH;FALSCH;FALSCH;WAHR;FALSCH};ZEILE(A$1:A$9)) , dann erhältst die gleiche Formel wie in F5.
Die Formeln D5:F5 durch Ziehen nach unten kopiert ergeben alle Zeilennummern im untersuchten Bereich (ZEILE(A$1:A$9), also Zeile 1 bis 9), wo in Spalte B das x steht. Da in diesem Bereich in Spalte B gemäß Beispiel nur dreimal das x steht, finden diese Kernformel ab Zeile 8 (d.h. ab der 4. Ergebniszelle) excelgemäß kein Zeile(nummer) mehr, was die Formel(n) natürlich mit einer entsprechenden Fehlermeldung quittieren muss(en).
Und genau dies wird mit dem ersten Formelteil abgefangen, weil damit ja die max. Anzahl von x in der Spalte B im untersuchten Bereich gezählt wird (vgl. Formel E1) und durch den Vergleich mit der jeweiligen Ergebniszeilennummer dann eine Ausgabe von = erzwungen wird.
Nun solltest Du Dir noch den Link MATRIX verstehen in aller Ruhe ansehen und dann hast Du eine gewisse Vorstellung wie das ganze funktioniert. Aber nimm Dir Zeit dazu. Das erfasst bzw. erlernt man nicht in wenigen Minuten.

	A	B	C	D	E	F	G
1	Zeilen-Nr.	Auswahl	Nr		3
2
3	3	x	101
4	4	x	102
5	5		103	3	3	3	101
6	6		104	4	4	4	102
7	7			8	8	8	105
8	8	x	105	#ZAHL!	#ZAHL!	#ZAHL!
9	9		106

Formeln der Tabelle

Zelle	Formel
E1	{=SUMME(N(B$1:B$9="x"))}
A3	=ZEILE()
D5	{=KKLEINSTE(WENN(B$1:B$9="x";ZEILE(A$1:A$9)); ZEILE(A1))}
E5	{=KKLEINSTE(WENN({FALSCH;FALSCH;WAHR;WAHR;FALSCH;FALSCH;FALSCH;WAHR;FALSCH};ZEILE(A$1:A$9)); ZEILE(A1))}
F5	{=KKLEINSTE({FALSCH;FALSCH;3;4;FALSCH;FALSCH;FALSCH;8;FALSCH};ZEILE(A1))}
G5	{=WENN(SUMME(N(B$1:B$999="x"))<ZEILE(A1); "";INDEX(C:C;KKLEINSTE(WENN(B$1:B$999="x";ZEILE(A$1:A$999)); ZEILE(A1))))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , -

Beliebteste Forumthreads (12 Monate)

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

300 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Formel mit kkleinste

10 Beiträge zum Forumthread Beiträge zu diesem Forumthread

300 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread