Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1124to1128
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

dropdown erklären

dropdown erklären
Volker
Hallo liebe Excelgemeinde
Kann mir einer mal schreiben wo ich eine leicht zu erlernende Erklärung für die Erstellung von Dropdown-Zellen zu finden sind. Alle die ich mit Google gefunden habe sind nicht so prall.
Ich habe eine Artikel-Tabelle (unsortiert) und möchte auf einem weiteren Tabellenblatt per Dropdown auf die "alphabetisch-sortiereten" Daten zugreifen.
Für Hilfe schon mal lieben Dank

15
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Benutzer
Anzeige
AW: dropdown erklären
27.12.2009 10:41:28
Volker
Hallo Sepp, danke fürdein Beispiel.
Ich habe aber in dem Tabellenblatt, auf das das ListenDropdown zugreifen soll, so viele Code, alle immer mal wider "dazugefummelt", da ich "machmal nicht weiss was da abgeht". Kannst du mir einen Verwais senden, in dem es leicht Erklärend der Aufbau beschrieben wird?
Gruss Volker
Anzeige
AW: dropdown erklären
27.12.2009 11:50:32
Josef
Hallo Volker,
den Code hast du ja wohl gesehen?
Es wird einfach aus den Einträgen bei den Artikeln ein sortiertes Array erzeugt, dieses dann in
eine Stringvariable eingelesen und der Gültigkeit der entsprechenden Zellen als Liste zugewiesen.
Gruß Sepp

OT Hyperlink
27.12.2009 10:56:42
Reinhard
Hallo Sepp,
"Code Anzeigen" ist wohl ein Hyperlink, denn entfernen kann ich ihn über Hyperlink entfernen.
Aber wie ändere ich ihn ab bzw. wie geb ich ihn ein?
Bei Hyperlink bearbeiten sehe ich dieses:
Userbild
Gruß
Reinhard
Anzeige
AW: OT Hyperlink
27.12.2009 11:46:44
Josef
Hallo Reinhard,
Link in den VBE Userbild
Gruß Sepp

AW: OT Hyperlink
27.12.2009 12:00:16
Volker
Hallo liebe Excel- Helfer.
Leider ist meine FRage wohl eigentlich untergegangen.
Wo finde ich eine leichte Anleitung zur Erstellung von Dropdown Zellen!!
Ausgangsfrage noch offen
27.12.2009 12:10:47
Reinhard
Hallo Volker,
sorry.
Gruß
Reinhard
AW: OT Hyperlink
27.12.2009 12:49:13
Josef
Hallo Volker,
was willst du eigentlich? Wie man ein Gültigkeits-DropDown ezeugt, wirst du bei "Excel gut" wohl wissen.
Und wie du Einträge sortiert in ein solches bringt, zeigt dir mein Beispiel.
Gruß Sepp

Anzeige
AW: OT Hyperlink
27.12.2009 13:01:29
Volker
Hallo Sepp, leider habe ich mich wohl da etwas überschätzt. Das mit Dropdown habe ich bis jetzt noch nie gemacht. Trotzdem danke für dein Hilfe.
Gruss Volker
AW: OT Hyperlink
27.12.2009 13:08:59
Josef
Hallo Volker,
zum händischen Erstellen von Gültigkeiten.
Guckst Du: Gültigkeit (1) - Grundlagen
Guckst Du: Gültigkeit (2) - Listen und mehr
Mein Beispiel macht die ganze Arbeit für dich, du musst nur die Tabellennamen und Bereiche anpassen!
Gruß Sepp

Anzeige
AW: OT Hyperlink
27.12.2009 13:17:16
Volker
Klasse von dir Sepp. Jetzte werde ich mal ans lernen gehen!!
Danke Euch, wie immer ...hier werden sie geholfen!!
Gruss Volker
AW: OT Hyperlink
27.12.2009 12:09:40
Reinhard
Hallo Sepp,
danke dir. In XL2000 sieht das anders aus, geht aber auch so.
Das feld "Adresse" existiert nicht.
Links "Datei oder Webseite" anklicken.
Dann erscheint dort wo bei dir das Feld "Suchen in" ist ein Feld "Datei oder Webseite.
In das Feld dann "#Modul1.Makro1" eingeben.
Mein Fehler war daß ich in deiner Mappe nicht auf "datei oder Webseite" geklickt hatte, sonst hätte ich dort ja "#Tabelle1.Worksheet_Change" gesehen.
Gruß
Reinhard
Anzeige
@ Sepp
27.12.2009 13:46:01
Frank
Hallo Sepp,
wie müsste ich das Makro denn ändern, damit ich das als normales Makro laufen lassen kann?
Danke im Voraus für Deine Hilfe!
Frank
AW: @ Sepp
27.12.2009 13:56:02
Josef
Hallo Frank,
das geht zB. so.
' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Private Sub createValidation()
  Dim vntList As Variant, strList As String
  
  With Sheets("Tabelle1") 'Tabelle mit den Listeneinträgen
    'Bereich anpassen!
    vntList = UniqueList(.Range("A2:A" & .Cells(Rows.Count, 1).End(xlUp).Row), True)
  End With
  
  strList = Join(vntList, ",")
  
  With Sheets("Tabelle2").Range("B2:B100") 'Tabelle und Bereich mit dem Gültigkeits-Dropdown
    .Validation.Delete
    .Validation.Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, _
      Operator:=xlBetween, Formula1:=strList
  End With
  
End Sub

Private Function UniqueList(Matrix As Range, Optional Sorted As Boolean = True) As Variant
  Dim objDic As Object, rng As Range, varTmp() As Variant
  
  Set objDic = CreateObject("Scripting.Dictionary")
  
  For Each rng In Matrix
    If rng.Value <> "" Then objDic(rng.Value) = 0
  Next
  
  varTmp = objDic.keys
  
  If Sorted Then QuickSort varTmp
  
  UniqueList = varTmp
  
  Set objDic = Nothing
End Function

Private Sub QuickSort(data() As Variant, Optional UG, Optional OG)
  Dim P1&, P2&, T1 As Variant, T2 As Variant
  
  UG = IIf(IsMissing(UG), LBound(data), UG)
  OG = IIf(IsMissing(OG), UBound(data), OG)
  
  P1 = UG
  P2 = OG
  T1 = data((P1 + P2) / 2)
  
  Do
    
    Do While (data(P1) < T1)
      P1 = P1 + 1
    Loop
    
    Do While (data(P2) > T1)
      P2 = P2 - 1
    Loop
    
    If P1 <= P2 Then
      T2 = data(P1)
      data(P1) = data(P2)
      data(P2) = T2
      P1 = P1 + 1
      P2 = P2 - 1
    End If
    
  Loop Until (P1 > P2)
  
  If UG < P2 Then QuickSort data, UG, P2
  If P1 < OG Then QuickSort data, P1, OG
  
End Sub

Gruß Sepp

Anzeige
Besten Dank! oT
27.12.2009 14:02:44
Frank

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige