Werte hochsummieren - fcs | HERBERS Excel Forum

Hallo Franz,
Gerne würde ich bzgl. dem Planungsfile wieder auf Dich zukommen, in der Hoffnung, Du kannst mir weiterhelfen!?!
Ich habe deinen Code in der Zwischenzeit weiter verarbeitet und im Planungsfile integriert.
https://www.herber.de/bbs/user/87869.txt
An einem Sachverhalt stecke ich jedoch noch fest. Und zwar definiere ich die WBS Elemente (1.1.1.2. etc.) über bestimmte Dropdown-Listen. Der vollständige Code erscheint erst, wenn alle Charakteristiken definiert wurden, solange steht in der Zeile "#NV".
Wenn ich ein Planwert eingeben möchte, bevor ich das ganze Projekt definiert habe, erscheint die VBA Fehlermeldung "Beenden" bzw. "Debuggen".
Wäre es möglich, dass wenn man versucht ein Planwert einzugeben, bevor man das ganze Projekt definiert hat (d.h. kein #NV bei den WBS Elementen), ein Warnhinweis erscheint wie zB. "#NV! - Bitte zuerst die Projektstruktur definieren" und der Code vorzeigt abbricht, bevor er die Fehlermeldung generiert?
Ich habe es bereits mit If-Then-Else versucht, jedoch hat es leider nicht richtig funktioniert.
Für Deine Hilfe wäre ich Dir sehr dankbar!
Beste Grüsse
Dip

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Dip,
der Fehler kann an unterschiedlichen Stellen auftreten. Ich hab deshalb in 2 Prozeduren Fehlerbehandlungen/Prüfungen eingebaut.
Gruß
Franz

'Ereignismakro unter dem Tabellenblatt
Private Sub Worksheet_Change(ByVal Target As Range)
Dim lngZeile1 As Long, lngZeile2 As Long, lngZeile As Long
Dim rngZelle As Range
On Error GoTo Beenden
Select Case Target.Column
Case gSpalteTotal, Is >= gSpalteJan1
Select Case Target.Row
Case Is >= gZeileProj1
If Me.ToggleButton1 = False Then
For Each rngZelle In Target.Cells
If Not IsNumeric(rngZelle.Value) Then
MsgBox "Als Eingaben sind in diesem Zellbereich nur Zahlen zulässig!", , _
"Daten zu Projekt neu berechnen"
Exit Sub
End If
Next
'1. Zeile Projekt ermitteln
lngZeile = Target.Row
lngZeile1 = lngZeile
Do Until Me.Cells(lngZeile1 - 1, 1) = ""
lngZeile1 = lngZeile1 - 1
Loop
'Letzte Zeile Projekt ermitteln
lngZeile = Target.Row
lngZeile2 = lngZeile
Do Until Me.Cells(lngZeile2 + 1, 1) = ""
lngZeile2 = lngZeile2 + 1
Loop
Call AdditionenVBAProjekt(Zeile1:=lngZeile1, Zeile2:=lngZeile2)
End If
End Select
End Select
Beenden:
With Err
Select Case .Number
Case 0 'alles OK
Case 13
MsgBox "#NV! - Bitte zuerst die Projektstruktur definieren", vbInformation + vbOKOnly,  _
_
"Prüfung vollständige Projektstruktur"
Case Else
MsgBox "Fehler-Nr.: " & .Number & vbLf & .Description, _
vbInformation + vbOKOnly, "Makro: Worksheet_Change"
End Select
End With
End Sub
'Makro im allgemeinen Modul
Sub Alle_Teilergebnisse_berechnen()
Dim lngZeile1 As Long, lngZeile2 As Long, lngZeile As Long
On Error GoTo Beenden
With ActiveSheet
lngZeile1 = gZeileProj1
'Letzte Zeile letztes Projekt ermitteln
lngZeile2 = .Cells(.Rows.Count, 1).End(xlUp).Row
'Fehlerprüfung - Summen-Berechnung über die WBS-Nummern ergibt Fehler wenn Fehler in einer  _
Zelle
lngZeile = Application.WorksheetFunction.Sum(.Range(.Cells(lngZeile1, 1), .Cells(lngZeile2,  _
1)))
Call AdditionenVBAProjekt(Zeile1:=lngZeile1, Zeile2:=lngZeile2)
'Werte in Leer-Zeilen zwischen Projekten wieder löschen
With .Range(.Cells(lngZeile1, 1), .Cells(lngZeile2, 1))
If Application.WorksheetFunction.CountBlank(.Cells) > 0 Then
.SpecialCells(xlCellTypeBlanks).EntireRow.ClearContents
End If
End With
End With
Beenden:
With Err
Select Case .Number
Case 0 'alles OK
Case 1004 'Fehler wenn Summe nicht berechnet werden kann
MsgBox "#NV! - Bitte zuerst die Projektstruktur definieren", vbInformation + vbOKOnly,  _
_
"Prüfung vollständige Projektstruktur"
Case Else
MsgBox "Fehler-Nr.: " & .Number & vbLf & .Description, _
vbInformation + vbOKOnly, "Makro: Alle_Teilergebnisse_berechnen"
End Select
End With
End Sub

Beliebteste Forumthreads (12 Monate)

Werte hochsummieren - fcs

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Werte hochsummieren - fcs

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread