weiß vielleicht jemand von Euch, wie man ein VBA-Modul ausdruckt und es schafft,
die aktuelle Zeit / und das Datum in der ersten Zeile mit auszudrucken?
Gruß und Dank,
Born
Option Explicit
Public Declare Function ShellExecute Lib "shell32.dll" Alias _
"ShellExecuteA" (ByVal hWnd As Long, _
ByVal lpOperation As String, _
ByVal lpFile As String, _
ByVal lpParameters As String, _
ByVal lpDirectory As String, _
ByVal nshowcmd As Long) As Long
Sub Test()
Dim strString As String
Dim sDatei As String
Dim F As Integer
'Datei Pfad
sDatei = IIf(Right$(ThisWorkbook.Path, 1) = "\", ThisWorkbook.Path, ThisWorkbook.Path & "\")
'Dateiname
sDatei = sDatei & "VBA_Code.txt"
'Code aus Modul1 auslesen
With ThisWorkbook.VBProject.VBComponents("Modul1").CodeModule
strString = .Lines(1, .CountOfLines)
End With
strString = "Ausgedruckt am: " & Format(Now, "dd.mm.yyyy hh:mm:ss") & vbCrLf & strString
'Textdatei erstellen
F = FreeFile
Open sDatei For Output As #F
Print #F, strString
Close #F
'Datei ausdrucken
Call ShellExecute(0, "print", sDatei, "", "", 6)
'5 Sekunden warten
Application.Wait Now + TimeSerial(0, 0, 5)
'Datei wieder löschen
Kill sDatei
End Sub
Gruß Tino