Anzeige
Archiv - Navigation
1312to1316
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Soll Ist Differenz - größer kleiner - "Grafik"

Soll Ist Differenz - größer kleiner - "Grafik"
28.05.2013 21:22:49
Werner
Hallo Excel-Freunde,
ich stehe vor eine "kleinen" spannenden Herausforderung.
Es geht darum, in einer Zelle folgende Bedingungen "grafisch" (einfach mit verschiedenen Buchstaben/Zeichen darzustellen)
Es soll eine einfache visuelle Darstellung (InZell) von Zahlenwerten
dargestellt werden.
Es gibt einen IST-Wert / einen SOLL-Wert (jeweils von 1 bis 4)
und die Differenz soll in einer Zelle ausgewiesen werden.
Wenn SOLL größer IST sollen andere Zeichen erscheinen
Wenn IST größer SOLL ebenfalls
Na, zur Verdeutlichung habe ich einen Datei hochgeladen
Ich hoffe, sie "spricht für sich".
Meine ersten Ansätze sind bereits enthalten :)
Freu mich auf einen Tip
Besten Excel-Gruss
Werner
hier die Datei:
https://www.herber.de/bbs/user/85565.xls

9
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Soll Ist Differenz - größer kleiner - "Grafik"
28.05.2013 21:33:19
Werner
Und hier mal das "Bild" aus der XLS-Datei - zur schnellen Übersicht
Userbild
Gruss
Werner

AW: Soll Ist Differenz - größer kleiner - "Grafik"
28.05.2013 21:33:55
Werner
Und hier mal das "Bild" aus der XLS-Datei - zur schnellen Übersicht
Userbild
Gruss
Werner

String-Unterschiede darstellen
29.05.2013 01:51:45
Erich
Hi Werner,
die Spalten F und G haben einfachere Formeln bekommen, die Spalten I und J enthalten mögliche Lösungen.
Die Formel in Spalte I geht von den Texten der Spalten F:G aus,
die Formel in Spalte J verarbeitet nur die Zahlen inden Spalten C:D.
 CDEFGHIJ
4ISTSOLL Graph ISTGraph SOLLso möchte ich es ;)sooder so
511 XOOOXOOOXOOOXOOOXOOO
612 XOOOXXOOX#OOX#OOX#OO
713 XOOOXXXOX##OX##OX##O
814 XOOOXXXXX###X###X###
921 XXOOXOOOX@OOX@OOX@OO
1022 XXOOXXOOXXOOXXOOXXOO
1123 XXOOXXXOXX#OXX#OXX#O
1224 XXOOXXXXXX##XX##XX##
1331 XXXOXOOOX@@OX@@OX@@O

Formeln der Tabelle
ZelleFormel
F5=WENN(C5="";""; WIEDERHOLEN("X";REST(C5;5)) &WIEDERHOLEN("O";REST(4-C5;5)))
G5=WENN(D5="";""; WIEDERHOLEN("X";REST(D5;5)) &WIEDERHOLEN("O";REST(4-D5;5)))
I5=WAHL(1+(LINKS(F5)<LINKS(G5))+2*(LINKS(F5)>LINKS(G5)); LINKS(F5); "#";"@") &WAHL(1+(TEIL(F5;2;1)<TEIL(G5;2;1))+2*(TEIL(F5;2;1)>TEIL(G5;2;1)); TEIL(F5;2;1); "#";"@") &WAHL(1+(TEIL(F5;3;1)<TEIL(G5;3;1))+2*(TEIL(F5;3;1)>TEIL(G5;3;1)); TEIL(F5;3;1); "#";"@") &WAHL(1+(RECHTS(F5)<RECHTS(G5))+2*(RECHTS(F5)>RECHTS(G5)); RECHTS(F5); "#";"@")
J5=WENN(C5="";""; WIEDERHOLEN("X";MIN(C5;D5)) &WIEDERHOLEN("#";MAX(0;D5-C5)) &WIEDERHOLEN("@";MAX(0;C5-D5)) &WIEDERHOLEN("O";4-MAX(C5;D5)))


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich
P.S.:
Mit der Excel Jeanie (und einigen anderen Tools) lassen sich Tabellenausschnitte sehr schön im Forum darstellen.
Dafür braucht man gar keine Grafik, mit der Excel eh nichts anfangen kann. :-)

Anzeige
AW: String-Unterschiede darstellen
29.05.2013 07:14:02
Werner
Hallo Erich,
Respekt ! Klasse Formeln :)
Verstehe bislang alle ausser der in Spalte I
Da werde ich mir heute im Laufe des Vormittages "tiefer einsteigen"
Danke Dir sehr für die schnelle nächtliche Lösung
und wünsche Dir einen tollen sonnigen Tag
Gruss
Werner

AW: String-Unterschiede darstellen > Leerzellen
29.05.2013 07:47:35
Werner
Erich, bin immer noch beeindruckt.
Die Formel in I ist gut - besser jedoch die in J :)
Nur habe ich in meinem Ursprungsthread eines nicht erwähnt (sorry dafür):
Es kann auch vorkommen, dass die IST bzw. SOLL-Felder LEER sind (also ohne Inhalt)
Wie fange ich so etwas in der Formel ab ?
Freu mich auf einen weiteren Tip
Besten Morgengruss
Werner
@eines in der Formel in J habe ich nicht verstanden ... warum max(0;D5-C5) - also die 0

Anzeige
bessere Prüfungen
29.05.2013 09:01:13
Erich
Hi Werner,
vielleicht können Zellen in den Spalten C:D nicht nur leer sein, sondern auch falsche Daten enthalten. :-)
Hier mal eine Version, die nur bei den Vorgaben 1, 2, 3 und 4 einen 4stellige Zeichenkette ausgibt:
 CDEFGHIJK
4ISTSOLL Graph ISTGraph SOLL sooder so 
511 XOOOXOOO XOOOXOOO 
631 XXXOXOOO X@@OX@@O 
731 XXXOXOOO X@@OX@@O 
823 XXOOXXXO XX#OXX#OWAHR
923  XXXO   FALSCH
104  XXXX     
11 4  XXXX    
12         
1301  XOOO    
141,011  XOOO    
15txt1  XOOO    
1620 XXOO     
1721,1 XXOO     
1829 XXOO     
192txt XXOO     

Formeln der Tabelle
ZelleFormel
F5=WENN(ISTNV(VERGLEICH(C5;{1.2.3.4};0)); ""; WIEDERHOLEN("X";REST(C5;5)) &WIEDERHOLEN("O";REST(4-C5;5)))
G5=WENN(ISTNV(VERGLEICH(D5;{1.2.3.4};0)); ""; WIEDERHOLEN("X";REST(D5;5)) &WIEDERHOLEN("O";REST(4-D5;5)))
I5=WENN(ISTNV(VERGLEICH(C5;{1.2.3.4};0)*VERGLEICH(D5;{1.2.3.4};0)); ""; WAHL(1+(LINKS(F5)<LINKS(G5))+2*(LINKS(F5)>LINKS(G5)); LINKS(F5); "#";"@") &WAHL(1+(TEIL(F5;2;1)<TEIL(G5;2;1))+2*(TEIL(F5;2;1)>TEIL(G5;2;1)); TEIL(F5;2;1); "#";"@") &WAHL(1+(TEIL(F5;3;1)<TEIL(G5;3;1))+2*(TEIL(F5;3;1)>TEIL(G5;3;1)); TEIL(F5;3;1); "#";"@") &WAHL(1+(RECHTS(F5)<RECHTS(G5))+2*(RECHTS(F5)>RECHTS(G5)); RECHTS(F5); "#";"@"))
J5=WENN(ISTNV(VERGLEICH(C5;{1.2.3.4};0)*VERGLEICH(D5;{1.2.3.4};0)); ""; WIEDERHOLEN("X";MIN(C5;D5)) &WIEDERHOLEN("#";MAX(0;D5-C5)) &WIEDERHOLEN("@";MAX(0;C5-D5)) &WIEDERHOLEN("O";4-MAX(C5;D5)))
K8=ISTZAHL(C8)
K9=ISTZAHL(C9)

Spalte K soll nur zeigen, dass in Zeile 9 nur "" ausgegeben wird, weil die 2 in C9 keine Zahl, sondern Text ist.
Zu max(0;D5-C5):
Wenn D5 kleiner als C5 ist, wird D5-C5 negativ.
WIEDERHOLEN("#";D5-C5) würde dann einen Fehlerwert zurückgeben.
WIEDERHOLEN("#";MAX(0;D5-C5)) gibt dagen wie gewünscht 0 Zeichen zurück.
Statt MAX(0;D5-C5) kann man auch nur MAX(;D5-C5) schreiben. Das bedeutet dasselbe - die 0 wird automatisch ergänzt.
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

Anzeige
AW: bessere Prüfungen
29.05.2013 09:14:52
Werner
Hey Erich
DANKE !
Kannst Du die Datei mal hochladen ?
Ich sitze hier gerade an einem englischen Rechner
und da gibt es Probleme mit den , und ; und ...
Danke vorab
Werner

AW: BeiSpielMappe
29.05.2013 20:51:52
Werner
Klasse ! Danke !
funktioniert einwandfrei .
Habe jetzt noch folgendes ergänzt
(siehe Deine erste Lösung)
Formel in J5
=WENN(C5="";""; WIEDERHOLEN("X";MIN(C5;D5)) &WIEDERHOLEN("#";MAX(0;D5-C5)) &WIEDERHOLEN("@";MAX(0;C5-D5)) &WIEDERHOLEN("O";4-MAX(C5;D5)))
ergänzt um "rechts(...;4)" um bei Leerzellen die zuviel geschriebenen Stellen zu löschen.
Das entspricht dann absolut meinen Vorstellungen.
Ohne Deine Hilfe hätte das nicht geklappt !
Danke und Dir noch einen schönen Abend
Stefan
Anzeige

300 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige