Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1060to1064
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Formatierung von Pivot-Charts

Formatierung von Pivot-Charts
18.03.2009 08:50:41
Pivot-Charts
guten morgen liebe leute,
ich stehe mal wieder vor einem problem, dass mich noch in die klappse bringt, wenn es nicht irgendwie gelöst werden kann.
ich habe in einer datei mehrere pivot-charts (also diagramme in abhängigkeit von pivottables).
diese habe ich mir nach meinen vorstellungen formatiert (flächenfarbe, linienfarbe, linienstärke, skalierung usw.).
jetzt habe ich folgendes phänomen. wenn ich die pivots aktuallisiere bleibt jede formatierung wie sie ist nur die linien gehen in den excelstandard zurück und werden so hässlich dünn und haben bei den datenpunkten die exceltypischen markierungen.
ich habe den diagrammtyp (meine formatierung) schon als standard gesetzt - hilft hier aber nicht.
daher bitte ich euch hier um ratschläge, diesen rückschritt zur alten formatierung der linien zu verhindern.
vielen dank und
viele grüße
selli

2
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Formatierung von Pivot-Charts
18.03.2009 13:57:52
Pivot-Charts
Hallo selli,
da hab ich leider keine guten Nachrichten.
Zumindest bis zur Version Excel 2003 ist dass leider so.
Da bleibt als Ausweg "nur" die Formatierung des Diagramms per VBA-Anweisungen nach jeder Pivot-Aktualisierung oder Aktivierung des Diagrammblatts.
Das kann aber ziemlich kompliziert/aufwendig werden, abhängig von der Komplexität der Pivot-Tabelle.
Hier mal ein Beispiel für ein Linien-Diagramm, wobei 5 Linien vordefinierte Farben und Markierungen haben.
Die Prozeduren müssen im VBA-Editor unter dem Diagrammblatt eingefügt werden.
die Prozedur "DiagrammFormat(objChart As Chart)" kann aber auch in einem allgemeine Modul plaziert werden, wenn mehrere Diagramme gleichartig formatiert werden sollen.
Gruß
Franz

Private Sub Chart_Calculate()
Call DiagrammFormat(Me)
End Sub
Sub DiagrammFormat(objChart As Chart)
Dim objReihe As Series, intIndex
Dim lngLinecolorIndex As Long
Dim lngLineWeight As Long
Dim lngLineStyle As Long
Dim lngMarkerSize As Long
Dim lngMarkerStyle As Long
Dim lngMarkerBackGroundColorIndex As Long
Dim lngMarkerForegroundColorIndex As Long
With objChart
For Each objReihe In .SeriesCollection
intIndex = intIndex + 1
With objReihe
'Reihen-Linien im Diagramm fett darstellen
lngLineWeight = xlThick ' andere Werte: xlHairline, xlThin, xlMedium
'Linienart festlegen
lngLineStyle = xlContinuous ' ander Werte: xlDash, xlDashDot, _
xlDashDotDot, xlDot, xlDouble, xlSlantDashDot, xlLineStyleNone
lngMarkerSize = 9
'LinenFarben ind Markierung setzen
Select Case intIndex
Case 1
lngLinecolorIndex = 6 'gelb - xlColorIndexAutomatic ,xlColorIndexNone
lngMarkerStyle = xlMarkerStyleDiamond
'xlMarkerStyleAutomatic. Automatische Markierungen.
'xlMarkerStyleCircle. Runde Markierungen.
'xlMarkerStyleDash. Lange Balken als Markierungen.
'xlMarkerStyleDiamond. Rautenförmige Markierungen.
'xlMarkerStyleDot. Kurze Balken als Markierungen.
'xlMarkerStyleNone. Keine Markierung.
'xlMarkerStylePicture. Bildmarkierungen.
'xlMarkerStylePlus. Quadratische Markierungen mit einem Pluszeichen.
'xlMarkerStyleSquare. Quadratische Markierungen.
'xlMarkerStyleStar Quadratische Markierungen mit einem Sternchen.
'xlMarkerStyleTriangle. Dreieckige Markierungen.
'xlMarkerStyleX. Quadratische Markierungen mit einem X.
lngMarkerBackGroundColorIndex = 2
lngMarkerForegroundColorIndex = 6
Case 2
lngLinecolorIndex = 3 'Rot
lngMarkerStyle = xlMarkerStyleCircle
lngMarkerBackGroundColorIndex = 2
lngMarkerForegroundColorIndex = 3
Case 3
lngLinecolorIndex = 9 'Dunkelrot
lngMarkerStyle = xlMarkerStyleSquare
lngMarkerBackGroundColorIndex = 2
lngMarkerForegroundColorIndex = 9
Case 4
lngLinecolorIndex = 7 'Rosa
lngMarkerStyle = xlMarkerStyleTriangle
lngMarkerBackGroundColorIndex = 2
lngMarkerForegroundColorIndex = 7
Case 5
lngLinecolorIndex = 4 'Hellgrün
lngMarkerStyle = xlMarkerStyleTriangle
lngMarkerBackGroundColorIndex = 2
lngMarkerForegroundColorIndex = 4
Case Else
MsgBox "Mehr Linien im Diagram als Festlegungen für einzelne Linien."
lngLinecolorIndex = xlColorIndexAutomatic
lngMarkerStyle = xlMarkerStyleAutomatic
lngMarkerBackGroundColorIndex = xlColorIndexAutomatic
lngMarkerForegroundColorIndex = xlColorIndexAutomatic
End Select
.Border.LineStyle = lngLineStyle
.Border.Weight = lngLineWeight
.Border.ColorIndex = lngLinecolorIndex
.MarkerBackgroundColorIndex = lngMarkerBackGroundColorIndex
.MarkerForegroundColorIndex = lngMarkerForegroundColorIndex
.MarkerSize = lngMarkerSize
.MarkerStyle = lngMarkerStyle
End With
Next
End With
End Sub


Anzeige
AW: Formatierung von Pivot-Charts
18.03.2009 14:59:19
Pivot-Charts
hallo franz,
erstmal vielen dank für deine lösung.
ich bin mittlerweile auch dazu übergegangen das diagramm bei calculate neu zu formatieren.
ist aber schon ziemlich doof, dass das nicht anders geht.
habe mich hierbei auf die linienstärke und die art der markierungen beschränkt, da diese gut in einer schleife abzuarbeiten sind. mit den farben kann und muß ich wohl leben, da immer mal wieder datenreihen hinzukommen.
vielen dank für deine bemühungen
gruß selli

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige