Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1196to1200
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Wert suchen und Bereich in gefundener Zeile kop.

Wert suchen und Bereich in gefundener Zeile kop.
Marc
Hallo Forenmitglieder,
ich bin neu hier im Forum und meine VBA Kenntnisse sind sehr bescheiden. Auch nach längerem Suchen bin ich bei meiner Aufgabenstellung bisher nicht weiter gekommen. Vielleicht könnt ihr mir helfen.
Das Makro soll die Spalte B (= Kalenderwoche) in einem Tabellenblatt (hierbei handelt es sich um eine Liste mit bis zu 500 Zeilen) nach der letzten Kalenderwoche durchsuchen. Der Wert der letzten KW steht in einem anderen Tabellenblatt. Bei allen Zeilen mit übereinstimmenden Werten (= Kalenderwochen) sollen jeweils die Spalten c:f kopiert werden und an eine bestimmte Stelle in einem anderen Tabellenblatt untereinander geschrieben werden.
Vielen Dank.
Marc.

3
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Benutzer
Anzeige
AW: Wert suchen und Bereich in gefundener Zeile kop.
23.01.2011 09:06:06
fcs
Hallo Marc,
hier ein Beispielmakro, das du bzgl. der Tabellennamen und Konstanten noch anpassen muss.
Gruß
Franz
Sub KW_Daten_Uebertragen()
Dim wksDaten As Worksheet, wksEingabe As Worksheet, wksZiel As Worksheet
Dim ZeileDaten As Long, ZeileZiel As Long, Spalte As Long
Dim vSuchen
Const ZelleKW As String = "C5" 'Eingabezelle für zu suchende KW
Const SpalteZiel As Long = 1 'EinfügeSpalte in Zieltabelle
Const ZeileZiel1 As Long = 4 'Zeile in der Einfügen beginnen soll wenn _
noch keine Daten vorhanden
Set wksDaten = Worksheets("Daten")     'Blatt in dem alle KW-Daten stehen
Set wksEingabe = Worksheets("Eingabe") 'Blatt in dem die zu suchende KW eingegeben wird
Set wksZiel = Worksheets("Ziel")       'Blatt in das Daten der KW kopiert werden sollen
'zu suchende KW einlesen
vSuchen = wksEingabe.Range(ZelleKW).Value
'1. Zielzeile ermitteln
With wksZiel
ZeileZiel = ZeileZiel1
For Spalte = SpalteZiel To SpalteZiel + 3
ZeileZiel = Application.WorksheetFunction.Max(ZeileZiel, _
.Cells(.Rows.Count, Spalte).End(xlUp).Row + 1)
Next
End With
'KW in Datentabelle suchen
With wksDaten
Application.ScreenUpdating = False
For ZeileDaten = 2 To .Cells(.Rows.Count, 2).End(xlUp).Row
If .Cells(ZeileDaten, 2).Value = vSuchen Then
'Zellen aus Spalten C:F kopieren
.Range(.Cells(ZeileDaten, 3), .Cells(ZeileDaten, 6)).Copy _
Destination:=wksZiel.Cells(ZeileZiel, SpalteZiel)
ZeileZiel = ZeileZiel + 1
End If
Next
Application.ScreenUpdating = True
End With
End Sub

Anzeige
AW: Wert suchen und Bereich in gefundener Zeile kop.
23.01.2011 16:26:53
Marc
Hallo Tino, hallo Franz,
Eure Lösungen funktionieren. Super. Vielen Dank.
Grüße, Marc.

337 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige