Zufallsgenerator

Option Explicit
Sub x()
Dim wsSrc As Worksheet     ' die Quell-Tabelle
Dim rngDst As Range        ' der 'Ziel-Bereich' = die Selektion
Dim arZufall() As Long     ' Array mit allen Zeilennummern von 1 ... lngZeilen
Dim lngZufall As Long      ' eine Zufallszahl zwischen 1 ... lngZeilen
Dim lngZeilen As Long      ' Anzahl der Zeilen der Quell-Tabelle
Dim intSpalten As Integer  ' Anzahlder zu kopierenden Spalten
Dim i As Long              ' Zähler
Randomize
Set rngDst = Selection
intSpalten = rngDst.Columns.Count
Set wsSrc = Worksheets("Daten")
lngZeilen = wsSrc.Cells(wsSrc.Rows.Count, 1).End(xlUp).Row
ReDim arZufall(1 To lngZeilen)
For i = 1 To lngZeilen
arZufall(i) = i
Next
For i = 1 To rngDst.Rows.Count
' Zufallszahl zwischen 1 und lngZeilen generieren
lngZufall = Int(lngZeilen * Rnd() + 1)
' Quellzeile ist die Zeile mit der Zeilennummer arZufall(lngZufall)
wsSrc.Cells(arZufall(lngZufall), 1).Resize(, intSpalten).Copy rngDst.Cells(1).Offset(i -  _
1)
' die letzte Zeilennummer auf die gerade gezogene Zeilennummer umkopieren
arZufall(lngZufall) = arZufall(lngZeilen)
' und dann einfach die Arraygrösse erniedrigen
lngZeilen = lngZeilen - 1
Next
End Sub
Private Sub CommandButton1_Click()
Call x
End Sub