Gibt es bei Excel eine Möglichkeit einer Summe zu sagen, wie lange sie laufen soll... also ich möchte in einer Zelle einen Wert eingeben (beispielsweise 10) dann möchte ich in einer Spalte in der ich ca. 100 werte habe aber nur ab einem bestimmten Wert die folgenden 10 summieren... besteht die möglichkeit die Laufzeit irgendwie flexibel einzubauen... sprich vllt mit der adresse der zelle zu arbeiten, dass ich die 10 einfach in eine 15 ändern könnte und nichts an der Summe an sich ändern muss?
Danke schon mal für die Hilfe
Hi Seb,
Zahlen in Spalte A. In C1 gibst Du ein, in welcher Zeile die Summe beginnen soll, und in C2 die Anzahl der zu summierenden Zellen.
=SUMME(BEREICH.VERSCHIEBEN(INDEX(A:A;C1);;;C2))
Steht in C1 z.B. ne 3 und in C2 ne 5, wird der Bereich A3:A7 summiert.
Grüße Boris
AW: SUMME flexibel bilden
10.05.2010 21:58:35
Seb
Dankeschön das ist genau das was ich brauchte jetzt hat es endlich funktioniert... Dankeschön!
6 Zeichen kürzer ;-)
11.05.2010 07:44:43
Christian
Hallo Seb, Hallo Boris,
mein Vorschlag ohne Index:
=SUMME(BEREICH.VERSCHIEBEN(A1;C1-1;;C2;))
MfG Christian
unvolatil: 2 Varianten
10.05.2010 22:39:39
silex1
Hallo,
Arbeitsblatt mit dem Namen 'Tabelle1'
A
B
1
3
2
100
3
4
10
5
6
7
10
8
10
Zelle
Formel
B7
=SUMME(A1:INDEX(A:A;B2))
B8
=SUMME(INDEX(A:A;B1):INDEX(A:A;B2))
VG, Rene
Anzeige
Das ist aber was anderes
10.05.2010 22:54:33
{Boris}
Hi Rene,
bei Dir ist es "von Zeile " "bis Zeile" - gewünscht war aber wohl "von Zeile" "Anzahl Zeilen"...
Grüße Boris
lesen>verstehen>antworten :-(
10.05.2010 23:25:13
silex1
Hallo Boris,
ja gut möglich, dass ich etwas daneben lag!
Is ja schon spät! Is nicht schlimm, Korrektur folgt ;-)
=SUMME(INDEX(A:A;B1):INDEX(A:A;B1+B2))
Oder wieder verdaddelt? :-(
VG, Rene ;-)
Fast ;-)
10.05.2010 23:37:56
{Boris}
Hi Rene,
=SUMME(INDEX(A:A;C1):INDEX(A:A;C1+C2-1))
Aber so ist es in der Tat nicht volatil ;-)
Grüße Boris