Vollständige Liste von Nummern

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Vielen Dank für Deine Antwort,
leider hilft mir diese Formel nicht viel.
Ich weiß ja nicht, wo die jeweilige Rechnungsnummer beginnt (bei 94500, oder erst bei 94800 oder auch bei 95700) auch weiß ich nicht, wo sie endet.
Ich weiß nur, dass die Eintragungen in D4 bis D? vorgenommen werden. Sind es in einem Monat 50 Rechnungen, so geht die Liste von D4 bis D54, sind es nur 20 Rechnungen, so geht die Liste von D4 bis D24.
Ich kann nun beginnend in Zeile 4, in Spalte X4 eine Formel schreiben und die runter kopieren bis X100 (das spielt keine Rolle, wie weit ich runter gehe, nach unten ist ja Platz)
Ich kann auch eine Meldung in einem einzelnen Feld bekommen, das ist egal. Wichtig ist nur, dass überwacht wird, dass innerhalb der Reihe D4 bis D? zwar leere Felder stehen können, aber WENN Zahlen drin stehen, dass diese vollständig sind, das heißt, dass keine Rechnungsnummern fehlen dürfen.
Also: Die Rechnungsnummern 94000 bis 94005 stehen unsortiert in D4 bis D10. In D9 steht ein Text. Das wird ignoriert. Die Rechnungsnummern sind jedoch alle da, also KEINE Meldung. Nun steht aber zwei mal ein Text UND EINE RECHNUNGSNUMMER FEHLT, sagen wir, die Nummer 94002 ist nicht vorhanden. Nun soll eine Meldung kommen, die lautet "Falsch", oder "Achtung", oder 0, das ist völlig egal, das kann ich dann selbst einstellen.
Mit freundlichem Gruß
Franz

Hi Franz,
hier ist eine Lösung anhand deiner Mappe - aber nicht in deiner Mappe
(zwei Nummern habe ich durch Lieferschein wersetzt):

	D	E	F	G	H
3	Rech.Nr.
4	94596	94602	94602	94602	94602
5	94597		94618	94618	94618
6	94610		#ZAHL!	#ZAHL!	#ZAHL!
7	94611
8	94598
9	94599
10	94600
11	94601
12	Lieferschein
13	94603
14	94604
15	94605
16	94606
17	Lieferschein
18	Lieferschein
19	94607
20	94608
21	94609
22	94612
23	94613
24	Lieferschein
25	Lieferschein
26	94614
27	94615
28	Lieferschein
29	94616
30	94617
31	Lieferschein
32	94620
33	94621
34	94619

Formeln der Tabelle

Zelle	Formel
E4	{=MIN(WENN(ISTFEHLER(VERGLEICH(ZEILE(INDEX(D:D;MIN(D3:D43)):INDEX(D:D;MAX(D3:D43))); D3:D43;0)); ZEILE(INDEX(D:D;MIN(D3:D43)):INDEX(D:D;MAX(D3:D43)))))}
F4	{=KKLEINSTE(WENN(ISTFEHLER(VERGLEICH(ZEILE(INDEX(D:D;MIN(D$3:D$43)):INDEX(D:D;MAX(D$3:D$43))); D$3:D$43;0)); ZEILE(INDEX(D:D;MIN(D$3:D$43)):INDEX(D:D;MAX(D$3:D$43)))); ZEILE(F1))}
G4	{=KKLEINSTE(WENN(ZÄHLENWENN(D$3:D$43;ZEILE(INDEX(D:D;MIN(D$3:D$43)):INDEX(D:D;MAX(D$3:D$43))))=0;ZEILE(INDEX(D:D;MIN(D$3:D$43)):INDEX(D:D;MAX(D$3:D$43)))); ZEILE(G1))}
H4	{=KKLEINSTE(WENN(ZÄHLENWENN(D:D;ZEILE(INDIREKT("1:"&MAX(D:D)-MIN(D:D)+1))+MIN(D:D)-1)=0;ZEILE(INDIREKT("1:"&MAX(D:D)-MIN(D:D)+1))+MIN(D:D)-1); ZEILE(H1))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Die Formel in H4 ist von http://www.excelformeln.de/formeln.html?welcher=362
Leider geht das alles nicht in deiner Mappe, denn du hast eine alte Excelversion, die nur 65536 Zeilen kennt.
Hier würden aber ca. 94630 Zeilen gebraucht.
Abhilfe: Aktuelleres Excel anschaffen oder die Re-Nummern in einer Hilfszeile um z. B. 90000 vermindern,
dann sollte es funzen.
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

Beliebteste Forumthreads (12 Monate)

	A	B
2	123	124
3	121
4	125
5	122
6	123
7	120

14 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

14
Beiträge zum Forumthread

Beiträge zu diesem Forumthread