Auflösung Pfadnamen / Sverweis

Hallo Freunde der Zellen,
ich möchte ein Projekt umsetzen für welches mir noch der richtige einstieg fehlt.
In der Finanzbuchhaltung werden jeden Monat immer wieder die selben Excel Sheets bbearbeitet und dann unter dem entsprechenden Monat abgespeichert:
\\fibu\Januar\Abstimmung-1.xls
\\fibu\Januar\Abstimmung-2.xls
\\fibu\Februar\Abstimmung-1.xls
\\fibu\Februar\Abstimmung-2.xls
In diesen Sheets sollen immer sverweise auf eine Basisdateindatei (Basic.xls) vorgenommen werden. Diese Datei wird immer vor den Abstimmarbeiten erstellt und dann in das entsprechende Monatsverzeichnis gespielt:
\\fibu\Januar\Basic.xls
\\fibu\Februar\Basic.xls
Soweit so gut.
Jetzt möchte ich aber Verweise aus den Arbeitsdateien vornehmen (zb: ='[BASIC.xlsx]SUSA'!$C:$I) ohne das der ganze Pfad jeden Monat geändert werden muss (also nicht: =\\fibu\Januar\[BASIC.xlsx]SUSA'!$C:$I)
und
wenn möglich - die Verweise auch noch funktionieren wenn die Datei Basic - nicht geöffnet ist.
Eine Hilfe wäre suuuuper!
danke

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

Hallo Axel,
kann man natürlich auch per VBA lösen.
In das Modul "DieseArbeitsmappe" der Datei "Abstimmung...".

' **********************************************************************
' Modul: DieseArbeitsmappe  Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub WorkBook_Open()
  Dim vntLS As Variant, vntTmp As Variant, vntName As Variant
  Dim lngIndex As Long
  Dim strMonth As String, strSep As String
  
  strSep = Application.PathSeparator
  
  With Me
    vntName = Split(.FullName, strSep)
    strMonth = LCase(vntName(UBound(vntName) - 1))
    vntLS = .LinkSources
    If IsArray(vntLS) Then
      For lngIndex = LBound(vntLS) To UBound(vntLS)
        vntTmp = Split(vntLS(lngIndex), strSep)
        If LCase(vntTmp(UBound(vntTmp))) Like "basic.*" Then
          If LCase(vntTmp(UBound(vntTmp) - 1)) <> strMonth Then
            ThisWorkbook.ChangeLink Name:=vntLS(lngIndex), _
              NewName:=.Path & strSep & vntTmp(UBound(vntTmp)), Type:=1
            .Save
            MsgBox "Die Verknüpfung zu '" & vntTmp(UBound(vntTmp)) & _
              "' wurde aktualisiert!", vbInformation, "Hinweis"
          End If
        End If
      Next
    End If
  End With
  
End Sub

« Gruß Sepp »

Beliebteste Forumthreads (12 Monate)

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread