Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1036to1040
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Rechnen mit Datum + Monat mit 30 Tagen

Rechnen mit Datum + Monat mit 30 Tagen
14.01.2009 23:47:00
Andreas
Hi,
ich habe folgendes Problem. Ich muss die Anzahl der Tage zwischen zwei Daten ermitteln. Für gewöhnlich ist das kein Problem, aber ich muss die vollen KALENDERmonate mit 30 Tagen berücksichtigen und die angebrochenen mit der tatsächlichen Anzahl der Tage.
Bsp:
22.12.2008 - 30.03.2009
Dezember '08 = 10 Tage
Januar '09 = 30 Tage
Februar '09 = 30 Tage
März '09 = 30 Tage
= 100 Tage im genannten Zeitraum
Ich habe schon versucht mit DateDif rumzuhandwerken. Leider erkennt mir die Funktion die Kalendermonate nicht als solche, sondern rechnet nur anhand der Zahlendaten die Monate aus.
Ein Kalendermonat geht vom 01.01. - 31.01. = 1 Kalendermonat, der in diesem Fall mit 30 Tagen angesetzt werden soll.
Es geht mir bei der Berücksichtigung der Monate NICHT um Zeitmonate (03.01. - 02.02. = 1 Zeitmonat).
Weiß jemand wie ich das hinbekommen kann?
Vielen Dank!
Mfg. Andreas

7
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Rechnen mit Datum + Monat mit 30 Tagen
14.01.2009 23:59:00
Andreas
Hat sich erledigt. Gerade als ich es eingestellt habe, habe ich etwas durch Zufall hier im Forum gefunden :o)
http://xlfaq.herber.de/texte/005797h.htm
Trotzdem Danke!
Mfg. Andreas
AW: Rechnen mit Datum + Monat mit 30 Tagen
15.01.2009 09:56:00
Gert
Hallo Zusammen,
auch für 30TageMonate gibt es eine Funktion :
=TAGE360(A2;B2;WAHR)
Das Ergebnis ist 98Tage.
Hier werden Monate nur mit 30Tagen berechnet, auch der Februar!!
Eine Funktion zur Zinsberechnung der Banken.
mfg
Gert
AW: Rechnen mit Datum + Monat mit 30 Tagen
15.01.2009 00:03:00
Josef
Hallo Andreas,
die Formeln stammen von http://www.excelformeln.de/formeln.html?welcher=437
ich habe sie für dein Problem angepasst.
Tabelle2

 ABCDEFGH
1Zeitraum       
2vonbis Dez 08Jän 09Feb 09Mär 09 
322.12.200830.03.2009 10303030 

Formeln der Tabelle
ZelleFormel
D2=DATUM(JAHR(A3); MONAT(A3)+1;)
E2=WENN($B3<=D2;"";D2+32-TAG(D2+32))
F2=WENN($B3<=E2;"";E2+32-TAG(E2+32))
G2=WENN($B3<=F2;"";F2+32-TAG(F2+32))
H2=WENN($B3<=G2;"";G2+32-TAG(G2+32))
D3=WENN(MIN(D2;$B3)-A3+1=TAG(DATUM(JAHR(D2); MONAT(D2)+1;0)); 30;MIN(D2;$B3)-A3+1)
E3=WENN(E2="";"";WENN(MIN(E2;$B3)-D2=TAG(DATUM(JAHR(E2); MONAT(E2)+1;0)); 30;MIN(E2;$B3)-D2))
F3=WENN(F2="";"";WENN(MIN(F2;$B3)-E2=TAG(DATUM(JAHR(F2); MONAT(F2)+1;0)); 30;MIN(F2;$B3)-E2))
G3=WENN(G2="";"";WENN(MIN(G2;$B3)-F2=TAG(DATUM(JAHR(G2); MONAT(G2)+1;0)); 30;MIN(G2;$B3)-F2))
H3=WENN(H2="";"";WENN(MIN(H2;$B3)-G2=TAG(DATUM(JAHR(H2); MONAT(H2)+1;0)); 30;MIN(H2;$B3)-G2))


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Sepp

Anzeige
AW: Rechnen mit Datum + Monat mit 30 Tagen
15.01.2009 00:42:44
Erich
Hallo Andreas,
jetzt hab ich auch noch etwas gebastelt - ich hoffe, das stimmt einigermaßen.
(Gebraucht wird nur die Formel in Spalte C. In E bis G stehen die 3 Bestandteile, in I die genaue Diff. in Tagen.)
 ABCDEFGHI
1vonbisTage 1.Monatvolle MonateL.Monat Diff
222.12.200830.03.2009100 106030 99
322.12.200823.12.20082 200 2
430.03.200931.03.20092 200 2
531.03.200901.04.20092 101 2
601.04.200902.04.20092 200 2
724.12.200711.05.2008139 812011 140
801.04.200901.04.20091 100 1
901.01.195031.12.199918002 311794031 18262

