Live-Forum - Die aktuellen Beiträge
Datum
Titel
16.04.2024 19:22:16
Von exceltabelle in word per steuerelement temarker
16.04.2024 18:50:53
Fehlermeldung bei Code - Excel speichern mit Bez. aus Zelle
16.04.2024 17:18:01
Projektplan-Tabelle oder Gantt ohne Balken
16.04.2024 17:05:25
formatierten Text direkt in Zelle einfügen
Du findest keine passende Antwort auf Deine Frage?
Stelle Deine Frage in unserem Live-Forum
Anzeige
Archiv - Navigation
1316to1320
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1316to1320
1316to1320
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Formel für Mittelwert

Formel für Mittelwert
21.06.2013 18:32:03
lapinana
Liebe User,
da ich absoluter Excel-Neuling bin, hoffe ich, hier schnelle Hilfe zu finden.
Ich möchte gerne eine Formel für eine Tabelle erstellen. Dabei soll in Reihe 4 in der Spalte F der Mittelwert der Spalten A bis E errechnet werden. Die Schwierigkeit besteht darin, dass die Spalten A bis C doppelt so viel zählen wie die Spalten D und E. Das zweite Problem ist auch, dass manchmal nicht alle Spalten eine Zahl enthalten und in diesem Fall auch nicht gezählt werden sollen. Es wäre sehr nett, wenn mir jemand von euch helfen könnte. Danke!

30
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Formel für Mittelwert
21.06.2013 18:41:41
Hajo_Zi



Tabelle1
 ABCDEF
6123454,20
7246454,20
8           
91  34  4,00
102  64  4,00

verwendete Formeln
Zelle Formel Bereich R1C1 für Add In
F6,F9{=MITTELWERT(WENN(A6:C6<>"";A6:C6*2) ;D6:E6) }$F$6 =AVERAGE(IF(RC[-5]:RC[-3]<>"",RC[-5]:RC[-3]*2) ,RC[-2]:RC[-1])
A7:C7,A10,C10=A6*2  =R[-1]C*2
D7:E7,D10=D6  =R[-1]C
F7,F10=MITTELWERT(A7:E7)   =AVERAGE(RC[-5]:RC[-1])
{} Matrixformel mit Strg+Umschalt+Enter abschließen
Matrixformeln sind durch geschweifte Klammern {} eingeschlossen
Diese Klammern nicht eingeben!!

XHTML Tabelle für Darstellung in Foren,
einschl. Bedingter Formatierung ab Version 2007
XHTML-Version 11.28



Anzeige
AW: Formel für Mittelwert
21.06.2013 18:59:27
lapinana
Leider habe ich mich wohl falsch ausgedrückt. Sorry. Ich bitte also noch einmal um Hilfe. Es geht beim Beispiel um eine Notenberechnung für die Schule. Die Schüler schreiben im Jahr 5 Prüfungen. Drei ganze und zwei halbe. Wie kann man den Notendurchschnitt zum Zwischenzeugnis ausrechnen, wenn z.B. erst zwei ganze und eine halbe Arbeit geschrieben und benotet worden sind? Im Beispiel sollte in F6 der Wert 2,625 stehen, wenn der Schüler in den drei ganzen Prüfungen die Noten 1, 2 und 3 hat und in den zwei halben eine 4 und eine 5 (1+2+3+4,5 / 4).

AW: Formel für Mittelwert
21.06.2013 19:17:34
Hajo_Zi
Gut Dir mag klar sein warum zu den ersten 3 Zahlen 4,5 addiert werden und warum durch 4. Mir nicht. Das wiederspricht der Aussage im ersten Beitrag.
Man sollte schon im ersten Beitrag die Aufgabe komplett beschreiben. Dann braucht der Antworter nicht vieles annehmen und die Anpassung durch den Fragesteller entfällt.
Man muss sich bei jeder veränderten Aufgabenstellung wieder neu in das Problem einarbeiten. Was bedeutet die erste Lösung war für den Papierkorb. Ich überlasse dann dem nächsten den Beitrag.
Gruß Hajo

Anzeige
@Hajo: wirklich?
21.06.2013 19:38:12
Erich
Hi Hajo,
IMHO hat der/die Fragesteller/in die Frage im Startpost komplett und eindeutig gestellt.
Klar, nett wäre schon an dieser Stelle ein konkretes Beispiel gewesen.
Angesichts der unterschiedlichen Gewichtungen erklärt sich auch die 4,5 recht leicht...
Einen Widerspruch zwischen Aussagen in den Beiträgen finde ich nicht.
Bist du hier nicht etwas zu hart in deiner Einschätzung?
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

AW: @Hajo: wirklich?
21.06.2013 19:39:41
Hajo_Zi
Hallo Erich,
A:C zählt doppelt 1*2+2*2+3*2 ist nicht 4,5
Gruß Hajo

Anzeige
einfache Erklärung
21.06.2013 20:01:11
Erich
Hi Hajo,
"... Spalten A bis C doppelt so viel zählen wie die Spalten D und E" (aus dem Eingangspost)
Das lässt sich auf unterschiedliche Weisen umsetzen.
Eine davon:
1 2 3 4 5 wird zu 1 2 3 4/2 5/2 wird zu 1 2 3 9/2 wird zu 1 2 3 4,5 wird zu 10,5. Geteilt wird durch 4.
Oder wie meine Formel:
1 2 3 4 5 wird zu 2*(1+2+3) +4+5 wird zu 2*6 + 9 wird zu 21. Geteilt wird durch 8.
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

Ja, hast du, weil Zensuren eine wichtige ...
21.06.2013 19:35:59
Luc:-?
…Info gewesen wäre, Lapinana,
denn da geht's wohl etwas anders, wenn sie gewichtet wdn sollen. Hier ist dann zu berücksichtigen, mit wieviel % sie an der Gesamtnote zu beteiligen sind. Das wären dann also 3×100% und 2×50%, was insgesamt 400% ergäbe. Daraus folgt für die Noten in A:C 100/400⇒¼ und D:E 50/400⇒⅛.
Das ergibt die Fml in F6: =MITTELWERT(A6:C6)*0,75+MITTELWERT(D6:E6)*0,25
Leerfelder wdn von der Fkt MITTELWERT grdsätzl nicht berücksichtigt, so dass du ja mal ausprobieren kannst, ob der Zensuren-Ø bei Ausfall von Prüfungen noch deinen Intentionen entspricht.
Gruß Luc :-?

Anzeige
@Luc: andere Aufgabenstellung?
21.06.2013 19:44:33
Erich
Hi Luc:-?,
da gibt es kleine Unterschiede:
 ABCDEFG
41 34 2,42,5
52 6  4#DIV/0!

Formeln der Tabelle
ZelleFormel
F4=WENN(ANZAHL(A4:E4)=0;"leer"; (2*(SUMME(A4:C4))+SUMME(D4;E4))/(2*ANZAHL(A4:C4)+ANZAHL(D4:E4)))
G4=MITTELWERT(A4:C4)*0,75+MITTELWERT(D4:E4)*0,25
F5=WENN(ANZAHL(A5:E5)=0;"leer"; (2*(SUMME(A5:C5))+SUMME(D5;E5))/(2*ANZAHL(A5:C5)+ANZAHL(D5:E5)))
G5=MITTELWERT(A5:C5)*0,75+MITTELWERT(D5:E5)*0,25

Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

Anzeige
Hab' ich schon gemerkt, weshalb wohl ...
21.06.2013 20:09:08
Luc:-?
…folgende Fml bei ihrer Version besser wäre, Erich:
=ABRUNDEN(WENNFEHLER(MITTELWERT(A2:C2)*(0,75+0,25*(SUMME(D2:E2)=0));0)+WENNFEHLER(MITTELWERT(D2:E2) *(0,25+0,75*(SUMME(A2:C2)=0));0);2)
Allerdings macht man das so wie zuerst gezeigt, wenn alle Noten vorliegen. Ob das auch die richtige Methode für ein Zwischenergebnis ist, sei anheim gestellt. Hier kommt es ja auch darauf an, wie fehlende Prüfungen beider Zensuren-/Prüfungsgruppen gewertet wdn sollen. Ich habe hier jetzt 0 genommen und bei komplettem Fehlen einer Gruppe jeweils den normalen Mittelwert gebildet. Ist alles leer, ergibt das also 0. Man könnte die fehlende Prüfung aber auch mit 5 bzw 6 bewerten… ;-)
Gruß Luc :-?

Anzeige
Allgemein üblicher scheint wohl folgende ...
21.06.2013 21:04:56
Luc:-?
…einfachere Formel zu sein:
=ABRUNDEN(WENNFEHLER(SUMME(A6:C6;A6:E6)/ANZAHL(A6:C6;A6:E6);0);2) °
Deren Ergebnis weicht aber mitunter von dem meiner zuvor korrigierten Fml ab.
° Statt 0 kann natürlich auch "" verwendet wdn!
Luc :-?

auch schön!
21.06.2013 21:18:42
Erich
Hi Luc,
eine kleine Änderung hätte ich noch vorzuschlagen: ABRUNDEN innerhalb des WENNFEHLER.
Dann kann man "" (oder "leer" statt 0 verwenden:
 ABCDEFG
41 34 2,42,4
5     #WERT!leer
6123452,622,62

Formeln der Tabelle
ZelleFormel
F4=ABRUNDEN(WENNFEHLER(SUMME(A4:C4;A4:E4)/ANZAHL(A4:C4;A4:E4); ""); 2)
G4=WENNFEHLER(ABRUNDEN(SUMME(A4:C4;A4:E4)/ANZAHL(A4:C4;A4:E4); 2); "leer")
F5=ABRUNDEN(WENNFEHLER(SUMME(A5:C5;A5:E5)/ANZAHL(A5:C5;A5:E5); ""); 2)
G5=WENNFEHLER(ABRUNDEN(SUMME(A5:C5;A5:E5)/ANZAHL(A5:C5;A5:E5); 2); "leer")
F6=ABRUNDEN(WENNFEHLER(SUMME(A6:C6;A6:E6)/ANZAHL(A6:C6;A6:E6); ""); 2)
G6=WENNFEHLER(ABRUNDEN(SUMME(A6:C6;A6:E6)/ANZAHL(A6:C6;A6:E6); 2); "leer")

Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

Anzeige
Richtig! Hatte das "" nachträgl überlegt, ...
21.06.2013 21:32:24
Luc:-?
…aber nicht ganz bis zuende, Erich. ;-)
Die Fml ergab sich aus Annas Wünschen und nach längerem Suchen gefundenen Anleitungen im w³. Nehme an, dass Analoges idR für Gesamtbenotungen verwendet wird.
Gruß Luc :-?

Natürlich sollte dann genauso auch ...
21.06.2013 21:49:06
Luc:-?
… =WENNFEHLER(KÜRZEN(MITTELWERT(A2:C2;A2:E2);2);"") fktionieren, Erich,
wodurch sich der Diskussionskreis dann schließen würde… ;-)
Luc :-?

AW: Natürlich ...
22.06.2013 09:08:15
Erich
Hi Luc :-?,
..., aber doch nicht ohne mein letztes Wort! :-)
Zur Lösung ist nichts mehr zu sagen - sie ist einfach schön. Aber zum Zustandekommen.
IMHO ist dieser Thread ein Beispiel für produktive Zusammenarbeit. Viele tragen etwas bei,
bauen auf den Ideen der anderen auf, lassen die Formel wachsen (meint hier: schrumpfen).
Rückmeldung nicht mehr nötig! - Grüße aus Kamp-Lintfort von Erich

Anzeige
...Trotzdem habe ich zu deinem Schlusswort ...
22.06.2013 13:55:01
Luc:-?
…doch noch eine kleine Ergänzung, Erich… ;-)
Nicht nur ein Bsp für produktive Zusammenarbeit, sondern man kann mE auch Denkprozesse erkennen…
Ich postuliere gern, dass diese idR 3stufig sind — vom Simplen über das Komplizierte zum Einfachen. Das mehr oder weniger Komplizierte war hier reichlich vertreten, zum Schluss ergab sich aber doch das Einfache. So sollte es eigentlich immer sein…
Die Besonderheit hier war aber selbstverständlich das, was du formuliert hast, die Zusammenarbeit und ggseitige Ergänzung. Das hat man normalerweise als „Einzelkämpfer“ nicht und bleibt deshalb oft auf der Stufe des Komplizierten hängen (allerdings soll's auch Leute geben, die sich mit dem Simplen begnügen!)… ;-)
Ahoi + schöWE! Luc :-?

Anzeige
Mittelwert gewichtet
21.06.2013 19:19:20
Erich
Hi ?,
ist es das?
 ABCDEF
1Dop1Dop2Dop3Einz1Einz2MW
2246454,125
3     leer
41 34 2,4
52 64 4
6123452,625

Formeln der Tabelle
ZelleFormel
F2=WENN(ANZAHL(A2:E2)=0;"leer"; (2*(SUMME(A2:C2))+SUMME(D2;E2))/(2*ANZAHL(A2:C2)+ANZAHL(D2:E2)))


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

AW: Mittelwert gewichtet
21.06.2013 19:38:55
lapinana
Ganz herzlichen Dank allen, die sich Gedanken gemacht und mir zu helfen versucht haben! Danke, Erich! Genau das ist es! Soeben habe ich die Formel auf meine Tabelle übertragen und enstrechend angepasst! Die Berechnung stimmt! Leider aber wird nur eine Nachkommastelle angezeigt. Wenn du noch Zeit hast und bereit bist, mir auch damit noch zu helfen, wäre ich erleichtert: An unserer Schule wird nach der zweiten Nachkommastelle ungerundet abgeschnitten. Weißt du, wo ich diese Funktion in Excel 2013 finde? Ich suche aber parallel mal im Netz, ich bin ja schon heilfroh, dass sich noch jemand gefunden hat, der einem Geisteswissenschafler ohne Sinn für Mathe und Computer beim Zeugnisnotenberechnen geholfen hat!

Anzeige und Rundung
21.06.2013 19:51:54
Erich
Hi,
das sind zwei verschiedene Themen:
a) "wird nur eine Nachkommastelle angezeigt"
So stimmt dass wohl nicht - 2,625 hat mindestens 3 Nachkommastellen.
Wie eine Zahl in einer Zelle angezeigt wird, hängt vom Zahlenformat der Zelle ab.
2,625 kann z. B. als 262,5% oder 263% angezeigt werden. Der Wert der Zelle bleibt 2,625.
Du kannst das Zahlenformat der MW-Zellen nach deinen Wünschen formatieren.
b)
Hier geht es jetzt nicht um die Anzeige des Wertes, sondern den Wert selbst, der in der Zelle steht.
Du möchtest ihn abrunden, und dafür gibt es die Fkt. ABRUNDEN. :-)
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

Anzeige und Rundung noch einmal
21.06.2013 19:53:14
Erich
Hi,
das sind zwei verschiedene Themen:
a) "wird nur eine Nachkommastelle angezeigt"
So stimmt dass wohl nicht - 2,625 hat mindestens 3 Nachkommastellen.
Wie eine Zahl in einer Zelle angezeigt wird, hängt vom Zahlenformat der Zelle ab.
2,625 kann z. B. als 262,5% oder 263% angezeigt werden. Der Wert der Zelle bleibt 2,625.
Du kannst das Zahlenformat der MW-Zellen nach deinen Wünschen formatieren.
b)
Hier geht es jetzt nicht um die Anzeige des Wertes, sondern den Wert selbst, der in der Zelle steht.
Du möchtest ihn abrunden, und dafür gibt es die Fkt. ABRUNDEN oder KÜRZEN. :-)
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

AW: Formel für Mittelwert
21.06.2013 19:53:31
lapinana
Tut mir leid, wenn ich hier offenbar mehrere Leute verärgert habe! Das war wahrlich nicht meine Absicht.
@Luc: Die Formel mit den Prozentzahlen funktioniert so leider nicht, da ich ja erst am Schuljahresende alle Noten habe, aber auch schon zum Zwischenzeugnis, wenn noch nicht alle Prüfungen geschrieben sind, einen Mittelwert brauche.
@Hajo: Entschuldigung! Ich wollte hier nicht für Ärger sorgen!
@Erich: Danke für die Hilfe und die Nachsicht mit fehlerhaften Menschen!
Einen schönen Abend allen!
Anna

Danke für deine Rückmeldung, und ...
21.06.2013 20:15:31
Erich
Hi Anna, (gibt es einen Geisteswissenschaftler, der Anna heißt? ;-) )
... keine Bange, du hast wohl niemanden verärgert, nicht nicht für Ärger gesorgt!
"Nachsicht mit fehlerhaften Menschen" == "Nachsicht mit Menschen"
Ist nicht jeder Mensch fehlerhaft? (außer dem Papst natürlich, und mir ...)
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

AW: Formel für Mittelwert
21.06.2013 20:08:19
Raphael
Hallo Lapinana,
ich sehe hier viele Lösungswege aber den offensichtlichsten nicht. Vielleicht habe auch ich etwas falsch verstanden, aber wenn du nur doppelt und einfach (bzw. ganz und halb) gewichtest, dann kannst du Hajos Formel einfach anpassen.
Den Bereich den du Ganz bzw. Doppelt gewichtest fragst du unter Mittelwert 2x ab und schon hast dus.
{=MITTELWERT(WENN(A6:C6"";A6:C6);WENN(A6:C6"";A6:C6);D6:E6)}
Gruss
Raphael

AW: Formel für Mittelwert
21.06.2013 20:19:23
lapinana
Hallo Raphael,
danke auch für dein Bemühen. Da ich noch nie mit Excel gearbeitet habe, verstehe ich leider nicht, was zu tun ist. Ich hatte schlicht eine Tabelle eines Kollegen bekommen, bei dem es nur vier ganze Prüfungen gibt (die dann in einem Extrafeld wieder 2:1 mit mündlichen Leistungen gerechnet werde). An dieser habe ich versucht, mich in Excel zu orientieren, und sie auf fünf Prüfungen auszuweiten, was mir leider trotz intensiven Lesens vieler Hilfeseiten nicht gelungen ist. Mir ist klar, dass man sich mit einem Computerprogramm ausgiebig beschäftigen sollte, wenn man damit arbeiten möchte. Einem Sprachenlehrer bleibt da wohl nur der Taschenrechner für die Notenberechnung. Es ist aber schön zu sehen, dass einem auf dieser Welt immer wieder fremde Menschen helfen oder es zumindest versuchen. Danke!

AW: Formel für Mittelwert
21.06.2013 20:25:34
Raphael
Da würde ich nicht den TR bemühen. Ich poste es dir so wie Hajo, dann ist es wahrscheinlich einfacher in der eigenen Tabelle umzusetzen.
Tabelle1

 ABCDEF
6123452.625
7246454.125
8123  2
91 3 11.8
102    2

Formeln der Tabelle
ZelleFormel
F6{=MITTELWERT(WENN(A6:C6<>"";A6:C6); WENN(A6:C6<>"";A6:C6); D6:E6)}
F7{=MITTELWERT(WENN(A7:C7<>"";A7:C7); WENN(A7:C7<>"";A7:C7); D7:E7)}
F8{=MITTELWERT(WENN(A8:C8<>"";A8:C8); WENN(A8:C8<>"";A8:C8); D8:E8)}
F9{=MITTELWERT(WENN(A9:C9<>"";A9:C9); WENN(A9:C9<>"";A9:C9); D9:E9)}
F10{=MITTELWERT(WENN(A10:C10<>"";A10:C10); WENN(A10:C10<>"";A10:C10); D10:E10)}
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruss
Raphael

AW: Formel für Mittelwert
21.06.2013 20:35:54
lapinana
Herzlichen Dank! Funktioniert auch! Am Ende des Tages werde ich doch noch meine Notenlistenberechnungsvorlage bekommen und dann bis in alle Ewigkeit verwenden können! Danke.

AW: Formel für Mittelwert
21.06.2013 20:57:44
Raphael
Bitte.
Uns allen gings mal so. Oder besser gesagt uns allen geht's immer wieder mal genau so wie dir.
Also viel Spass damit.
Gruess
Raphael

und noch kein Ende...
21.06.2013 21:09:42
Erich
Hi,
Raphaels Formel (in G2) lässt sich noch stark vereinfachen - in H2 steht die Formel ohne WENN und ohne Matrix:
 ABCDEFGHIJ
1Dop1Dop2Dop3Einz1Einz2MWMWMWMWMW2
2246454,1254,1254,1254,124,12
3     leer#DIV/0!#DIV/0!leer0
41 34 2,42,42,42,42,5
52 64 44444
6123452,6252,6252,6252,622,62

Formeln der Tabelle
ZelleFormel
F2=WENN(ANZAHL(A2:E2)=0;"leer"; (2*(SUMME(A2:C2))+SUMME(D2;E2))/(2*ANZAHL(A2:C2)+ANZAHL(D2:E2)))
G2{=MITTELWERT(WENN(A2:C2<>"";A2:C2); WENN(A2:C2<>"";A2:C2); D2:E2)}
H2=MITTELWERT(A2:C2;A2:C2; D2:E2)
I2=WENN(ANZAHL(A2:E2)=0;"leer";KÜRZEN(MITTELWERT(A2:C2;A2:C2; D2:E2); 2))
J2=ABRUNDEN(WENNFEHLER(MITTELWERT(A2:C2)*(0,75+0,25*(SUMME(D2:E2)=0)); 0) +WENNFEHLER(MITTELWERT(D2:E2) *(0,25+0,75*(SUMME(A2:C2)=0)); 0); 2)
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen

In I2 steht H2 ergänzt um Fehlerabfänger-WENN und Abrunden.
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

AW: und noch kein Ende...
21.06.2013 21:20:22
Raphael
Danke Erich,
schon wieder was gelernt.
Gruess
Raphael

Dank zurück!
21.06.2013 21:31:09
Erich
Hi Raphael,
gelernt habe ich eher von dir! Du hast doch die Idee aufgebracht, im MITTELWERT den 1. Bereich doppelt anzugeben.
Dass man das A2:C2<>"" weglassen kann, entstand aus der Überlegung, dass es dem Mittelwert egal ist,
ob in den Zellen Text steht oder nicht. Da kann auch "xyz" in der Zelle stehen.
Wichtig ist für den Mittelwert doch nur, ob in den Zellen Zahlen stehen oder nicht.
Und wenn mindestens eine Zahl da ist, regelt Mittelwert den Rest (leere Zellen, Texte, ...) von allein.
Schönen Abend noch! - Grüße aus Kamp-Lintfort von Erich

Finale
22.06.2013 08:57:36
Erich
Hi zusammen,
damit er leichter zu finden ist, in einem anderen Zweig dieses Threads - hier ist
Lucs krönender Abschluss: :-)
https://www.herber.de/forum/archiv/1316to1320/t1318986.htm#1319025
(als Link ins Archiv, damit er auch übernächste Woche noch funktioniert...)
Für Eilige hier noch mal Lucs Formel:
=WENNFEHLER(KÜRZEN(MITTELWERT(A2:C2;A2:E2);2);"")
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

Beliebteste Forumthreads (12 Monate)

Anzeige
Jetzt das Excel-Portal bewerten: Deine Stimme zählt!

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige