Live-Forum - Die aktuellen Beiträge
Datum
Titel
20.04.2024 00:49:19
Excel Sheet in einen Excel Kalender einfügen
20.04.2024 00:08:11
In Ordner nur das Speichern von Dateien erlauben
19.04.2024 21:26:15
mehrfache Texte finden
19.04.2024 19:41:34
Bei VBA Ausführung Anzeige einfrieren
Du findest keine passende Antwort auf Deine Frage?
Stelle Deine Frage in unserem Live-Forum
Anzeige
Archiv - Navigation
1240to1244
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1240to1244
1240to1244
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

zwei Dateien vergleichen

zwei Dateien vergleichen
Selina
Guten Tag !
Ich stehe vor einem bisher für mich unlösbaren Problem. Zwar bin ich auf meiner Suche zu unzähligen ähnlichen Posts gestossen, allerdings fand ich bisher die beste Lösung noch nicht :-(
Und zwar gehts um folgendes:
Ich möchte mittels einem Makro zwei Excel Dateien zusammen vergleichen (da vertrauliche Daten, kann ich diese leider hier nicht als Beispiele hochladen)
Beide Dateien sind - bis auf die Spalte E unterschiedlich aufgebaut.
Spalte E beinhaltet immer eine 4 stellige Zahl (in beiden Dateien gibts die Spalte E mit 4-stelligem Zahleninhalt)
Nun möchte ich ab einem dritten File (da wo das Makro drinsteht) folgendes machen:
- Excel-Datei 1 öffnen (Dateinamen kann immer unterschiedlich sein)
- Excel-Datei 2 öffnen (Dateinamen kann immer unterschiedlich sein)
- Makro starten
nun sollen die Spalten E der beiden Excel-Files miteinander verglichen werden.
als Output soll in einem Tabellenblatt (in der Mappe aus welcher ich das Makro startete)
folgendes Zurückkommen:
Zahl aus Spalte E
Text: "in beiden Dateien vorhanden" oder Text "nur in Datei 1 vorhanden" oder Text "nur in Datei 2 vorhanden".
geht das irgendwie ?
Ich hab echt keine Ahnung wie ich das angehen soll.
Wäre wirklich super, wenn mir hier jemand weiterhelfen könnte. (evt. hat jemand bereits ein ähnliches Beispiel ?)
im voraus HERZLICHEN DANK !

17
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Benutzer
Anzeige
AW: zwei Dateien vergleichen
12.12.2011 12:40:17
Rudi
Hallo,
in ein Modul: 
Sub Vergleich()
Dim oVergleich As Object, arrVergleich, lngI As Long
Dim strFile1 As String, strFile2 As String, wkb As Workbook
With Application.FileDialog(msoFileDialogFilePicker)
.Title = "Datei 1 auswählen"
.AllowMultiSelect = False
.InitialFileName = "*.xls"
If .Show = -1 Then
strFile1 = .SelectedItems(1)
End If
End With
If strFile1 = "" Then
MsgBox "Abbruch"
Exit Sub
End If
With Application.FileDialog(msoFileDialogFilePicker)
.Title = "Datei 2 auswählen"
.AllowMultiSelect = False
.InitialFileName = "*.xls"
If .Show = -1 Then
strFile2 = .SelectedItems(1)
End If
End With
If strFile2 = "" Then
MsgBox "Abbruch"
Exit Sub
End If
Application.ScreenUpdating = False
Set oVergleich = CreateObject("Scripting.dictionary")
Set wkb = Workbooks.Open(strFile1)
With wkb.Sheets(1)
arrVergleich = .Range(.Cells(2, 5), .Cells(Rows.Count, 5).End(xlUp))
End With
For lngI = LBound(arrVergleich) To UBound(arrVergleich)
oVergleich(arrVergleich(lngI, 1)) = "In Datei 1 vorhanden"
Next
wkb.Close False
Set wkb = Workbooks.Open(strFile2)
With wkb.Sheets(1)
arrVergleich = .Range(.Cells(2, 5), .Cells(Rows.Count, 5).End(xlUp))
End With
For lngI = LBound(arrVergleich) To UBound(arrVergleich)
If oVergleich.exists(arrVergleich(lngI, 1)) Then
oVergleich(arrVergleich(lngI, 1)) = "In beiden Dateien vorhanden"
Else
oVergleich(arrVergleich(lngI, 1)) = "In Datei 2 vorhanden"
End If
Next
wkb.Close False
With Worksheets.Add
.Cells(1, 1).Resize(oVergleich.Count) = Application.Transpose(oVergleich.keys)
.Cells(1, 2).Resize(oVergleich.Count) = Application.Transpose(oVergleich.items)
End With
End Sub

Gruß
Rudi
Anzeige
AW: zwei Dateien vergleichen
12.12.2011 13:17:13
Selina
Hei Rudi !
schon vorab mal vielen herzlichen Dank für die superschnelle Hilfe !
werde mir diesen toll aussehenden Code gleich mal zu Gemüte führen und testen.
Danke schon mal herzlich !
AW: zwei Dateien vergleichen
12.12.2011 15:07:53
Selina
Hallo nochmals !
Also ... dieses Makro läuft ja wirklich sensationell gut !
Doch ein paar Kleinigkeiten werde ich noch anpassen müssen (wenn ich bloss wüsste wie :-(
Und zwar:
Habe bemerkt, dass die beiden zu öffnenden Dateien sich bezüglich Formatierung auch etwas unterscheiden.
D.h. das erste File ist alles OK
im zweiten File hat es meist noch als Text gespeicherte Zahlen in der Spalte E.
Und genau die machen dann Probleme.
Nun stell ich mir die Frage:
Wie müsste ich den Code anpassen, wenn ich
- beim öffnen der zweiten Datei gleichzeitig noch die Formatierung aus dem ersten File mitgeben will ?
Ich meine ....
wenn ich jetzt vor dem File-öffnen das Format der ersten Datei mittels Pinsel in das zweite File übertrage und beide Dateien so speichere, dann läuft das Makro einwandfrei.
Ach ja ... warum unterschiedliche Formatierungen ? - weil beide Files aus zwei verschiedenen Systemen exportiert werden.
Geht mein Wunsch irgendwie umzusetzen ? (also Formatierung aus der ersten Datei auf die zweite übertragen)
Herzlichen Dank !
Anzeige
AW: zwei Dateien vergleichen
12.12.2011 15:46:46
Rudi
Hallo,
dann wandeln wir einfach in Zahlen um. 
Sub Vergleich()
Dim oVergleich As Object, arrVergleich, lngI As Long
Dim strFile1 As String, strFile2 As String, wkb As Workbook
Const strDat1 As String = "In Datei 1 vorhanden"
Const strDat2 As String = "In Datei 2 vorhanden"
Const strBeide As String = "In beiden Dateien vorhanden"
With Application.FileDialog(msoFileDialogFilePicker)
.Title = "Datei 1 auswählen"
.AllowMultiSelect = False
.InitialFileName = "*.xls"
If .Show = -1 Then
strFile1 = .SelectedItems(1)
End If
End With
If strFile1 = "" Then
MsgBox "Abbruch"
Exit Sub
End If
With Application.FileDialog(msoFileDialogFilePicker)
.Title = "Datei 2 auswählen"
.AllowMultiSelect = False
.InitialFileName = "*.xls"
If .Show = -1 Then
strFile2 = .SelectedItems(1)
End If
End With
If strFile2 = "" Then
MsgBox "Abbruch"
Exit Sub
End If
Application.ScreenUpdating = False
Set oVergleich = CreateObject("Scripting.dictionary")
oVergleich("Nr.") = "Ergebnis"
Set wkb = Workbooks.Open(strFile1)
With wkb.Sheets(1)
arrVergleich = .Range(.Cells(2, 5), .Cells(Rows.Count, 5).End(xlUp))
End With
For lngI = LBound(arrVergleich) To UBound(arrVergleich)
oVergleich(CInt(arrVergleich(lngI, 1))) = strDat1
Next
wkb.Close False
Set wkb = Workbooks.Open(strFile2)
With wkb.Sheets(1)
arrVergleich = .Range(.Cells(2, 5), .Cells(Rows.Count, 5).End(xlUp))
End With
For lngI = LBound(arrVergleich) To UBound(arrVergleich)
If oVergleich.exists(CInt(arrVergleich(lngI, 1))) Then
oVergleich(CInt(arrVergleich(lngI, 1))) = strBeide
Else
oVergleich(CInt(arrVergleich(lngI, 1))) = strDat2
End If
Next
wkb.Close False
With Worksheets.Add
.Cells(1, 1).Resize(oVergleich.Count) = Application.Transpose(oVergleich.keys)
.Cells(1, 2).Resize(oVergleich.Count) = Application.Transpose(oVergleich.items)
.Columns.AutoFit
.Cells(1, 1).Sort key1:=.Cells(2, 1), order1:=xlAscending, header:=xlYes
End With
End Sub

Gruß
Rudi
Anzeige
AW: zwei Dateien vergleichen
12.12.2011 16:30:40
Selina
Hallo Rudi
Herzlichen Dank für Deine Hilfe !
Aber ...
das Makro bricht nun bei der Zeile hier ab:
oVergleich(CInt(arrVergleich(lngI, 1))) = strDat1
Fehlermeldung: Überlauf
:-/
Grummel ! Was muss ich ändern ?
AW: zwei Dateien vergleichen
12.12.2011 22:44:12
Rudi
Hallo,
mach mal aus CInt überall CLng
Wobei: du hattest was von 4-stelligen Zahlen geschrieben. Die können eigentlich nicht größer als 9999 werden.
Gruß
Rudi
AW: zwei Dateien vergleichen
13.12.2011 10:32:16
Selina
Hallo Rudi !
ich werde das gleich mal probieren.
Habe soeben bemerkt, dass es zwischendurch wohl auch 5 Stellige Zahlen geben kann :-(
Optimierung
13.12.2011 10:42:08
Rudi
Hallo,
das sollte alles erschlagen: 
Sub Vergleich()
Dim oVergleich As Object, arrVergleich, lngI As Long
Dim strFile1 As String, strFile2 As String, wkb As Workbook
Dim strDat As String, vntMatch
Const strBeide As String = "In beiden Dateien vorhanden"
With Application.FileDialog(msoFileDialogFilePicker)
.Title = "Datei 1 auswählen"
.AllowMultiSelect = False
.InitialFileName = "*.xls"
If .Show = -1 Then
strFile1 = .SelectedItems(1)
End If
End With
If strFile1 = "" Then
MsgBox "Abbruch"
Exit Sub
End If
With Application.FileDialog(msoFileDialogFilePicker)
.Title = "Datei 2 auswählen"
.AllowMultiSelect = False
.InitialFileName = "*.xls"
If .Show = -1 Then
strFile2 = .SelectedItems(1)
End If
End With
If strFile2 = "" Then
MsgBox "Abbruch"
Exit Sub
End If
Application.ScreenUpdating = False
Set oVergleich = CreateObject("Scripting.dictionary")
oVergleich("Nr.") = "Ergebnis"
Set wkb = Workbooks.Open(strFile1)
strDat = "In " & wkb.Name & " vorhanden"
With wkb.Sheets(1)
arrVergleich = .Range(.Cells(2, 5), .Cells(Rows.Count, 5).End(xlUp))
End With
For lngI = LBound(arrVergleich) To UBound(arrVergleich)
vntMatch = arrVergleich(lngI, 1)
If IsNumeric(vntMatch) Then vntMatch = vntMatch + 0
oVergleich(vntMatch) = strDat
Next
wkb.Close False
Set wkb = Workbooks.Open(strFile2)
strDat = "In " & wkb.Name & " vorhanden"
With wkb.Sheets(1)
arrVergleich = .Range(.Cells(2, 5), .Cells(Rows.Count, 5).End(xlUp))
End With
For lngI = LBound(arrVergleich) To UBound(arrVergleich)
vntMatch = arrVergleich(lngI, 1)
If IsNumeric(vntMatch) Then vntMatch = vntMatch + 0
If oVergleich.exists(vntMatch) Then
oVergleich(vntMatch) = strBeide
Else
oVergleich(vntMatch) = strDat
End If
Next
wkb.Close False
With Worksheets.Add
.Cells(1, 1).Resize(oVergleich.Count) = Application.Transpose(oVergleich.keys)
.Cells(1, 2).Resize(oVergleich.Count) = Application.Transpose(oVergleich.items)
.Columns.AutoFit
.Cells(1, 1).Sort key1:=.Cells(2, 1), order1:=xlAscending, header:=xlYes
End With
End Sub

Gruß
Rudi
Anzeige
AW: Optimierung
13.12.2011 11:15:36
Selina
Hallo Rudi !
noch ein neuer toller Code ?! :-)
FREU !!!
Ich werde mir diesen gleich mal austesten.
AW: Optimierung
13.12.2011 11:20:02
Selina
Einfach sensationell dieser Code !!!
genau was ich brauche :-)
Jetzt muss ich bloss noch ne Möglichkeit finden, nebst den Werten aus Spalte E (da stehen ja diese Zahlen drin) auch noch die Werte der Spalten F + G im Resultatefile auszugeben.
Geht das irgendwie ?
AW: Optimierung
13.12.2011 11:46:28
Rudi
Hallo,
sicher geht das. 
Sub Vergleich2()
Dim oVergleich As Object, arrVergleich, lngI As Long
Dim strFile1 As String, strFile2 As String, wkb As Workbook
Dim strDat As String, vntMatch
Dim arrErg(), vntTmp, arrKeys, arrItems
Const strBeide As String = "In beiden Dateien vorhanden"
With Application.FileDialog(msoFileDialogFilePicker)
.Title = "Datei 1 auswählen"
.AllowMultiSelect = False
.InitialFileName = "*.xls"
If .Show = -1 Then
strFile1 = .SelectedItems(1)
End If
End With
If strFile1 = "" Then
MsgBox "Abbruch"
Exit Sub
End If
With Application.FileDialog(msoFileDialogFilePicker)
.Title = "Datei 2 auswählen"
.AllowMultiSelect = False
.InitialFileName = "*.xls"
If .Show = -1 Then
strFile2 = .SelectedItems(1)
End If
End With
If strFile2 = "" Then
MsgBox "Abbruch"
Exit Sub
End If
Application.ScreenUpdating = False
Set oVergleich = CreateObject("Scripting.dictionary")
oVergleich("Nr.") = Array("Ergebnis", "F", "G")
Set wkb = Workbooks.Open(strFile1)
strDat = "In " & wkb.Name & " vorhanden"
With wkb.Sheets(1)
arrVergleich = .Range(.Cells(2, 5), .Cells(Rows.Count, 5).End(xlUp)).Resize(, 3)
End With
For lngI = LBound(arrVergleich) To UBound(arrVergleich)
vntMatch = arrVergleich(lngI, 1)
If IsNumeric(vntMatch) Then vntMatch = vntMatch + 0
oVergleich(vntMatch) = Array(strDat, arrVergleich(lngI, 2), arrVergleich(lngI, 3))
Next
wkb.Close False
Set wkb = Workbooks.Open(strFile2)
strDat = "In " & wkb.Name & " vorhanden"
With wkb.Sheets(1)
arrVergleich = .Range(.Cells(2, 5), .Cells(Rows.Count, 5).End(xlUp)).Resize(, 3)
End With
For lngI = LBound(arrVergleich) To UBound(arrVergleich)
vntMatch = arrVergleich(lngI, 1)
If IsNumeric(vntMatch) Then vntMatch = vntMatch + 0
If oVergleich.exists(vntMatch) Then
vntTmp = oVergleich(vntMatch)
vntTmp(0) = strBeide
oVergleich(vntMatch) = vntTmp
Else
oVergleich(vntMatch) = Array(strDat, arrVergleich(lngI, 2), arrVergleich(lngI, 3))
End If
Next
wkb.Close False
arrKeys = oVergleich.Keys
arrItems = oVergleich.Items
ReDim arrErg(1 To oVergleich.Count, 1 To 4)
For lngI = 0 To oVergleich.Count - 1
arrErg(lngI + 1, 1) = arrKeys(lngI)
arrErg(lngI + 1, 2) = arrItems(lngI)(0)
arrErg(lngI + 1, 3) = arrItems(lngI)(1)
arrErg(lngI + 1, 4) = arrItems(lngI)(2)
Next
With Worksheets.Add
.Cells(1, 1).Resize(oVergleich.Count, 4) = arrErg
.Columns.AutoFit
.Cells(1, 1).Sort key1:=.Cells(2, 1), order1:=xlAscending, header:=xlYes
End With
End Sub

Gruß
Rudi
Anzeige
AW: Optimierung
13.12.2011 13:51:41
Selina
SENSATIONELL !!!!!!!
Vielen herzlichen Dank !
Nun werde ich das ganze Makro noch ein wenig zu Gemüte ziehen um wieder was dazuzulernen.
Evt. werde ich noch irgenwelche Routine / Code einbauen müssen, der mir die Spalten in beiden Files ans gleiche Ort schiebt.
Denn... im Moment ist es so, dass das erste File die Spalten G und F anders gefüllt hat als das zweite File.
Ziel soll es ja doch aber sein, dass im Resultate-File alles was zusammengehört dann auch untereinander in der gleichen Spalte stehen.
Beispiel:
In File 1 stehen in Spalte E eine 4 Stellige Zahl, in Spalte F ein Ort und in Spalte G ein Text-Code
Im zweiten File steht in Spalte E eine 4 stellige Zahl, in Spalte F steht nichts, in Spalte G steht ein Ort
den Textcode gibts im zweiten File nicht.
Ziel muss es schliesslich sein, immer die gleichen werte im Ziel-File dann auch in der gleichen Spalte untereinander zu schreiben.
Also...
Spalte A: Nr.
Spalte B: Ergebnis
Spalte C: Ort (aus dem ersten File die Spalte F, aus dem zweiten File die Spalte G
Spalte D: Text Code aus File 1
Anzeige
AW: Optimierung
13.12.2011 14:02:07
Rudi
Hallo,
sollte so gehen: 

Set wkb = Workbooks.Open(strFile2)
strDat = "In " & wkb.Name & " vorhanden"
With wkb.Sheets(1)
arrVergleich = .Range(.Cells(2, 5), .Cells(Rows.Count, 5).End(xlUp)).Resize(, 3)
End With
For lngI = LBound(arrVergleich) To UBound(arrVergleich)
vntMatch = arrVergleich(lngI, 1)
If IsNumeric(vntMatch) Then vntMatch = vntMatch + 0
If oVergleich.exists(vntMatch) Then
vntTmp = oVergleich(vntMatch)
vntTmp(0) = strBeide
oVergleich(vntMatch) = vntTmp
Else
oVergleich(vntMatch) = Array(strDat, arrVergleich(lngI, 3), "")
End If
Next
wkb.Close False
...

Gruß
Rudi
Anzeige
AW: Optimierung
13.12.2011 15:45:21
Selina
Hallo Rudi !
Es ist einfach wirklich äusserst Sensationell wie Du mir hier hilfst ! DANKE TAUSEND MAL !!!!!
Genau was ich brauche. Ich komme meinem Wunschresultat immer näher :-)
Nun muss ich noch folgendes hinzufügen:
Die erste Datei die geöffnet wird kommt von einem System-Export her.
Das File hat leider noch unnützliche Informationen drin.
D.h. nun möchte ich gleich beim öffnen des Files die ersten 13 Zeilen (inkl. zweier Grafiken dort drin) komplett rauslöschen.
Denn der erste Datensatz steht im ersten File immer in Zeile 14
Dann solle das File so lange sein, wie in Spalte E Daten vorhanden sind.
Also sobald Spalte E keine Werte mehr drin hat (= letzter Datensatz) so solle alles was darunter in den Zeilen steht (ist auch unnötiger Info-Text aus dem Export) gelöscht werden.
Bei der zweiten Datei wird es leider wohl noch schwieriger :-(
hier sind beim Öffnen der Datei immer zuerst die ersten 9 Zeilen zu löschen (= unnötige Informationen) Der erste Datensatz steht immer in Zeile 10.
Problem beim zweiten File dürfte allerdings sein, dass die Datensätze immer nach ein paar Zeilen durch eine Zeile, welche in der Spalte D das Wort "Kalender" enthält unterbrochen wird. Es folgen dann immer 3 unnötige Zeilen und weiter gehts mit dem nächsten Datensatz. etc...
Es sind also immer die Zeilen mit dem Wort "Kalender" zu finden und inkl. drei weiterer Zeilen zu löschen (also immer 4 Zeilen löschen, damit die Datensätze nicht unterbrochen werden)
Den Schluss des zweiten Files erkennt man an der Zeile mit dem Text "Mandant"
Diese Zeile muss dann auch gelöscht werden.
Erst wenn beide Dateien dementsprechend aufbereitet wurden (resp. alle unnötigen Zeilen gelöscht wurden) soll das Vergleichen beginnen.
Geht das ?
Wenn ich diese beiden Sachen auch noch implementieren kann, so öffne ich dann die Flasche Champagner ! :-)
resp. dann ist das Resultat wirklich perfekt und fertig ! :-)
Anzeige
Optimierung Step2
13.12.2011 16:55:34
Rudi
Hallo,
das kann ich nicht testen: 
Sub Vergleich2()
Dim oVergleich As Object, arrVergleich, lngI As Long
Dim strFile1 As String, strFile2 As String, wkb As Workbook
Dim strDat As String, vntMatch
Dim arrErg(), vntTmp, arrKeys, arrItems
Dim oShp As Shape
Const strBeide As String = "In beiden Dateien vorhanden"
With Application.FileDialog(msoFileDialogFilePicker)
.Title = "Datei 1 auswählen"
.AllowMultiSelect = False
.InitialFileName = "*.xls"
If .Show = -1 Then
strFile1 = .SelectedItems(1)
End If
End With
If strFile1 = "" Then
MsgBox "Abbruch"
Exit Sub
End If
With Application.FileDialog(msoFileDialogFilePicker)
.Title = "Datei 2 auswählen"
.AllowMultiSelect = False
.InitialFileName = "*.xls"
If .Show = -1 Then
strFile2 = .SelectedItems(1)
End If
End With
If strFile2 = "" Then
MsgBox "Abbruch"
Exit Sub
End If
Application.ScreenUpdating = False
Set oVergleich = CreateObject("Scripting.dictionary")
oVergleich("Nr.") = Array("Ergebnis", "F", "G")
Set wkb = Workbooks.Open(strFile1)
strDat = "In " & wkb.Name & " vorhanden"
With wkb.Sheets(1)
For Each oShp In .Shapes
oShp.Delete
Next
.Rows("1:13").Delete
arrVergleich = .Range(.Cells(1, 5), .Cells(1, 5).End(xlDown)).Resize(, 3)
End With
For lngI = LBound(arrVergleich) To UBound(arrVergleich)
vntMatch = arrVergleich(lngI, 1)
If IsNumeric(vntMatch) Then vntMatch = vntMatch + 0
oVergleich(vntMatch) = Array(strDat, arrVergleich(lngI, 2), arrVergleich(lngI, 3))
Next
wkb.Close False
Set wkb = Workbooks.Open(strFile2)
strDat = "In " & wkb.Name & " vorhanden"
With wkb.Sheets(1)
.Rows("1:9").Delete
.Cells.Find(what:="Mandant", LookIn:=xlValues, lookat:=xlWhole).EntireRow.Delete
For lngI = .Cells(Rows.Count, 4).End(xlUp).Row To 1 Step -1
If .Cells(lngI, 4) = "Kalender" Then .Cells(lngI, 1).Resize(4).EntireRow.Delete
Next lngI
arrVergleich = .Range(.Cells(1, 5), .Cells(Rows.Count, 5).End(xlUp)).Resize(, 3)
End With
For lngI = LBound(arrVergleich) To UBound(arrVergleich)
vntMatch = arrVergleich(lngI, 1)
If IsNumeric(vntMatch) Then vntMatch = vntMatch + 0
If oVergleich.exists(vntMatch) Then
vntTmp = oVergleich(vntMatch)
vntTmp(0) = strBeide
oVergleich(vntMatch) = vntTmp
Else
oVergleich(vntMatch) = Array(strDat, arrVergleich(lngI, 3), "")
End If
Next
wkb.Close False
arrKeys = oVergleich.Keys
arrItems = oVergleich.Items
ReDim arrErg(1 To oVergleich.Count, 1 To 4)
For lngI = 0 To oVergleich.Count - 1
arrErg(lngI + 1, 1) = arrKeys(lngI)
arrErg(lngI + 1, 2) = arrItems(lngI)(0)
arrErg(lngI + 1, 3) = arrItems(lngI)(1)
arrErg(lngI + 1, 4) = arrItems(lngI)(2)
Next
With Worksheets.Add
.Cells(1, 1).Resize(oVergleich.Count, 4) = arrErg
.Columns.AutoFit
.Cells(1, 1).Sort key1:=.Cells(2, 1), order1:=xlAscending, header:=xlYes
End With
End Sub

Gruß
Rudi
Anzeige
AW: Optimierung Step2
14.12.2011 09:17:16
Selina
Hallo Rudi !
Guten Tag !
Vorerst mal vielen, vielen herzlichen Dank für Deine grossartige, unübertreffbare Hilfe !
ich werde mir den Code gleich mal anschauen und testen.
Feddback folgt dann selbstverständlich
AW: Optimierung Step2
14.12.2011 09:53:21
Selina
ES LÄUUUUUUUUUFT !!!!!!
VIELEN VIELEN VIELEN HERZLICHEN DANK LIEBER RUDI !!!!
Ohne Dich hätt ich das wohl nie sooo schnell hingekriegt !!!

43 Forumthreads zu ähnlichen Themen

2 Zellen aus verschiedenen Dateien vergleichen
Joni

Hi,
ich sollte die Werte aus 2 Zellen aus verschiedenen Dateien miteinander vergleichen und verwende dafür folgende Zeile:
If .Cells(j, 2) = Workbooks(DNSB).Worksheets(Bericht1).Cells(jj, 2) Then
Leider erhalte ich immer eine Fehler. Ich habe auch schon andere Varianten probiert. Do...
08.06.2009 00:57:53
Thread-ID: 1079774
8 Beiträge
Anzeige
2 Tabellen aus 2 Dateien miteinander vergleichen
Frank

Hallo zusammen,
Ich habe hier noch mal was für die Excel Cracks
Ausgangslage:
Protokolldatei (in dieser Datei befinden sich die Makros; und letztendlich die kopierten Zeilen in denen Unterschiede gefunden wurden)
Aus der Protokolldatei heraus (Datei1 Tabelle Monat07; Datei2 Tabe...
10.09.2009 02:30:35
Thread-ID: 1101552
2 Beiträge
2 Dateien vergleichen und Wert ausgaben
Andreas

Hallo Community,
ich habe 2 Dateien, welche in Spalte B identische Werte hat, jedoch willkürlich verteilt. Sprich Zelle B5 in Datei 1 kann in Datei 2 Zelle B13 sein. Datei 1 (Datei.1-Bearbeitung) ist die Datei, welche immer bearbeitet wird. Datei 2 (Datei.2-Check) benötigt jedoch immer den...
07.04.2012 11:17:49
Thread-ID: 1258255
6 Beiträge
Anzeige
Excel 2010-Dateien vergleichen - alte Mitglieder e
Ardona

Guten Abend
Ich habe alte Tabellen aus verschiedenen Regionen, wo die Mitglieder wie folgt gelistet sind:
Nachname (Spalte A), Vorname (Spalte B), E-Mail-Adresse (Spalte C), Herr oder Frau (Spalte D), Stasse (Spalte E) etc.
Die Mitglieder sind alphabetisch von A-Z (Spalte A) geordne...
19.07.2013 14:38:35
Thread-ID: 1323256
3 Beiträge
Zellen inhalte zwischen 2 Dateien vergleichen
HerrA

Hallo zusammen,
kann mir jemand helfen?
Ich habe in einer Datei einen Wert in einer Zelle stehen. Nun soll in einer anderen Datei (immer die Gleiche) die Zeilen nach dem Wert (der immer in der gleichen Spalte C steht) durchsucht werden. Sobald in der Spalte C der Wert gefunden wurde sol...
01.04.2014 12:47:45
Thread-ID: 1355664
6 Beiträge
2 Dateien vergleichen
Thomas

Hi,
hab da wieder mal ne frage^^
ich hab zwei Dateien.
Datei 1 wurde am Montag angelegt, da sind sehr viele Werte, text, etc hinterlegt.
Datei 2 wurde am Mittwoch angelegt, da sind manche Werte, texte etc von Montag verändert worden, manche nicht, es sind aber auch neue dazu gek...
14.04.2014 12:04:24
Thread-ID: 1357227
6 Beiträge
2 Dateien vergleichen
Michael

Hallo!
Folgendes Problem hab ich. Ich muss 2 Tabellen miteinander vergleichen.
Tabellen Blatt 1 (meine aktiven Angebote)
Spalte A: EAN Code
Spalte B; Warenbeschreibung
Tabellen Blatt 2 (Bestand des Großhändlers)
Spalte A: EAN Code
Spalte B: Warenbeschreibung
Spal...
24.12.2014 10:53:27
Thread-ID: 1399520
2 Beiträge
Zellen vergleichen - zwei Excel Dateien
Stefan

Huhu,
ich würde gern z.B. die komplette Spalte "C" aus 2 verschiedenen Excel-Dateien vergleichen und wenn es eine Dopplung gibt die jeweilige Zeile in farbig makieren...
ich habe leider nur wenig VBA-Kenntnisse und weis nicht genau ob ich auf dem richtigen Weg bin :) vielleicht könnt ih...
05.05.2015 14:23:16
Thread-ID: 1424709
2 Beiträge
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Jetzt das Excel-Portal bewerten: Deine Stimme zählt!

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige
Archiv - Verwandte Themen
Forumthread
Beiträge
7
14
1
5
14
2
5
5
1
1
8
2
1
9
4
2
4
12
3
2
6
1
9
9
2