Formeln der Tabelle
ZelleFormel
C2=MIN(B2+1;DATUM(JAHR(A2); MONAT(A2)+1;1))-A2 + 30*MAX(;12*(JAHR(B2)-JAHR(A2))+MONAT(B2)-MONAT(A2)-1) + (B2>DATUM(JAHR(A2); MONAT(A2)+1;0))*(B2-MAX(A2;DATUM(JAHR(B2); MONAT(B2); 0)))
E2=MIN(B2+1;DATUM(JAHR(A2); MONAT(A2)+1;1))-A2
F2=30*MAX(;12*(JAHR(B2)-JAHR(A2))+MONAT(B2)-MONAT(A2)-1)
G2=(B2>DATUM(JAHR(A2); MONAT(A2)+1;0))*(B2-MAX(A2;DATUM(JAHR(B2); MONAT(B2); 0)))
I2=B2-A2+1

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: Monat mit 30 Tagen - Korrektur
15.01.2009 12:44:01
Erich
Hallo Andreas,
da waren im letzten Beitrag npoch ein paar Ergebnisse falsch.
Das ist hoffentlich besser:
 ABCDEFGHI
1vonbisTage 1.Monatvolle MonateL.Monat Diff
222.12.200830.03.2009100 10230 99
322.12.200831.03.2009100 1030 100
401.02.200928.02.200930 010 28
501.04.200930.04.200930 010 30
601.05.200931.05.200930 010 31
722.12.200823.12.20082 200 2
830.03.200931.03.20092 200 2
931.03.200901.04.20092 101 2
1001.04.200905.04.20095 005 5
1101.01.200031.12.20041800 0600 1827

Formeln der Tabelle
ZelleFormel
C2=(TAG(A2)>1)*(MIN(B2+1;DATUM(JAHR(A2); MONAT(A2)+1;1))-A2) + 30*MAX(;12*(JAHR(B2)-JAHR(A2))+MONAT(B2)-MONAT(A2)+(TAG(A2)=1)-(B2<DATUM(JAHR(B2); MONAT(B2)+1;))) + (B2-DATUM(JAHR(B2); MONAT(B2); 0)) * (B2<DATUM(JAHR(B2); MONAT(B2)+1;0)) * (1-(TAG(A2)>1)*(JAHR(A2)=JAHR(B2))*(MONAT(A2)=MONAT(B2)))
E2=(TAG(A2)>1)*(MIN(B2+1;DATUM(JAHR(A2); MONAT(A2)+1;1))-A2)
F2=MAX(;12*(JAHR(B2)-JAHR(A2))+MONAT(B2)-MONAT(A2)+(TAG(A2)=1)-(B2<DATUM(JAHR(B2); MONAT(B2)+1;)))
G2=(B2-DATUM(JAHR(B2); MONAT(B2); 0)) * (B2<DATUM(JAHR(B2); MONAT(B2)+1;0)) * (1-(TAG(A2)>1)*(JAHR(A2)=JAHR(B2))*(MONAT(A2)=MONAT(B2)))
I2=B2-A2+1

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: Monat mit 30 Tagen - Formeln kürzer
15.01.2009 15:38:55
Erich
Hi nochmal:
 ABCDEFGHI
1vonbisTage 1.Monatvolle MonateL.Monat Diff
222.12.200830.03.2009100 10230 99
322.12.200831.03.2009100 1030 100
401.02.200928.02.200930 010 28
501.04.200930.04.200930 010 30
601.05.200931.05.200930 010 31
722.12.200823.12.20082 200 2
830.03.200931.03.20092 200 2
931.03.200901.04.20092 101 2
1001.04.200905.04.20095 005 5
1101.01.200031.12.20041800 0600 1827

Formeln der Tabelle
ZelleFormel
C2=(TAG(A2)>1)*(MIN(B2+1;DATUM(JAHR(A2); MONAT(A2)+1;1))-A2) + 30*MAX(;12*(JAHR(B2)-JAHR(A2))+MONAT(B2)-MONAT(A2)+(TAG(A2)=1)-(TAG(B2+1)>1)) + TAG(B2)*(TAG(B2+1)>1)*(1-(TAG(A2)>1)*(TEXT(A2;"JJJJMM")=TEXT(B2;"JJJJMM")))
E2=(TAG(A2)>1)*(MIN(B2+1;DATUM(JAHR(A2); MONAT(A2)+1;1))-A2)
F2=MAX(;12*(JAHR(B2)-JAHR(A2))+MONAT(B2)-MONAT(A2)+(TAG(A2)=1)-(TAG(B2+1)>1))
G2=TAG(B2) * (TAG(B2+1)>1) * (1-(TAG(A2)>1)*(TEXT(A2;"JJJJMM")=TEXT(B2;"JJJJMM")))
I2=B2-A2+1

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: Monat mit 30 Tagen - Formeln kürzer
15.01.2009 19:36:26
Andreas
Hi,
danke für die zahlreichen Antworten :o)
Meine Lösung hatte anfangs auch so ähnlich ausgesehen. Trotzdem danke für die Bemühungen.
Ich werde die VBA-Funktion verwenden. Diese kann ich nach belieben anpassen, da ich VBA von den Formatierungen her übersichtlicher finde, wie eine so lange Excel-Formel.
Trotzdem noch mal vielen Dank!
Mfg. Andreas

246 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige