AW: Namen in eienr Liste zählen
20.01.2012 15:33:57
Peter
Hallo Matthias,
vielleicht so:
'
' Ich habe eine Tabelle mit ein paar tausend Zeilen.
' Sagen wir in A steht ein Name und in B eine Tätigkeit.
'
' Franz Müller test
' Heidi Muster bla
' Klaus Maler test
' Franz Müller test
'
' Der gute Franz kommt jetzt zweimal vor, und ich möchte ein Makro schreiben, das
' mir auf einer Seite Zusammenfassung aufzählt, wie oft Franz in der Spalte vorkommt.
'
Public Sub WieOft()
Dim myDict As Object
Dim WkSh As Worksheet
Dim lLetzte As Long
Dim vTemp As Variant
Dim iIndx As Integer
Dim rZelle As Range
Set myDict = CreateObject("Scripting.Dictionary")
Set WkSh = ThisWorkbook.Worksheets("Tabelle1") ' den Tabellenblattnamen ggf. anpassen!
lLetzte = WkSh.Cells(Rows.Count, 1).End(xlUp).Row
' die Eingabe-Werte in ein Array speichern
vTemp = WkSh.Range("A1:A" & lLetzte)
' den Array abarbeiten
For iIndx = LBound(vTemp) To UBound(vTemp)
If vTemp(iIndx, 1) "" Then ' ist die Zelle gefüllt?
' in's Dictionary übernehmen und zählen
myDict(vTemp(iIndx, 1)) = myDict(vTemp(iIndx, 1)) + 1
End If
Next iIndx
' ausgeben der per Dictionary gesammelten Daten
Set WkSh = ThisWorkbook.Worksheets("Tabelle2") ' den Tabellenblattnamen ggf. anpassen!
WkSh.Range("A1:A" & lLetzte).ClearContents ' den Ausgabe-Bereich leeren/löschen
Set rZelle = WkSh.Range("A1") ' den Ausgabe-Bereich festlegen
rZelle.Resize(myDict.Count) = WorksheetFunction.Transpose(myDict.Keys)
rZelle.Offset(0, 1).Resize(myDict.Count) = WorksheetFunction.Transpose(myDict.Items)
' sortieren der Anzahl Vorkommen nach Vorkommen, Namen
WkSh.Range("A1:B" & WkSh.Cells(Rows.Count, 1).End(xlUp).Row).Sort _
Key1:=WkSh.Range("B1"), Order1:=xlDescending, _
Key2:=WkSh.Range("A1"), Order2:=xlAscending, _
Header:=xlGuess, OrderCustom:=1, _
MatchCase:=False, Orientation:=xlTopToBottom, _
DataOption1:=xlSortNormal, _
DataOption2:=xlSortNormal
End Sub
Gruß Peter