Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1344to1348
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Datenschnitt Pivot, jedes Element drucken

Datenschnitt Pivot, jedes Element drucken
05.01.2014 12:27:14
Tim
Hallo zusammen,
in einer Pivot habe ich einen Datenschnitt eingefügt. Ich möchte jetzt, dass jedes Element des Datenschnitts ( sind mindestens 200) aufgerufen und gedruckt wird ( ggf. zunächst als PDF abgespeichert wird, jedoch dann als eine PDF-Datei und nicht mehrere).
Die Elemente des Datenschnitts sind nicht fix, sondern können sich von Update zu Update entsprechend verändern, Elemente fallen weg oder es kommen neue hinzu.
Vermutlich funktioniert das nur über VBA, bloß wie am einfachsten?
Danke

2
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Datenschnitt Pivot, jedes Element drucken
06.01.2014 01:09:52
fcs
Hallo Tim,
alle Ausdrucke in ein PDF-File funktioniert nicht ohne weiteres.
Hier ist es einfacher, alle Datenschnitte in Einzeldateien zu speichern und diese dann mit einem Tool (z.B. Adobe Acrobat oder FreePDF-Join) in einer PDF-Datei zusammenzufassen.
Nachfolgend 2 Makros, die du bezüglich des Namens des Datenschnitts noch anpassen musst.
Gruß
Franz
Sub DatenSchnitteDrucken()
' Datenschnitte Drucken
Dim objSlicerItem As SlicerItem, objSlicerCache As SlicerCache
Dim intItem As Integer
Dim wks As Worksheet
Set wks = ActiveSheet
Set objSlicerCache = ActiveWorkbook.SlicerCaches("Datenschnitt_Feld03") 'Name anpassen, _
ggf. mit Makrorekorder Datenschnittselektion aufzeichnen.
objSlicerCache.ClearManualFilter
If objSlicerCache.SlicerItems.Count > 1 Then
For intItem = 2 To objSlicerCache.SlicerItems.Count
objSlicerCache.SlicerItems(intItem).Selected = False
Next
wks.PrintOut
For intItem = 2 To objSlicerCache.SlicerItems.Count
objSlicerCache.SlicerItems(intItem).Selected = True
objSlicerCache.SlicerItems(intItem - 1).Selected = False
wks.PrintOut
Next
Else
wks.PrintOut
End If
End Sub
Sub DatenSchnitteMakePDFs()
' Datenschnitte  als PDFs speichern
Dim objSlicerItem As SlicerItem, objSlicerCache As SlicerCache
Dim intItem As Integer, strNamePDF
Dim wks As Worksheet
Set wks = ActiveSheet
Set objSlicerCache = ActiveWorkbook.SlicerCaches("Datenschnitt_Feld03") 'Name anpassen, _
ggf. mit Makrorekorder Datenschnitt-Filterselektion aufzeichnen.
objSlicerCache.ClearManualFilter
If objSlicerCache.SlicerItems.Count > 1 Then
For intItem = 2 To objSlicerCache.SlicerItems.Count
objSlicerCache.SlicerItems(intItem).Selected = False
Next
strNamePDF = ActiveWorkbook.Path & "\" & Format(1, "0000") _
& objSlicerCache.SlicerItems(1).Name & ".pdf"
wks.ExportAsFixedFormat Type:=xlTypePDF, Filename:=strNamePDF, _
Quality:=xlQualityStandard, includedocproperties:=True, _
ignoreprintareas:=False, openafterpublish:=False
For intItem = 2 To objSlicerCache.SlicerItems.Count
objSlicerCache.SlicerItems(intItem).Selected = True
objSlicerCache.SlicerItems(intItem - 1).Selected = False
strNamePDF = ActiveWorkbook.Path & "\" & Format(intItem, "0000") _
& objSlicerCache.SlicerItems(intItem).Name & ".pdf"
wks.ExportAsFixedFormat Type:=xlTypePDF, Filename:=strNamePDF, _
Quality:=xlQualityStandard, includedocproperties:=True, _
ignoreprintareas:=False, openafterpublish:=False
Next
Else
strNamePDF = ActiveWorkbook.Path & "\" & Format(1, "0000") _
& objSlicerCache.SlicerItems(1).Name & ".pdf"
wks.ExportAsFixedFormat Type:=xlTypePDF, Filename:=strNamePDF, _
Quality:=xlQualityStandard, includedocproperties:=True, _
ignoreprintareas:=False, openafterpublish:=False
End If
End Sub

Anzeige
AW: Datenschnitt Pivot, jedes Element drucken
07.01.2014 19:42:55
Tim
Hallo Franz,
super, vielen Dank. Klappt wunderbar!
Gruß Tim

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige