Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1272to1276
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Bereich neben fixierter Spalte

Bereich neben fixierter Spalte
Benedikt
Guten Morgen zusammen
Zuerst ein Dankeschön für all die Arbeit und Hilfe die Ihr jeden Tag leistet.
Ich wäre Dankbar wenn mir jemand bei einem Problem um einen Terminkalender helfen könnte.
In Spalte A2 bis A51 sind die Namen der Mitarbeiter. Diese Spalte ist fixiert.
Ab Spalte B bis NF ist immer ein Tagesdatum enthalten.
Beim öffnen des Terminkalender ist die Spalte mit dem aktuellen Datum neben der Spalte A. Soweit so gut.
Jetzt meine Frage:
Wie kann ich den Bereich A2bisA51 und die nächsten 10 Spalten unbekannt2-unbekannt51 markieren damit ich ein PDF drucken kann.
Ich hoffe es ist einigermassen verständlich
Sub PDFspeichern()
Bereich für druck markieren?
Selection.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
"O:\Hugo 2010\Terminkalender\Terminplan aktuell.pdf", Quality:= _
xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, _
OpenAfterPublish:=False
End Sub
Vielen Dank für eure Hilfe und einen ganz schönen Tag

22
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Benutzer
Anzeige
AW: Bereich neben fixierter Spalte
10.08.2012 10:03:34
Rudi
Hallo,
du musst die Spalten zwischen A und Datum ausblenden.
Sub CreatePDF()
Dim rng As Range
Application.ScreenUpdating = False
Set rng = Rows(1).Find(what:=Date, LookIn:=xlFormulas)
If rng.Column > 2 Then
Range(Cells(1, 2), Cells(1, rng.Column - 1)).EntireColumn.Hidden = True
End If
Range(Cells(1, 1), rng.Offset(, 9)).Resize(52).ExportAsFixedFormat _
Type:=xlTypePDF, Filename:="c:\temp\test.pdf", _
Quality:=xlQualityStandard, IncludeDocProperties:=True, _
IgnorePrintAreas:=False, OpenAfterPublish:=False
Columns.Hidden = False
End Sub

Gruß
Rudi
Anzeige
vorerst vielen Dank
10.08.2012 10:35:57
Benedikt
Vielen Dank Rudi
Ich kann leider erst heute Abend testen. Falls Probleme auftauchen melde ich mich wieder
Ich wünsche Dir einen schönen Tag
@Rudi Fehlermeldung
10.08.2012 11:36:55
Benedikt
Hallo Rudi
etwas passt Ihm nicht.
Im Moment erhalte ich die Fehlermeldung : Objektvariable oder With-Blochvariable nicht festgelegt bei rng.Column > 2 Then
PS. Die Datum sind in Zeile 3 ab Spalte B
AW: @Rudi Fehlermeldung
10.08.2012 11:52:24
Rudi
Hallo,
dann eben
Set rng=Rows(3).Find (.....)
Gruß
Rudi
AW: @Rudi Fehlermeldung immer noch
10.08.2012 12:08:46
Benedikt
Sorry geht trotzdem nicht, gleiche Fehlermeldung an der selben Stelle.
AW: @Rudi Fehlermeldung immer noch
10.08.2012 12:22:36
Rudi
Hallo,
dann lad mal die Mappe hoch.
Gruß
Rudi
AW: @Rudi Fehlermeldung immer noch
10.08.2012 13:32:27
Benedikt
Vielen Dank Rudi für deine Geduld
Im Anhang die Datei - ein wenig abgespeckt. Das Makro im this workbook open um die Spalte des aktuellen Tages neben Spalte A zu plazieren ist in dieser Version nicht enthalten (liegt auf dem PC zu Hause)
https://www.herber.de/bbs/user/81365.xlsm
Anzeige
AW: @Rudi Fehlermeldung immer noch
10.08.2012 14:25:34
Rudi
Hallo,
Sub PDFspeichern()
Dim rng As Range, bolFound As Boolean
Application.ScreenUpdating = False
For Each rng In Range(Cells(2, 2), Cells(3, Columns.Count).End(xlToLeft))
If rng = Date Then
bolFound = True
Exit For
End If
Next
If bolFound Then
If rng.Column > 2 Then
Range(Cells(1, 2), Cells(1, rng.Column - 1)).EntireColumn.Hidden = True
End If
Range(Cells(1, 1), rng.Offset(, 9)).Resize(52).ExportAsFixedFormat _
Type:=xlTypePDF, Filename:="O:\Hugo 2010\Terminkalender\Terminplan aktuell.pdf", _
Quality:=xlQualityStandard, IncludeDocProperties:=True, _
IgnorePrintAreas:=False, OpenAfterPublish:=False
Columns.Hidden = False
Else
MsgBox Date & "nicht gefunden!", vbCritical, "Gebe bekannt ..."
End If
End Sub

Gruß
Rudi
Anzeige
vielen dank so geht es
10.08.2012 14:37:38
Benedikt
.
dafür neuer Fettnapf
10.08.2012 15:55:14
Benedikt
Rudi dein Code ist Super und läuft. Nur sind jetzt die ausgeblendeten Spalten der Samstage und Sonntage wieder eingeblendet. Lässt sich das verhindern?
entfettet
10.08.2012 17:15:59
Rudi
Hallo,
Sub PDFspeichern()
Dim rng As Range, bolFound As Boolean
Application.ScreenUpdating = False
For Each rng In Range(Cells(2, 2), Cells(3, Columns.Count).End(xlToLeft))
If rng = Date Then
bolFound = True
Exit For
End If
Next
If bolFound Then
If rng.Column > 2 Then
Range(Cells(1, 2), Cells(1, rng.Column - 1)).EntireColumn.Hidden = True
End If
Range(Cells(1, 1), rng.Offset(, 9)).Resize(52).ExportAsFixedFormat _
Type:=xlTypePDF, Filename:="O:\Hugo 2010\Terminkalender\Terminplan aktuell.pdf", _
Quality:=xlQualityStandard, IncludeDocProperties:=True, _
IgnorePrintAreas:=False, OpenAfterPublish:=False
For Each rng In Range(Cells(2, 2), Cells(3, Columns.Count).End(xlToLeft))
rng.EntireColumn.Hidden = Weekday(rng, vbMonday) > 5
Next
Else
MsgBox Date & "nicht gefunden!", vbCritical, "Gebe bekannt ..."
End If
End Sub

Gruß
Rudi
Anzeige
fast entfettet
10.08.2012 17:48:14
Benedikt
Danke für deine Zeit und Geduld.
Beim zweiten mal schliessen der Datei kommt die Fehlermeldung Laufzeitfehler '13' Typen unverträglich
rng.EntireColumn.Hidden = Weekday(rng, vbMonday) > 5
Alles I.O
10.08.2012 19:46:35
Benedikt
Vielen herzlichen Dank Rudi
Doch Fehlermeldung
11.08.2012 11:46:13
Benedikt
Beim schliessen der Datei kommt die Fehlermeldung Laufzeitfehler '13' Typen unverträglich.
Markierung bei rng.EntireColumn.Hidden = Weekday(rng, vbMonday) > 5
AW: Doch Fehlermeldung
11.08.2012 11:52:52
Hajo_Zi
man könnte vermuten die Variable ist nicht belegt, oder es steht keine Zahl drin.

AW: Doch Fehlermeldung
11.08.2012 12:17:48
Benedikt
Danke Hajo, aber ich kann den Code von rudi nicht lesen und weiss wirklich nicht wo, welche Variable oder Zahl fehlt.
Anzeige
AW: Doch Fehlermeldung
11.08.2012 14:01:16
Hajo_Zi
Hallo,
die Variable Stand nach Weekday(
Gruß Hajo
AW: Doch Fehlermeldung
12.08.2012 08:34:11
Benedikt
Sorry so kurz vor der Ziellinie schaffe ich es einfach nicht.
Laufzeitfehler '13' Typen unverträglich.
Markierung bei rng.EntireColumn.Hidden = Weekday(rng, vbMonday) > 5
Liegt es am benutzerdefinierten Datumsformat TTT. / TT. MMM. ?
Sub PDFspeichern()
Dim rng As Range, bolFound As Boolean
Application.ScreenUpdating = False
For Each rng In Range(Cells(2, 2), Cells(3, Columns.Count).End(xlToLeft))
If rng = Date Then
bolFound = True
Exit For
End If
Next
If bolFound Then
If rng.Column > 2 Then
Range(Cells(1, 2), Cells(1, rng.Column - 1)).EntireColumn.Hidden = True
End If
Range(Cells(1, 1), rng.Offset(, 9)).Resize(52).ExportAsFixedFormat _
Type:=xlTypePDF, Filename:="O:\Hugo 2010\Terminkalender\Terminplan aktuell.pdf", _
Quality:=xlQualityStandard, IncludeDocProperties:=True, _
IgnorePrintAreas:=False, OpenAfterPublish:=False
For Each rng In Range(Cells(2, 2), Cells(3, Columns.Count).End(xlToLeft))
 rng.EntireColumn.Hidden = Weekday(rng, vbMonday) > 5
Next
Else
MsgBox Date & "nicht gefunden!", vbCritical, "Gebe bekannt ..."
End If
End Sub
Ich bin sehr dankbar eure für Hilfe
Grüsse aus der Schweiz Benedikt
Anzeige
AW: Doch Fehlermeldung
12.08.2012 09:13:37
Hajo_Zi
aus dem Code sieht man das die Variable belegt ist also kann es nur an der Datrei liegen. Das Im Bereich B2:C... keine Daten eingetragen sind.
Gruß Hajo
Danke Hajo, so war es
12.08.2012 09:55:36
Benedikt
.
AW: Danke Hajo, so war es
12.08.2012 10:04:47
Hajo_Zi
das könnte man mit einem kleine Trick umgehen.
Option Explicit
Sub PDFspeichern()
Dim rng As Range, bolFound As Boolean
Application.ScreenUpdating = False
For Each rng In Range(Cells(2, 2), Cells(3, Columns.Count).End(xlToLeft))
If rng = Date Then
bolFound = True
Exit For
End If
Next
If bolFound Then
If rng.Column > 2 Then
Range(Cells(1, 2), Cells(1, rng.Column - 1)).EntireColumn.Hidden = True
End If
Range(Cells(1, 1), rng.Offset(, 9)).Resize(52).ExportAsFixedFormat _
Type:=xlTypePDF, Filename:="O:\Hugo 2010\Terminkalender\Terminplan aktuell.pdf", _
Quality:=xlQualityStandard, IncludeDocProperties:=True, _
IgnorePrintAreas:=False, OpenAfterPublish:=False
For Each rng In Range(Cells(2, 2), Cells(3, Columns.Count).End(xlToLeft))
If IsDate(rng) Then
rng.EntireColumn.Hidden = Weekday(rng, vbMonday) > 5
End If
Next
Else
MsgBox Date & "nicht gefunden!", vbCritical, "Gebe bekannt ..."
End If
End Sub
Gruß Hajo
Anzeige
Besten Dank Hajo
12.08.2012 11:04:43
Benedikt
Vielen Dank für die Hilfe.
Leider besitze ich nicht die Gnade, mit VBA zu spielen. Dank dem Forum entstehen trotzdem immer wieder ganz ansehliche Lösungen. Sobald aber die Vorschläge wirklich Professionel sind, kann ich als Laie nur unter schwersten Bedingungen an der Vorgabe weiter Arbeiten.
Dein Code läuft perfekt durch, Du hast mir sehr geholfen.
Ich wünsche Dir einen schönen Tag

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige