Live-Forum - Die aktuellen Beiträge
Datum
Titel
24.04.2024 00:20:14
Bestimmte Spalten als xls exportieren per Makro
23.04.2024 22:08:10
Auflisten in Spalte VBA
23.04.2024 21:33:46
Nur farbige/nicht farbige Zellen markieren
23.04.2024 21:29:56
Bestimmte Zellen auf andere Arbeitsblätter kopieren
Du findest keine passende Antwort auf Deine Frage?
Stelle Deine Frage in unserem Live-Forum
Anzeige
Archiv - Navigation
1420to1424
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1420to1424
1420to1424
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Formel stabiler machen

Formel stabiler machen
11.04.2015 21:32:20
Thomas

Hallo,
ich berechne mit der Formel
SUMME(WENN((MONAT(auswertung2!$A$2:$A187)=E$2)*(auswertung2!$A$2:$A187>0)*(JAHR(auswertung2!$A$2:$A187)=$A$1);auswertung2!$B2:$B100))
monatlich die betroffenen Werte. Nun kommt es vor das in der Datumsspalte (A) auch ein Text geschrieben ist ( z. B. nur abfrage) so das es noch kein Datum gibt. Leider gibt die Formel dann ine Fehlermeldung aus.
Ist es möglich diese Formel so zu Ändern das die anderen Werte trotzdem berechnet werden? Cool würde auch sein wenn es eine Formel gibt welche mir die Textwerte Zählt
und in einer extraspalte stehen würde in welcher Zeile ich Sie finde.
https://www.herber.de/bbs/user/97030.xlsx
Liebe Güsse Thomas

12
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Formel stabiler machen
11.04.2015 22:10:59
Matze
Hi Thomas,
Formelexperten machen das bestimmt wieder kürzer, ich hab hier einfach mal die Funktion "Wennfehler" benutzt. Am Ende der Formel findest du den Rückgabewert in dem Fall die 0 sobald die Formel einen Fehler schreibt.
{=WENNFEHLER(SUMME(WENN((MONAT(auswertung2!$A$2:$A187)=E$2)*(auswertung2!$A$2:$A187>0) *(JAHR(auswertung2!$A$2:$A187)=$A$1);auswertung2!$B2:$B100));0) }
{=WENNFEHLER(ANZAHL(WENN((MONAT(auswertung2!$A$2:$A188)=E$2)*(auswertung2!$A$2:$A188>0) *(JAHR(auswertung2!$A$2:$A188)=$A$1);auswertung2!$B3:$B101));0) }
Die geschweiften Klammern nicht mit eingeben die Formel mit
Strg+Shift+Enter Abschließen
Gruß Matze

Anzeige
Oh ich glaub da hab ich wieder zu schnell
11.04.2015 22:17:28
Matze
Hi Thomas gelesen,
du willst ja trotz des Textes in Spalte A einen berechneten Wert haben.
Ich stell mal auf offen , ich muss passen ,bin aber auf eine Lösung durch die Profis gespannt.
Gruß Matze

AW: Formel stabiler machen
11.04.2015 22:21:04
Daniel
Hi
du hast Excel 2007 und damit einige neue Funktionen, die dir helfen dein Problem zu lösen.
nimm folgendes (Formeln für Spalte E)
Summe pro Monat: =SUMMEWENNS($B:$B;$A:$A;">="&DATUM($A$1;E$2;1);$A:$A;"<"&DATUM($A$1;E$2+1;1))
Anzahl pro Monat: =ZÄHLENWENNS($A:$A;">="&DATUM($A$1;E$2;1);$A:$A;"<"&DATUM($A$1;E$2+1;1))
Anzahl der Texte: in Spalte A: =Anzahl2(A:A)-Anzahl(A:A)
Zeilennummer des ersten Textes: =Vergleich("*";A:A;0)
Gruß Daniel

Anzeige
AW: Formel stabiler machen
11.04.2015 22:48:21
Thomas
Hallo,
erst mal besten Dank für eure Vorschläge auch Dir Matze Matthias. Ich finde es super das Du es versucht hast.
die Lösungen von Daniel und von Luschi funktionieren beide super die Fehlermeldung ist weg.
Und cool sind auch die weitern Lösungen von Daniel. Alle Formeln Funktionieren. Ich bin total begeistert. Daniel hast Du auch noch eine Idee wie ich alle Zeilennummern Auflisten Könnte in denen ein Text steht?.
nochmal ganz liebe dank Ihr habt mir das WE gerettet. Allein hätte ich das nie geschafft.
Liebe grüsse Thomas

AW: Formel stabiler machen
11.04.2015 23:38:50
Daniel
Hi
als Matrixformel (eingabe mit STRG+SHIFT+ENTER abschließen)
=KKLEINSTE(WENN(ISTTEXT($A$1:$A$99);ZEILE($A$1:$A$99));ZEILE(A1))
Formel soweit wie benötigt nach unten ziehen.
Zellbereich für Spalte A anpassen.
Gruß Daniel

Anzeige
AW: Formel stabiler machen
12.04.2015 00:07:12
Luschi
Hallo Thomas,
ab Excel 2010 geht es auch so (ohne Strg+Shift+Enter):
=AGGREGAT(15;6;ZEILE($A$1:$A$99)/ISTTEXT($A$1:$A$99);ZEILE(A1))
da diese neue Funktion selbst Matrix-Funktioalität hat.
15 - KKleinste
 6 - Fehlerwerte ignorieren.
Gruß von Luschi
aus klein-Paris

Auflisten, in welcher Form, ...
12.04.2015 00:10:20
Luc:-?
…Thomas?
1. Als Matrix/Vektor über ggf mehrere Zellen (Spalten u/o Zeilen) mit alten Fktt per MatrixFml bspw so:
F1:F14: {=KKLEINSTE(WENN(ISTTEXT(A1:A20);ZEILE(A1:A20);"");ZEILE(A1:A20))}
2. Alle zusammen in einer Zelle als Liste mit einer UDF dann zB so:
F15: {=VJoin(WENN(ISTTEXT(A1:A20);ZEILE(A1:A20);"");", ";-1)}
Der Link führt nicht zur neuesten Version (Vs1.3) von VJoin. Da diese in einer hochgeladenen Mappe enthalten ist, dürfte sie auch nur schwer zu finden sein. Die verlinkte Vs1.1 sollte aber ausreichen.
Gruß, Luc :-?

Anzeige
AW: Auflisten, in welcher Form, ...
12.04.2015 08:27:20
Thomas
Hallo Luc
erstmal besten dank für die Lösungen. Die Matrixformel funktioniert super aber das mit der UDF bekomme ich nicht sauber dargestellt. Kannst Du noch mal schauen was ich falsch mache? Ich habe den Code in ein allgemeines Modul kopiert,aber es kommt nur #Name? als Ergebnis,
Es klinkt sehr spannend alle in eine zelle zu verketten.
https://www.herber.de/bbs/user/97032.xlsm
Liebe Grüsse Thomas

Pardon, habe den Link aus Versehen doch ...
12.04.2015 14:04:36
Luc:-?
…auf Vs1.0 gesetzt, Thomas,
die noch nicht ideal ist (Vs1.1 hätte aber sicher gereicht). Deshalb deine Datei zurück mit einigen angebrachten Korrekturen und der neuesten VJoin-Vs1.3 (VSplit brauchst du hierbei zwar nicht, ist aber aktuell).
Gruß+schöSo, Luc :-?

Anzeige
AW: Pardon, habe den Link aus Versehen doch ...
12.04.2015 20:57:45
Thomas
Hallo Luc,
Die Lösung ist riesig somit habe ich alle Informationen in einer Zelle.
Einfach spitze besten Dank.
Liebe Grüsse Thomas

Bitte sehr, gern geschehen! ;-) owT
13.04.2015 01:07:58
Luc:-?
:-?

AW: Formel stabiler machen
11.04.2015 22:21:19
Luschi
Hallo Thomas,
als Matrixformel für Zelle 'E4':
{=SUMME((WENNFEHLER(MONAT($A$2:$A$17)=MONAT(E$1);0))*(WENNFEHLER(JAHR($A$2:$A$17)=JAHR(E$1);0)) *($B$2:$B$17)) }
und dann nach rechts ziehen!
Matrixformel: Strg+Shift+Return
Gruß von Luschi
aus klein-Paris

Beliebteste Forumthreads (12 Monate)

Anzeige
Jetzt das Excel-Portal bewerten: Deine Stimme zählt!

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige