Sverweis auf Dateien mit wechslenden Dateinamen

Hallo zusammen,
ich habe eine Datei (nennen wir mal Bericht) in welche täglich Daten eingetragen werden.
In drei andere Dateien (nennen wir mal Daten 1, 2, 3) werden ebenfalls täglich Daten eingetragen.
In der Datei Bericht nehme ich mittels Sverweis Bezug auf die Dateien Daten 1, 2, 3 allerdings nicht immer auf die gleiche, das wechselt.
Nun zu meinem Problem.
Die Dateien Daten 1, 2, 3 erhalten jedes Jahr einen neuen Dateinamen-Zusatz (die aktuelle Jahreszahl). Ebenfalls wird ein neues Verzeichnis angelegt in welchem die Dateien Daten 1, 2, 3 liegen, ebenfalls mit einem Jahreszusatz. Die Datei Bericht liegt in einem anderen Verzeichnis.
Die Sverweisfunktion sieht folgendermaßen aus:
SVERWEIS($U$1;'Y:\Bereich\Daten 2012\[Daten Bereich 3 2012.xls]Reihe 12'!$A$7:$M$370;13)
In 2011 sah die Formel so aus:
SVERWEIS($U$1;'Y:\Bereich\Daten 2011\[Daten Bereich 3 2011.xls]Reihe 12'!$A$7:$M$370;13)
An der Zellposition U1 befindet sich ein Datum.
Der Verzeichnis und Dateiname ändert sich jedes Jahr und daher muss ich alle Sverweise manuell ändern.
Ich hätte daher gerne die Möglichkeit das Jahr der Zelle U1 als Jahreszahl im Verzeichnis und Dateinamen einzubinden. Dann entfällt komplett die manuelle Änderung.
Mit INDIREKT hab ich das nicht hinbekommen. Geht wohl auch ohnehin nicht, da die Datiene Daten 1, 2, 3 nicht geöffnet werden sollen.
Wer kann mir hier helfen?
Im Archiv bin ich leider nicht fündig geworden.
Danke schon mal!
Gruß Heinz

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

Hallo Heinz,
teste mal diese Möglichkeit.
Der Code kommt in das Modul der Tabelle mit dem Jahr in U1.

' **********************************************************************
' Modul: Tabelle6  Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
  Dim vntLink As Variant
  Dim lngIndex As Long
  Dim strReplace As String, strNewLink As String
  
  If Target.Address(0, 0) = "U1" Then
    If IsNumeric(Target) Then
      If Target >= 1900 And Target <= 3999 Then
        strReplace = " " & CStr(Target)
        vntLink = ThisWorkbook.LinkSources
        If Not IsEmpty(vntLink) Then
          For lngIndex = 1 To UBound(vntLink)
            strNewLink = regReplace(vntLink(lngIndex), " [0-9]{4}", strReplace)
            If strNewLink <> CStr(vntLink(lngIndex)) Then
              ThisWorkbook.ChangeLink Name:=vntLink(lngIndex), _
                NewName:=strNewLink, Type:=xlExcelLinks
            End If
          Next
        End If
      End If
    End If
  End If
  
End Sub


Private Function regReplace(ByVal Text As String, ByVal Pattern As String, ByVal Replacement As String, Optional IgnoreCase As Boolean = True) As String
  Dim objRegExp As Object
  Set objRegExp = CreateObject("Vbscript.regexp")
  With objRegExp
    .Pattern = Pattern
    .IgnoreCase = IgnoreCase
    .Global = True
    regReplace = .Replace(Text, Replacement)
  End With
  Set objRegExp = Nothing
End Function

« Gruß Sepp »

Beliebteste Forumthreads (12 Monate)

Sverweis auf Dateien mit wechslenden Dateinamen

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

320 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Sverweis auf Dateien mit wechslenden Dateinamen

10 Beiträge zum Forumthread Beiträge zu diesem Forumthread

320 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread