Live-Forum - Die aktuellen Beiträge
Datum
Titel
29.03.2024 13:14:12
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1156to1160
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Images aus Tabellenblatt auf C speichern

Images aus Tabellenblatt auf C speichern
kle
Hallo,
habe in einem Tabellenblatt eine Grafik (Bild) - dieses möchte ich gern temporär auf C:\Temp speichern als gif und nach einem anderen Vorgang soll es wieder gelöscht werden.
Aber irgendwie bekomme ich das speichern nicht hin... HILFE !
Vielen Dank !
Gruß
Kay

4
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Benutzer
Anzeige
AW: Images aus Tabellenblatt auf C speichern
09.05.2010 21:51:45
Josef

Hallo Kay,

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Sub create() 'Speichern
  'Tabellen und Bildname anpassen!
  Export_Picture Sheets("Tabelle2").Shapes("Picture 1"), "C:\Temp\temp.gif"
End Sub

Sub destroy() 'Löschen
  On Error Resume Next
  Kill "C:\Temp\temp.gif"
End Sub

Private Function Export_Picture(myShape As Shape, FileName As String) As Long
  'Idea by Nepumuk
  Dim myChart As Chart, myChartObject As ChartObject
  Dim strFilter As String
  
  On Error GoTo ErrExit
  
  Application.ScreenUpdating = False
  Application.DisplayAlerts = False
  
  strFilter = UCase(Right(FileName, 3))
  
  Select Case strFilter
    Case "GIF", "JPG", "PNG"
    Case Else
      MsgBox "Ungültiges Grafikformat!" & vbLf & vbLf & "Export als '" & FileName & "' nicht möglich.", _
        vbInformation, "Export_Picture"
      Err.Raise vbObjectError + 1024
  End Select
  
  Set myChart = Charts.Add
  Set myChartObject = ActiveChart.ChartObjects.Add(0, 0, myShape.Width, myShape.Height)
  
  myShape.Copy
  
  With myChartObject
    With .Chart
      .ChartArea.Border.LineStyle = xlLineStyleNone
      .Paste
      .Export FileName:=FileName, FilterName:=strFilter, Interactive:=False
    End With
    .Delete
  End With
  
  myChart.Delete
  
  ErrExit:
  Export_Picture = Err.Number = 0
  Application.DisplayAlerts = True
  Application.ScreenUpdating = True
  Set myChart = Nothing
  Set myChartObject = Nothing
  Set myShape = Nothing
End Function

Gruß Sepp

Anzeige
AW: Klappt noch nicht - Musterdatei beigefügt
09.05.2010 22:22:39
kle
Hi Josef,
...vielen dank - aber irgendwie klappt es nicht. OHNE dass ich eine "Negativrückmeldung erhalte".
Habe eine Musterdatei erstellt und beigefügt. Die Grafik-Datei wird einfach nicht gespeichert und das erstellte Diagramm mit dem Bild - wird auch nicht gelöscht...
Danke für Deine Unterstützung bereits an dieser Stelle !
Gruß
Kay

Die Datei https://www.herber.de/bbs/user/69493.xlsm wurde aus Datenschutzgründen gelöscht


AW: Klappt noch nicht - Musterdatei beigefügt
09.05.2010 22:56:27
Josef

Hallo Kay,
"C:\KLE\" muss natürlich existieren!
https://www.herber.de/bbs/user/69494.xlsm

Gruß Sepp

Anzeige
AW: klappt - Danke !
10.05.2010 01:04:24
kle
Hi...
wusste doch da war noch was ;o) ?!
Jetzt klappt es perfekt - genau wie ich es mir vorgestellt hatte. Vielen Dank !
Gruß
Kay

301 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige