Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1044to1048
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Array Formel mit =finden()

Array Formel mit =finden()
04.02.2009 10:28:00
chris
Hallo guten morgen,
ich habe eine frage.Wäre klasse wenn Ihr mir helfen könnt.
Ich habe eine Datei in der stehen untereinander werte in Spalte A
Jetzt will ich eine Anzahl von denen zeilen in denen wert Wert "Rotes" vorkommt.
Also als Beispiel:
ChrisRotesmelde
ChrisBlaumelde
ChrisGrünmelde
ChrisRotesmelde
usw..
Jetzt soll das ergebniss der ARRAy formel sein 2 weil 2 mal Rotes vorkommt.
Ich habe es schon so versucht aber klappt nicht ganz :(
=SUMME((FINDEN(("Rotes");A2:A15)))
Danke im vorraus für euere Hilfe.
P.s es muss eine Array formel sein.
Danke

17
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Array Formel mit =finden()
04.02.2009 10:34:00
Erich
Hallo Chris,
mal mit, mal ohne Array:
 AB
1 2
2ChrisRotesmelde2
3ChrisBlaumelde 
4ChrisGrünmelde 
5ChrisRotesmelde 

Formeln der Tabelle
ZelleFormel
B1{=SUMME(--ISTZAHL(FINDEN(("Rotes"); A2:A15)))}
B2=SUMMENPRODUKT(1*ISTZAHL(FINDEN(("Rotes"); A2:A15)))
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: Array Formel mit =finden()
04.02.2009 10:38:31
chris
hallo Erich,
klappt beides super.
Nur bitte erklär doch mal formel 1.
Sowas hab ich noch nicht gesehen.
Geht das auch anders.
also irgendwie mit *1 oder muss (--ISTZAHL sein ?
Danke im vorraus Erich
AW: Array Formel mit =finden()
04.02.2009 10:41:00
chris
Noch eine frage erich,
wie kann ich deine Formel hier anbauen ?
Also das die Spalte A noch ein Suchkriterium hat.
=SUMME((B2:B150"")*((MONAT(B2:B150)=C2)))
irgendwie so:
=SUMME((B2:B150"")*((MONAT(B2:B150)=C2)) * SUMME(--ISTZAHL(FINDEN(("Rotes"); A2:A15))
AW: Array Formel mit =finden()
04.02.2009 10:42:00
chris
Stopp letzteres Problem habe ich hinbekommen.denke ich :)
So:
=SUMME((B2:B150"")*((MONAT(B2:B150)=C2)))*(--ISTZAHL(FINDEN(("Rotes"); A2:A150)))
Anzeige
AW: wieder offen
04.02.2009 10:44:00
chris
Hallo Erich,
klappt doch nicht meine Formel :(
AW: Array Formel mit =finden()
04.02.2009 10:45:52
Erich
Hi Chris,
das Doppelminus ist aber doch einigermaßen gebräuchlich
zum Umwandeln von logischen oder Textwerten in Zahlen.
Statt "--" kannst du auch "0+" oder "1*" schreiben - die tun das Gleiche.
Schau auch mal hier: https://www.herber.de/forum/archiv/1044to1048/t1046666.htm#1046846
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
AW: Array Formel mit =finden()
04.02.2009 10:50:54
chris
Danke Erich.
Aber das bekomme ich nicht hin.
So funtioniert die Formel nicht.
=SUMME((B2:B150"")*((MONAT(B2:B150)=C2)))*(--ISTZAHL(FINDEN(("Rotes"); A2:A150)))
Warum ?
Danke Erich
Anzeige
AW: Array Formel mit =finden()
04.02.2009 10:52:00
Erich
Hi Chris,
probier mal
 ABCD
1   2
2ChrisRotesmelde04.02.20092 
3ChrisBlaumelde04.02.2009  
4ChrisGrünmelde   
5ChrisRotesmelde04.02.2009  
6ChrisRotesmelde01.01.2009  

Formeln der Tabelle
ZelleFormel
D1{=SUMME((MONAT(B2:B150)=C2)*ISTZAHL(FINDEN("Rotes";A2:A150)))}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: Array Formel mit =finden()
04.02.2009 11:05:00
chris
Klapp nicht Erich.
Es fehlt noch die Abfrage ob in Spalte A Leer ist oder nicht.
Weil wenn in c2 der Wert 1 steht für Monat 1 werden aber auch in Spalte A die zellen als Monat 2 gezählt die Leer sind.
Verstehst du mich ?
Danke
AW: Array Formel mit =finden()
04.02.2009 11:18:52
chris
Habe es doch hinbekommen.
Mit dieser formel.
=SUMME((MONAT($B$2:$B$150)=C2)*ISTZAHL(FINDEN("Rotes";$A$2:$A$150)))
Hatte einen Denkfehler.
Vielen Dank noch einmal Erich !!!
AW: Array Formel mit =finden()
04.02.2009 11:43:01
Erich
Hi Chris,
MONAT(leereZelle) ist 1, das hatte ich übersehen. So sollte es gehen:
 ABCD
1  Monat 
2ChrisRotesmelde04.02.200911
3ChrisBlaumelde04.02.2009 1
4ChrisGrünmelde  2
5ChrisRotesmelde04.02.2009  
6ChrisRotesmelde01.01.2009  
7ChrisRotesmelde   

Formeln der Tabelle
ZelleFormel
D2{=SUMME((B2:B150>0)*(MONAT(B2:B150)=C2)*ISTZAHL(FINDEN("Rotes";A2:A150)))}
D3=SUMMENPRODUKT((B2:B150>0)*(MONAT(B2:B150)=C2)*ISTZAHL(FINDEN("Rotes";A2:A150)))
D4{=SUMME((MONAT($B$2:$B$150)=C2)*ISTZAHL(FINDEN("Rotes";$A$2:$A$150)))}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: Array Formel mit =finden()
05.02.2009 06:55:00
chris
Klappt super.
Danke Dir für deine Mühen !!!
AW: noch 1 mal offen mit Datei
05.02.2009 07:13:00
chris
Hallo Erich jetzt muss ich doch noch mal aufmachen :(
Habe noch einen Fehler entdeckt gerade.Weiß aber nicht warum dieser auftaucht.
Ich habe mal eine Beispieldatei angehängt.
In der beispieldatei ist tritt der fehler folgendermaßen auf.Momentan stht als Wert für Monat Januar = 1 und februar = 3
wenn ich jetzt das Datum in der Zelle A2 ändere von
"dfgs am 02.02.2009 um 13:27:43 ,Rotes_;W430;W420"
in "dfgs am 02.01.2009 um 13:27:43 ,Rotes_;W430;W420"
ändern sich die Zaheln nicht richtig.Aus der zelle D2 wird von Wert = 1 der Wert 3 also es erhöht sich der Zähler um 2 obwohl ich nur ein Datum geändert habe ?
Kannst du mir das erklären ? Oder vielleicht jemand anders.?
https://www.herber.de/bbs/user/59111.xls
Würde mich sehr freuen.
Vielen Dank noch einmal gruß Chris
Anzeige
AW: Korrekturen nötig
05.02.2009 09:39:47
Erich
Hi Chris,
in der Tab. sind 2 richtige Fehler und noch eine "Unschönheit":
In B2 und B3 steht identisch die Formel =TEIL(A2;FINDEN("am";A2)+3;10)
In B3 sollte aber doch wohl A3 ausgewertet werden. (In B9 wird jetzt A8 ausgewertet.)
Lösung: Formel von B2 nach unten kopieren.
In D2 steht: =SUMMENPRODUKT(((MONAT(B2:B10)=C2)*ISTZAHL(FINDEN("Rotes";A2:A10))))
in D3 steht: =SUMMENPRODUKT(((MONAT(B3:B151)=C3)*ISTZAHL(FINDEN("Rotes";A3:A151))))
in D4 steht: =SUMMENPRODUKT(((MONAT(B4:B152)=C4)*ISTZAHL(FINDEN("Rotes";A4:A152))))
Der Bereich, in dem gezählt wird, ändert sich von Zeile zu Zeile. Das hast du sicher nicht gewollt.
Lösung: Entscheiden für einen Bereich, z. B. Zeilen 2 bis 33 (kann auch 10 oder 150 sein)
Formel in D2: =SUMMENPRODUKT(((MONAT($B$2:$B$33)=C2)*ISTZAHL(FINDEN("Rotes";$A$2:$A$33))))
diese Formel nach unten kopieren. Die Dollarzeichen sind wichtig - absolute Adressierung!
Die Unschönheit:
Die Formel in B2 liefert einen Text: =TEIL(A2;FINDEN("am";A2)+3;10)
Wenn du MONAT(B2) rechnen lässt, wandelt Excel den Text in ein Datum um.
Dass in B2 jetzt kein Datum steht, kannst leicht sehen, wenn du der Zelle mal ein Format wie T.MMMM.JJ gibst.
Die Anzeige des Textes wird sich dadurch nicht ändern.
Wenn du in B2 ein Datum stehen haben willst, kannst du in B2 schreiben:
=--TEIL(A2;FINDEN("am";A2)+3;10) (Ergebnis ist etwa 39846.)
Dann musst du der Spalte B noch ein Datumsformat geben.
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: Korrekturen nötig
06.02.2009 07:22:00
chris
Hallo Erich,
ich schreibe gerade gleich mal mit.
Bin gerade am Fehler korrigieren.
Also die ersten beiden Fehler habe ich ausgebessert.
Vielen Dank.
zU fehler zwei:
Der Bereich, in dem gezählt wird, ändert sich von Zeile zu Zeile. Das hast du sicher nicht gewollt.
stimmt habe ich ausgebessert.Formel in D2 ist
=SUMMENPRODUKT(((MONAT($B$2:$B$100)=C2)*ISTZAHL(FINDEN("Rotes";$A$2:$A$100))))
und diese kann ich runter ziehen.
Und zu 3 habe ich auch ausgebessert.
"Dass in B2 jetzt kein Datum steht, kannst leicht sehen, wenn du der Zelle mal ein Format wie T.MMMM.JJ gibst.
Die Anzeige des Textes wird sich dadurch nicht ändern."
Stimmt hast du recht.Wusste nicht das die neue Formel das bewerkt.Muss aber auch nicht alles verstehen.
Vielen Dank Erich.
jetzt klappt alles !!!
gruß chris
Anzeige
Hat's geklappt - Korrekturen ok? (owT)
05.02.2009 20:32:00
Erich
(owT) := ohne weiteren Text
AW: Hat's geklappt - Korrekturen ok? (owT)
05.02.2009 20:33:00
chris
Ich gebe morgen bescheid wenn ich dazu komme.
Danke erst einmal Erich !

6 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige