Anzeige
Archiv - Navigation
1080to1084
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Kontrollkästchen - AutoAusfüllen

Kontrollkästchen - AutoAusfüllen
20.06.2009 16:55:46
Frank
Hallo Zusammen!
Ein schönes Wochenende an alle und nun zu meiner Frage!!!
Ich habe in Zelle A1 ein Kontrollkästchen welches mit Zelle B1 verknüpft ist. Mittels AutoAusfüllen kann ich weitere Kontrollkästchen in Spalte A setzen, aber der Zellbezug bleibt immer B1. Wie wird daraus B2, B3 usw., ohne dass ich es manuell erledigen muss? Geht das?
Ich bin für sämtliche Hilfe und Anregungen schon jetzt dankbar!!!
Gruß Frank H.

18
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Kontrollkästchen - AutoAusfüllen
20.06.2009 16:59:00
Heinz
Hi,
das geht nur mit VBA, indem du in einer Schleife jedem Kästchen die Zellverknüpfung zuweist.
mfg Heinz
AW: Kontrollkästchen - AutoAusfüllen
20.06.2009 17:08:08
Frank
Hallo Heinz!!!
VBA ist nicht meine Stärke. Kannst du mir, oder jeder Andere, einen Ansatz bieten!!! Dieser solle verständlich und veränderbar sein!!!
Danke!
Gruß Frank H.
AW: Kontrollkästchen - AutoAusfüllen
20.06.2009 18:40:44
Josef
Hallo Frank,
mit diesem Code wird jedem Kontrollkästchen die rechte Nachbarzelle als Verknüpfung zugewiesen.
Sub verknuepfung()
  Dim objShp As Shape
  
  For Each objShp In ActiveSheet.Shapes
    If objShp.FormControlType = xlCheckBox Then
      objShp.DrawingObject.LinkedCell = objShp.TopLeftCell.Offset(0, 1).Address
    End If
  Next
End Sub

Gruß Sepp

Anzeige
AW: Kontrollkästchen - AutoAusfüllen
20.06.2009 18:56:04
Frank
Hallo Sepp!!!
Danke, Danke - Funzt super!!!
Ich hoffe das ich deine Zeit noch einmal in Anspruch nehmen kann. Nun sollen in Spalte A untereinander 20 Kästchen sein und in Spalte D auch untereinander 20 Kästchen und die Verknüpfungen in K und L. Wie stelle ich das an, das ich in der Schleife jeweils die entsprechenden Boxen anspreche.
Schon vorab Danke!!!
Gruß Frank H .
AW: Kontrollkästchen - AutoAusfüllen
20.06.2009 18:59:48
Josef
Hallo Frank,
das erledig der Code schon von alleine!
"mit diesem Code wird jedem Kontrollkästchen die rechte Nachbarzelle als Verknüpfung zugewiesen."
Erstelle einfach die Kontrollkästechen, positioniere sie und lass den Code laufen.
Gruß Sepp

Anzeige
AW: ? warum funkt es nicht ?...
20.06.2009 19:31:07
Josef
Hallo Robert,
bei "Kontrollkästchen" ist für mich klar, das es aus der Formular-Symbolleiste stammt.
Du Verwendest eine CheckBox aus der Steuerelemente-Symbolleiste, die muss man anders ansprechen.
Sub verknuepfung()
  Dim objOLE As OLEObject
  For Each objOLE In ActiveSheet.OLEObjects
    If objOLE.progID = "Forms.CheckBox.1" Then
      objOLE.LinkedCell = objOLE.TopLeftCell.Offset(0, 1).Address
    End If
  Next
End Sub

Gruß Sepp

Anzeige
OK, aber Kontrollkästchen geht nicht
20.06.2009 19:37:30
robert
hi Sepp,
danke, so gehts,
aber siehe datei mit formular-kontrollkästchen...
oder mach ichs schon wieder falsch ? :-(
gruß
robert
https://www.herber.de/bbs/user/62600.xls
AW: OK, aber Kontrollkästchen geht nicht
20.06.2009 19:57:59
Josef
Hallo Robert,
für beide Typen auf einem Blatt muss man natürlich im Code unterscheiden.
Sub verknuepfung()
  Dim objShp As Shape
  For Each objShp In ActiveSheet.Shapes
    On Error Resume Next
    If objShp.Type = msoOLEControlObject Then
      If objShp.progID = "Forms.CheckBox.1" Then
        objShp.LinkedCell = objShp.TopLeftCell.Offset(0, 1).Address
      End If
    ElseIf objShp.Type = msoFormControl Then
      If objShp.FormControlType = xlCheckBox Then
        objShp.DrawingObject.LinkedCell = objShp.TopLeftCell.Offset(0, 1).Address
      End If
    End If
  Next
End Sub

Gruß Sepp

Anzeige
AW: OK, aber Kontrollkästchen geht nicht
20.06.2009 20:04:33
robert
hi sepp,
es ist komisch...
mit diesem code kommt fehler 1004 bei If objShp.......
mit der letzten version gehts....
ich sehe aber keinen unterschied im code
bitte probier es mal in meiner datei aus
gruß
robert

Sub verknuepfung()
Dim objShp As Shape
For Each objShp In ActiveSheet.Shapes
If objShp.FormControlType = xlCheckBox Then
objShp.DrawingObject.LinkedCell = objShp.TopLeftCell.Offset(0, 1).Address
End If
Next
End Sub


Das ist der Unterschied..
20.06.2009 20:29:41
robert
hi sepp,
mit dieser zeile funkts, aber warum ?
On Error Resume Next
gruß
robert
Anzeige
AW: Das ist der Unterschied..
20.06.2009 20:31:11
Josef
Hallo Robert,
diese Zeile braucht's nicht, wenn du meinen letzten Code nimmst, habe nur vergessen die Zeile rauszunehmen.
Gruß Sepp

ich widerspreche dir nur ungern, aber..
20.06.2009 20:35:18
robert
..es geht nicht ! ohne On Error Resume Next
hast du es mit meiner datei getestet ?
gruß
robert
AW: ich widerspreche dir nur ungern, aber..
20.06.2009 20:52:58
Josef
Hallo Robert,
getestet ja, aber eben mit "On Error Resume Next".
So passt es aber.
Sub verknuepfung()
  Dim objShp As Shape
  For Each objShp In ActiveSheet.Shapes
    If objShp.Type = msoOLEControlObject Then
      If objShp.OLEFormat.progID = "Forms.CheckBox.1" Then
        objShp.OLEFormat.Object.LinkedCell = objShp.TopLeftCell.Offset(0, 1).Address
      End If
    ElseIf objShp.Type = msoFormControl Then
      If objShp.FormControlType = xlCheckBox Then
        objShp.DrawingObject.LinkedCell = objShp.TopLeftCell.Offset(0, 1).Address
      End If
    End If
  Next
End Sub

Gruß Sepp

Anzeige
JA, so ist es OK-Danke !!! owT
20.06.2009 21:08:34
robert
AW: JA, so ist es OK-Danke !!! owT
20.06.2009 21:16:20
Frank
Hallo Ihr Zwei!!!!
Da habe ich wohl einen Vulkan ausgelöst und Sepp konnte das Feuer eindämmen oder gar löschen. Nun habe ich aber noch eine Frage an Sepp: Du musst nicht antworten, aber meine Neugier möcht's schon gern wissen. Wo hast du dein Wissen rund um Excel her?
Schönen Abend noch allerseits!!!
Gruß Frank H. aus unser Hauptstadt!!!
AW: JA, so ist es OK-Danke !!! owT
20.06.2009 21:21:28
Josef
Hallo Frank,
alle autoditaktisch aus spass an der Freude wie man so schön sagt, das meiste durch "learning by doing" und durch dieses (das Beste) und anderen Foren.
Gruß Sepp

Anzeige
AW: Na, dann kann ich ja noch hoffen! owT
20.06.2009 21:26:43
Frank
.

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige