Live-Forum - Die aktuellen Beiträge
Datum
Titel
23.04.2024 11:26:57
Probleme mit tbl.Listrows.add
23.04.2024 10:55:14
Zeilen sortieren
23.04.2024 10:23:52
Tabelle 90° drehen + Filteroptionen
23.04.2024 10:11:03
Dateiname plus Wenn vorhanden dann "(1)" anhängen.
Du findest keine passende Antwort auf Deine Frage?
Stelle Deine Frage in unserem Live-Forum
Anzeige
Archiv - Navigation
1272to1276
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1272to1276
1272to1276
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

zweitkleinste aus einer Rheie in nicht zusammenhän

zweitkleinste aus einer Rheie in nicht zusammenhän
Gerhard
Hallo Zusammen
Ich stehe an bei einem Problem.
Ich habe eine Zahlenrehie in nicht zusammenhängenden Zellen (z.B. P107=8; P110=25; P113=4; P116=1; P119=1; P122=1; P125=1 usw.) Und da möchte ich jetzt die zweitkleinste Zahl in der Zelle I6 Anzeigen lassen.
Mit =KKLEINSTE funktioniert nicht, da ich mehrmals die 1 gebrauche. Und alle anderen Lösungen wie die ich bis jetzt gefunden oder selbst entwickelt habe funktionieren nicht da entweder die 1 zu viel vorkommt oder die Zellen nicht zusammenhängend sind.
Kann mir da jemand mit einer Lösung helfen?
Besten Dank
Gerhard
AW: zweitkleinste aus einer Rheie in nicht zusammenhän
09.08.2012 14:21:52
Rudi
Hallo,
mit Hilfsspalten:
 PQRS
1078 84
108  25 
109  4 
11025 1 
111  1 
112  1 
1134 1 
114    
115    
1161   
117    
118    
1191   
120    
121    
1221   
123    
124    
1251   

ZelleFormel
R107=INDEX($P$107:$P$125;(ZEILE(A1)-1)*3+1)
R108=INDEX($P$107:$P$125;(ZEILE(A2)-1)*3+1)
R109=INDEX($P$107:$P$125;(ZEILE(A3)-1)*3+1)
R110=INDEX($P$107:$P$125;(ZEILE(A4)-1)*3+1)
R111=INDEX($P$107:$P$125;(ZEILE(A5)-1)*3+1)
R112=INDEX($P$107:$P$125;(ZEILE(A6)-1)*3+1)
R113=INDEX($P$107:$P$125;(ZEILE(A7)-1)*3+1)
S107=KKLEINSTE(R107:R113;ZÄHLENWENN(R107:R113;MIN(R107:R113))+1)

Gruß
Rudi
Anzeige
zweitkleinste aus einer Reihe ohne Hilfsspalte
09.08.2012 14:58:28
Rudi
Hallo,
 PQR
1078 4
1081  
1092  
11025  
1111  
1122  
1134  
1142  
1152  
1161  
1172  
1182  
1191  
1202  
1212  
1221  
1232  
1242  
1251  

NameBezug
MeinBereich=WENN(REST(ZEILE(Tabelle1!$P$107:$P$125)+1;3)=0;Tabelle1!$P$107:$P$125;"")

ZelleFormel
R107{=KKLEINSTE(MeinBereich;SUMME((MeinBereich=MIN(MeinBereich))*1)+1)}
Achtung, Matrixformel!
Die geschweiften Klammern{} nicht eingeben,
sondern die Zelle mit
Shift + Strg + Enter
verlassen statt Enter alleine.

Gruß
Rudi
Anzeige
AW: zweitkleinste aus einer Rheie in nicht zusammenhän
09.08.2012 16:05:05
Uwe
Hallo Gerhard,
eine von Rudis beiden Lösungen wird wohl am sinnvollsten sein, aber da es mich soviel "Schweiß gekostet hat (;o)", möchte ich Euch auch meine "Monster"-Formel vorstellen.
Immerhin kommt sie ohne Hilfsspalte und ohne Namen aus:
=MIN(WENN(WENN((P107:P1000)*(REST(ZEILE(P107:P1000);3)=2)=0;9^9;(P107:P1000)*(REST(ZEILE(P107:P1000); 3)=2))=MIN(WENN((P107:P1000)*(REST(ZEILE(P107:P1000);3)=2)=0;9^9;(P107:P1000)*(REST(ZEILE(P107:P1000) ;3)=2)));9^9;WENN((P107:P1000)*(REST(ZEILE(P107:P1000);3)=2)=0;9^9;(P107:P1000) *(REST(ZEILE(P107:P1000);3)=2))))
Teste mal genau, ob ich nicht auch noch einen Fehler reingebaut habe.
Gruß
Uwe
(:o)
Anzeige
AW: zweitkleinste aus einer Rheie in nicht zusammenhän
09.08.2012 16:16:50
Rudi
Hallo,
und ohne Namen
den hab ich nur eingebaut, um dieses Monster zu zähmen:
 PQ
107253
108  
109  
1108 
111  
112  
1134 
114  
115  
1161 
117  
118  
1191 
120  
121  
1221 
123  
124  
1253 

ZelleFormel
Q107{=KKLEINSTE(WENN(REST(ZEILE(Tabelle1!$P$107:$P$125)+1;3)=0;Tabelle1!$P$107:$P$125;"");SUMME((WENN(REST(ZEILE(Tabelle1!$P$107:$P$125)+1;3)=0;Tabelle1!$P$107:$P$125;"")=MIN(WENN(REST(ZEILE(Tabelle1!$P$107:$P$125)+1;3)=0;Tabelle1!$P$107:$P$125;"")))*1)+1)}
Achtung, Matrixformel!
Die geschweiften Klammern{} nicht eingeben,
sondern die Zelle mit
Shift + Strg + Enter
verlassen statt Enter alleine.

Gruß
Rudi
Anzeige
Zweitkleinste aus unregelmäßig unzusammenhängend
09.08.2012 16:53:11
Erich
Hi zusammen,
wenn sich der Bereich nicht durch eine Formel darstellen lässt, sondern explizit hingeschrieben werden muss,
geht es auch (auch mit Namensvergabe zur Abkürzung):
 PQ
1078 
1081 
10911 
11025 
111 6
1129 
1136 
1143 
1157 
1161 
1174 
118  
1191 

Formeln der Tabelle
ZelleFormel
Q111=KKLEINSTE(myName;1+SUMME(ZÄHLENWENN(INDIREKT({"P107:P110"."P112:P113"."P112:P113"."P115:P116"."P119"}); MIN(myName))))
Namen in Formeln
ZelleNameBezieht sich auf
Q111myName=Tabelle1!$P$107:$P$110;Tabelle1!$P$112:$P$113;Tabelle1!$P$115:$P$116;Tabelle1!$P$119

Verwendet habe ich dabei eine Formelö aus
http://www.excelformeln.de/formeln.html?welcher=359
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich
Anzeige
AW: Zweitkleinste aus unregelmäßig unzusammenhängend
13.08.2012 08:09:55
Gerhard
Guten Morgen Rudi, Uwe und Erich
Besten Dank für eure Lösungen... ich sehe ich habe mehrere Möglichkeiten und alle funktionieren.
Ich muss nur noch schauen welche ich einbauen werde, da ich nicht der einzige bin der mit der Tabelle arbeitet, um die Nachvollziehbarkeit zu gewährleisten. Da wir bei uns in der Firma noch schlechtere Excel-Nutzer haben als ich das bin.
Auf jeden Fall möchte ich euch für euer Engagement und die tolle Hilfe danken.
Bis zum nächsten Mal...
Gerhard

Beliebteste Forumthreads (12 Monate)

Anzeige
Jetzt das Excel-Portal bewerten: Deine Stimme zählt!

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige