AW: API - Shape aus Worksheet in Userform
13.11.2011 17:53:09
Nepumuk
Hallo,
da gibt es mehrere Möglichkeiten, so z.B.:
Option Explicit
Private Declare Function OleCreatePictureIndirect Lib "olepro32.dll" ( _
ByRef PicDesc As PIC_DESC, _
ByRef RefIID As GUID, _
ByVal fPictureOwnsHandle As Long, _
ByRef IPic As IPictureDisp) As Long
Private Declare Function CopyImage Lib "user32.dll" ( _
ByVal handle As Long, _
ByVal un1 As Long, _
ByVal n1 As Long, _
ByVal n2 As Long, _
ByVal un2 As Long) As Long
Private Declare Function IsClipboardFormatAvailable Lib "user32.dll" ( _
ByVal wFormat As Integer) As Long
Private Declare Function OpenClipboard Lib "user32.dll" ( _
ByVal hWnd As Long) As Long
Private Declare Function GetClipboardData Lib "user32.dll" ( _
ByVal wFormat As Integer) As Long
Private Declare Function EmptyClipboard Lib "user32.dll" () As Long
Private Declare Function CloseClipboard Lib "user32.dll" () As Long
Private Type GUID
Data1 As Long
Data2 As Integer
Data3 As Integer
Data4(0 To 7) As Byte
End Type
Private Type PIC_DESC
lngSize As Long
lngType As Long
lnghPic As Long
lnghPal As Long
End Type
Private Const PICTYPE_BITMAP = 1
Private Const CF_BITMAP = 2
Private Const IMAGE_BITMAP = 0
Private Const LR_COPYRETURNORG = &H4
Private Const GC_CLASSNAMEMSEXCEL = "XLMAIN"
Private Function Paste_Picture() As IPictureDisp
Dim lngReturn As Long, lngCopy As Long, lngPointer As Long
If IsClipboardFormatAvailable(CF_BITMAP) <> 0 Then
lngReturn = OpenClipboard(Application.hWnd)
If lngReturn > 0 Then
lngPointer = GetClipboardData(CF_BITMAP)
lngCopy = CopyImage(lngPointer, IMAGE_BITMAP, 0, 0, LR_COPYRETURNORG)
Call CloseClipboard
If lngPointer <> 0 Then Set Paste_Picture = Create_Picture(lngCopy)
End If
End If
End Function
Private Function Create_Picture( _
ByVal plnghPic As Long) As IPictureDisp
Dim udtPicInfo As PIC_DESC, udtID_IDispatch As GUID
Dim objPicture As IPictureDisp
With udtID_IDispatch
.Data1 = &H20400
.Data4(0) = &HC0
.Data4(7) = &H46
End With
With udtPicInfo
.lngSize = Len(udtPicInfo)
.lngType = PICTYPE_BITMAP
.lnghPic = plnghPic
.lnghPal = 0
End With
Call OleCreatePictureIndirect(udtPicInfo, udtID_IDispatch, 0&, objPicture)
Set Create_Picture = objPicture
End Function
Private Function GetPicture() As Boolean
Dim objShape As Shape
Dim blnFound As Boolean
With ThisWorkbook.Sheets("Tabelle1")
For Each objShape In .Shapes
If objShape.Name = "GroupSh" Then
objShape.CopyPicture Appearance:=xlScreen, Format:=xlBitmap
GetPicture = True
Exit For
End If
Next
End With
End Function
Private Sub CommandButton1_Click()
Unload Me
End Sub
Private Sub UserForm_Activate()
Dim objPicture As IPictureDisp
Call CreateShape
If GetPicture Then
Set objPicture = Paste_Picture
If Not objPicture Is Nothing Then
UserForm1.Image1.Picture = objPicture
Else
MsgBox "''GroupSh'' can't show", vbCritical, "Error"
End If
Else
MsgBox "Shape ''GroupSh'' not found", vbCritical, "Error"
End If
End Sub
Ich benutz aber ein Image-Control denn das ist dafür gedacht Bilder anzuzeigen.
Gruß
Nepumuk