AW: erweiterter SVERWEIS?
18.09.2009 12:48:34
ransi
HAllo Heike
Mit "Bordmitteln" wird das sehr schwer.
Ein kleines bischen VBA und es ist ganz einfach.
PAcke diesen Code mal in ein Modul:
' **********************************************************************
' Modul: Sverweis_anders Typ: Allgemeines Modul
' **********************************************************************
Option Explicit
Public Function SVERWEIS2(Kriterium As String, _
Bereich As Range, _
SuchSpalte As Integer, _
ErgebnissSpalte As Integer, _
Optional Unikate As Boolean = True, _
Optional Trenner As String = ", ") As String
Dim arrTmp
Dim L As Long
Dim Mydic As Object
arrTmp = Bereich
Set Mydic = CreateObject("Scripting.Dictionary")
If Unikate = True Then
For L = 1 To UBound(arrTmp)
If arrTmp(L, SuchSpalte) = Kriterium Then Mydic(arrTmp(L, ErgebnissSpalte)) = 0
Next
SVERWEIS2 = Join(Mydic.keys, Trenner)
Else:
For L = 1 To UBound(arrTmp)
If arrTmp(L, SuchSpalte) = Kriterium Then Mydic(L) = arrTmp(L, ErgebnissSpalte)
Next
SVERWEIS2 = Join(Mydic.items, Trenner)
End If
End Function
Der Aufruf ist dann ganz einfach:
Tabelle1
| A | B |
1 | Bereich | Kostenstelle |
2 | Prod | 111 |
3 | Prod | 112 |
4 | Prod | 113 |
5 | Mat | 211 |
6 | Mat | 212 |
7 | Mat | 213 |
8 | Mat | 214 |
9 | etc. | |
10 | | |
11 | so sollte es aussehen: | |
12 | Prod | 111, 112, 113 |
13 | Mat | 211, 212, 213, 214 |
14 | etc. | |
Formeln der Tabelle |
Zelle | Formel | B12 | =sverweis2(A12;$A$2:$B$9;1;2;WAHR) | B13 | =sverweis2(A13;$A$2:$B$9;1;2;WAHR) |
|
Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
ransi