Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1180to1184
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Auswertung Tabelle

Auswertung Tabelle
Steffen
Hallo
Ich habe eine Tabelle als Ergebnis einer Auswertung.
Die Tabelle hat den Bereich C3:AM33.
die Tabelle zählt Plattenformate, in X Richtung die Maße in X, in Y Richtung die Maße in Y.
Beispiel, ich habe Platten im Format 1000 x 500 und dieses kommt 3 mal vor, dann steht in der Tabelle im entsprechenden Feld "3".
Da einige der 510 Formate nicht vorkommen (mehr als die Hälfte) steht in vielen Feldern eine 0.
Nun möchte ich als Ergebnis eine Auswertung haben in der Steht:
3 Platten 1000 x 500
4 Platten 800 x 600
...
Also es sollen nur die vorhandenen aufgelistet werden (das ganze noch nach Anzahl zu Sortieren wäre dann deluxe).
Wie mache ich sowas?
Steffen

11
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Benutzer
Anzeige
AW: Auswertung Tabelle
12.10.2010 08:22:08
Christian
Hallo Steffen,
Nachbau ist meist anders als Original, kannst Du bitte mal ein Bsp. einstellen!
MfG Christian
AW: Auswertung Tabelle
12.10.2010 09:02:59
Steffen
Hallo
Ich bekomme die Datei nicht in den Upload. Angeblich falscher Dateiname, ich weiß aber nicht wo der Fehler liegen soll, der Name hat 8 Buchstaben und keine Sonderzeichen.
Die Tabelle sieht ganze einfach aus. in Zeile 1 die Maße in X Richtung: 50, 100, 150, 200, 250 etc.
in Spalte A die Maße in Y Richtung: 50, 100, 150, 200, 250 etc.
wenn es jetzt ein Tafel mit den Maßen 100*100 gibt, dann steht im entsprechenden Feld eine 1. Wenn es mehr gibt steht eine größer Zahl z.B. eine 28 drin.
Steffen
Anzeige
AW: Auswertung Tabelle
12.10.2010 09:18:56
Steffen
Hab das Ausrufezeichen vergessen
AW: Auswertung Tabelle
12.10.2010 10:10:18
Christian
Hallo Steffen,
ein Ansatz mit 2 Hilfsspalten:
Tabelle3

 WXYZ
1AnzahlAbmessung  
23200 x 2502,9495$E$6
33200 x 1502,9497$E$4
43150 x 2502,9595$D$6
51250 x 35011,9793$B$8
614300 x 20013,9296$G$5
717400 x 20016,9096$I$5
828300 x 15027,9297$G$4
9    
10    
11    

Formeln der Tabelle
ZelleFormel
W2{=WENN(ZEILE(A1)>ZÄHLENWENN($B$2:$U$21;">"&0); "";KKLEINSTE(WENN($B$2:$U$21>0;$B$2:$U$21); ZEILE(A1)))}
X2=WENN(W2="";"";INDEX($A$1:$U$1;SPALTE(INDIREKT(Z2)))&" x "&INDEX($A$1:$A$21;ZEILE(INDIREKT(Z2))))
Y2{=WENN(W2="";"";KKLEINSTE(WENN($B$2:$U$21>0;$B$2:$U$21-ZEILE($1:$20)%%-SPALTE(B1:U1)%); ZEILE(A1)))}
Z2{=WENN(W2="";"";ADRESSE(MAX(($B$2:$U$21-ZEILE($1:$20)%%-SPALTE(B1:U1)%=Y2)*ZEILE($2:$21)); MAX(($B$2:$U$21-ZEILE($1:$20)%%-SPALTE(B1:U1)%=Y2)*SPALTE(B:U))))}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Tabelle3

 ABCDEFGHIJKLMNOPQRSTU
1 501001502002503003504004505005506006507007508008509009501000
25000000000000000000000
310000000000000000000000
4150000302800000000000000
52000000014017000000000000
625000330000000000000000
730000000000000000000000
8350120000000000000000000
940000000000000000000000
1045000000000000000000000
1150000000000000000000000
1255000000000000000000000
1360000000000000000000000
1465000000000000000000000
1570000000000000000000000
1675000000000000000000000
1780000000000000000000000
1885000000000000000000000
1990000000000000000000000
2095000000000000000000000
21100000000000000000000000


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
MfG Christian
Anzeige
AW: Auswertung Tabelle
12.10.2010 15:11:27
Christian
Hallo,
ZEILE() musst Du anpassen, Bereiche für INDEX() auch.
Lies Dich mal durch die Hilfe zu den einzelnen Formeln ;-)
Blechtafeln neu 2

 APAQARAS
4AnzahlAbmessungen  
551050 x 13504,8192$R$12
65850 x 20504,8978$J$26
761000 x 15505,8388$P$16
87850 x 13506,8992$J$12
917800 x 155016,9188$H$16
1018925 x 170017,8685$M$19
1120900 x 185019,8782$L$22
12    

Formeln der Tabelle
ZelleFormel
AP5{=WENN(ZEILE(A1)>ZÄHLENWENN($D$5:$AN$35;">"&0); "";KKLEINSTE(WENN($D$5:$AN$35>0;$D$5:$AN$35); ZEILE(A1)))}
AQ5=WENN(AP5="";"";INDEX($A$4:$AN$4;SPALTE(INDIREKT(AS5)))&" x "&INDEX($C$1:$C$35;ZEILE(INDIREKT(AS5))))
AR5{=WENN(AP5="";"";KKLEINSTE(WENN($D$5:$AN$35>0;$D$5:$AN$35-ZEILE($1:$31)%%-SPALTE(D4:AN4)%); ZEILE(A1)))}
AS5{=WENN(AP5="";"";ADRESSE(MAX(($D$5:$AN$35-ZEILE($1:$31)%%-SPALTE(D5:AN5)%=AR5)*ZEILE($5:$35)); MAX(($D$5:$AN$35-ZEILE($1:$31)%%-SPALTE(D4:AN4)%=AR5)*SPALTE(D:AN))))}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
MfG Christian
Anzeige
AW: Auswertung Tabelle
12.10.2010 15:40:11
Steffen
Ja jetzt funktionierts
Was bedeutet denn der Bezug auf "Zeile(A1)"
Das Feld ist doch gar nicht belegt?
Kann man die Sortierung absteigend anlegen?
Besten Dank
Steffen
AW: Auswertung Tabelle
12.10.2010 16:10:25
Christian
Hallo Steffen,
ZEILE(A1)=1, ZEILE(A2)=2 siehe Hilfe!
Die benötigst Du für die k (Rang) der KKLEINSTE-Formel, um sie kopierbar zu halten, damit Du nicht in jeder Zelle 1, 2 usw. für k eintragen musst!
Was meinst Du mit absteigend? Formate oder Anzahl der Tafeln?
Im ersten Thread wolltest Du noch aufsteigend ;-)
MfG Christian
AW: Auswertung Tabelle
12.10.2010 16:26:58
Steffen
Hallo Christian
Mit absteigend meine ich, daß die meisten Formate oben stehen sollen.
Also beginnend mit der größten Anzahl (oben) und unten die kleinste Anzahl.
Steffen
Anzeige
AW: Auswertung Tabelle
12.10.2010 16:34:52
Christian
Hallo,
einfach mit KKGRÖSSTE anpassen!
Hilfe zu Formeln: http://www.online-excel.de/excel/grusel.php?f=6
Blechtafeln neu 2

 APAQARAS
4AnzahlAbmessungen  
520900 x 185019,8782$L$22
6201175 x 190019,7681$W$23
718925 x 170017,8685$M$19
817800 x 155016,9188$H$16
97850 x 13506,8992$J$12
1061000 x 15505,8388$P$16
1161025 x 18005,8283$Q$21
1261025 x 18505,8282$Q$22
135850 x 20504,8978$J$26
1451050 x 13504,8192$R$12
155900 x 185019,8782$L$22
16    
17    

Formeln der Tabelle
ZelleFormel
AP5{=WENN(ZEILE(A1)>ZÄHLENWENN($D$5:$AN$35;">"&0); "";KGRÖSSTE(WENN($D$5:$AN$35>0;$D$5:$AN$35); ZEILE(A1)))}
AQ5=WENN(AP5="";"";INDEX($A$4:$AN$4;SPALTE(INDIREKT(AS5)))&" x "&INDEX($C$1:$C$35;ZEILE(INDIREKT(AS5))))
AR5{=WENN(AP5="";"";KGRÖSSTE(WENN($D$5:$AN$35>0;$D$5:$AN$35-ZEILE($1:$31)%%-SPALTE(D4:AN4)%); ZEILE(A1)))}
AS5{=WENN(AP5="";"";ADRESSE(MAX(($D$5:$AN$35-ZEILE($1:$31)%%-SPALTE(D5:AN5)%=AR5)*ZEILE($5:$35)); MAX(($D$5:$AN$35-ZEILE($1:$31)%%-SPALTE(D4:AN4)%=AR5)*SPALTE(D:AN))))}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
MfG Christian
Anzeige
Besten Dank
13.10.2010 10:46:17
Steffen
Danke, hat mir sehr weitergeholfen.
Schöne Grüße
Steffen

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige