AW: Kalenderdatum verknüpfen
04.01.2011 19:44:40
Josef
Hallo Jörn,
kopiere den folgenden Code in das Modul von Tabelle "Kalender".
Mit eine Dppelklick auf ein Datum wird das Bild angezeigt.
' **********************************************************************
' Modul: Tabelle19 Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************
Option Explicit
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim vntRet As Variant, lngLast As Long, objShp As Shape
deleteShape
If IsDate(Target) Then
Cancel = True
With Sheets("Fahrtenbuch")
vntRet = Application.Match(Target, .Columns(2), 0)
If IsNumeric(vntRet) Then
lngLast = .Cells(vntRet, 2).End(xlDown).Row - 1
.Range(.Cells(vntRet, 1), .Cells(lngLast, 7)).Copy
Me.Pictures.Paste
For Each objShp In Me.Shapes
If objShp.Name Like "Picture*" Then Exit For
Next
If Not objShp Is Nothing Then
With objShp
.Top = Target.Top
.Left = Target.Left + Target.Width
.Fill.Visible = msoTrue
.Fill.ForeColor.RGB = RGB(155, 155, 155)
.ScaleHeight 0.7, msoTrue
.Name = "Info"
.OnAction = "Tabelle19.deleteShape"
End With
End If
Else
MsgBox "Kein Eintrag im Fahrtenbuch!"
End If
End With
End If
End Sub
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
deleteShape
End Sub
Sub deleteShape()
On Error Resume Next
Me.Shapes("Info").Delete
On Error GoTo 0
End Sub
Gruß Sepp