Mehrere Pagefields gleichzeitig wählen (Pivot)

Hallo Gemeinde!
Eine Frage wieder mal:
Es geht um eine Datei mit diversen Pivotstatistiken, die selbst per Makro erstellt wird. Es sind dabei jeweils mehrere Pivotauswertungen auf einem Sheet (also 1 Datensheet, n Sheets und jeweils m Pivots per Sheet). Was nun cool wäre zu haben:
Die Statistiken beziehen sich immer auf eine Verkaufsregion, die wiederum aus mehreren Standorten besteht. Jeder Standort besteht wieder aus mehreren Verkäufern. Den Verkaufsleiter interessieren nun zunächst die Zahlen für die ganze Region, dann für einzelne Standort usw. Ist es möglich, durch Betätigen einer Listbox (bzw. evt. anderere Auswahlalternative) ALLE Pagefields ALLER Statistiken einzugrenzen. Bsp: In einer Listbox wird beispielsweise München (nur 1x) angewählt, und alle Statistiken zeigen nur noch die Werte für München an. Wichtig: Datei wird jedesmal neu per Makro erzeugt, ich müsste also auch diesen Mechanismus per Makro erzeugen. Event? Wie?
Danke Euch schonmal für die Hilfe...
Gruss Florian

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

'Synchronisieren bestimmter Seitenfelder von Pivottabellen auf einem Tabellenblatt Private Sub Worksheet_PivotTableUpdate(ByVal Target As PivotTable) Dim pvPT As PivotTable, pvField As PivotField, sWert As String, sField As String Application.EnableEvents = False For Each pvPT In Me.PivotTables Select Case pvPT.Name Case Target.Name 'Namen der Pivot-Tabs, die nicht mit synchronisiert werden sollen 'do nothing Case Else sField = "Region" sWert = Target.PageFields(sField).CurrentPage.Name pvPT.PageFields(sField).CurrentPage = sWert sField = "Standort" sWert = Target.PageFields(sField).CurrentPage.Name pvPT.PageFields(sField).CurrentPage = sWert End Select Next Application.EnableEvents = True End Sub

Hallo Florian,
im Prinzip hast du die Vorgehensweise verstanden.
Du erstellst eine Arbeitsmappe mit einem leeren Tabellenblatt.
Diese enthält unter "DieseArbeitsmappe" die Prozedur, die nach Aktualisierung einer Pivottabelle in einem Tabellenblatt ausgeführt werden soll. Ob du diese Datei als "normale" Exceldatei (XLS) oder Mustervorlage (XLT) anlegst ist im Prinzip egal.
Die Verknüpfungen werden in der Prozedur dabei durch die Objektvariablen, die Case-Anweisungen und die Namen der Seitenfelder hergestellt.

Private Sub Workbook_SheetPivotTableUpdate(ByVal Sh As Object, ByVal Target As PivotTable)
'Synchronisieren bestimmter Seitenfelder von Pivottabellen auf einem Tabellenblatt
Dim pvPT As PivotTable, pvField As PivotField, sWert As String, sField As String
Application.EnableEvents = False
Select Case Sh.Name
Case "Daten", "Tabelle2" 'Tabellennamen der Blätter ohne Pivot-Tabellen, bzw. deren Pivot- _
Tabs _
nicht synchronisiert werden sollen
Case Else
'Seitenfelder der Pivot-Tabellen im aktiven Tabellenblatt synchronisieren
For Each pvPT In Sh.PivotTables
Select Case pvPT.Name
Case Target.Name 'Namen der Pivot-Tabs, die nicht mit synchronisiert werden sollen
'do nothing
Case Else
sField = "Region"
sWert = Target.PageFields(sField).CurrentPage.Name
pvPT.PageFields(sField).CurrentPage = sWert
sField = "Standort"
sWert = Target.PageFields(sField).CurrentPage.Name
pvPT.PageFields(sField).CurrentPage = sWert
End Select
Next
End Select
Application.EnableEvents = True
End Sub

Die Objekt-Variable "Sh" steht für das aktive Blatt in dem eine Pivot-Tabelle aktualisiert wurde.
Die Objekt-Variable "Target" steht für die Pivot-Tabelle, die aktualisiert wurde.
Mit den Case-Anweisungen wird dann gesteuert, was in welchen Tabellenblättern passieren soll.
Hier werden die Tabellen "Daten" und "Tabelle2" ohne weitere Aktionen übersprungen.
In allen anderen Tabellenblättern werden in der For-Schleife die Einstellungen für die Seitenfelder "Region" und "Standort" in allen Pivottabellen auf dem aktiven Blatt an die Einstellung der soeben geänderten Pivot-Tabelle angepasst.
Die Namen der Tabellen und Seitenfelder muss du natürlich an die Namen in der von deiner Steuerdatei erzeugten Datei anpassen.
Gruß
Franz

Beliebteste Forumthreads (12 Monate)

Mehrere Pagefields gleichzeitig wählen (Pivot)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Mehrere Pagefields gleichzeitig wählen (Pivot)

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread