Live-Forum - Die aktuellen Beiträge
Datum
Titel
19.04.2024 19:41:34
Bei VBA Ausführung Anzeige einfrieren
19.04.2024 17:05:40
Zählen von Zeilen, in denen in bestimmten Bereich Daten sind
19.04.2024 16:34:52
gemeinsamer Filter über drei Spalten
19.04.2024 15:39:42
Exceltabelle daten per combobox zu word Datei
Du findest keine passende Antwort auf Deine Frage?
Stelle Deine Frage in unserem Live-Forum
Anzeige
Archiv - Navigation
1420to1424
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1420to1424
1420to1424
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Runden 1/4 Stunde dezimal / Verteilung

Runden 1/4 Stunde dezimal / Verteilung
16.04.2015 15:31:28
Doris
Hallo zusammen,
ich habe in 3 Zellen dezimale Zeiten.
mit der Formel =RUNDEN(A1*24;0)/24 etc konnte ich auf eine viertel Stunde zwar runden, jedoch stimmt die Verteilung nun nicht mehr, d.h. die Summe der 3 Zellen ist ungleich
Gibt es eine andere Möglicheit?

15
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Runden 1/4 Stunde dezimal / Verteilung
16.04.2015 15:32:56
Hajo_Zi
muss doch auch, da die einen Zellen gerundet.

AW: Runden 1/4 Stunde dezimal / Verteilung
16.04.2015 15:38:15
Doris
es sind alle 3 Zellen gerundet. Gibt es keine Möglichkeit die Rundung aufzuteilen (ab-, auf?)

Gerundete Summe ungleich Summe der Gerundeten
16.04.2015 17:05:43
Erich
Hi Doris,
zeigen die Zeilen 4:5 in etwa dein Problem, oder habe ich das falsch verstanden?
Vielleicht ist die Formel in B10 eine Lösung. Damit wird einer der Werte nicht als Ergebnis einer Rundung ermittelt,
er wird vielmehr als Differenz bestimmt.
 AB
101:2301:30
201:4801:45
301:5302:00
405:0405:00
5 05:15
6  
7  
801:2301:30
901:4801:45
1001:5301:45
1105:0405:00
12 05:00

Formeln der Tabelle
ZelleFormel
B1=RUNDEN(A1*96;0)/96
B2=RUNDEN(A2*96;0)/96
B3=RUNDEN(A3*96;0)/96
A4=SUMME(A1:A3)
B4=RUNDEN(A4*96;0)/96
B5=SUMME(B1:B3)
B8=RUNDEN(A8*96;0)/96
B9=RUNDEN(A9*96;0)/96
B10=B11-SUMME(B8:B9)
A11=SUMME(A8:A10)
B11=RUNDEN(A11*96;0)/96
B12=SUMME(B8:B10)


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8
Noch etwas:
Wie rundest du mit "RUNDEN(A1*24;0)/24" auf Viertelstunden? Bei mir sieht das aus wie die Rundung auf volle Stunden.
Auf Viertelstunden runde ich mit "RUNDEN(A1*96;0)/96". Ein Tag hat eben 96 Viertelstunden.
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

Anzeige
Industriezeiten und Excelzeiten
16.04.2015 19:29:46
lupo1
Wie Erich schon sagte:
=RUNDEN(A1*4;)/4 Industriezeiten
=RUNDEN(A1*96;)/96 Excel-Zeiten
Die Summe von Rundungen ist der Summe Ungerundeter nur ÄHNLICH GROSS, nicht GLEICH.
___________________________________________________________________
MfG Lupo - 11.10.2012: {MSO 2000 SP3;Win 7} - 28.02.2013: {MSO 2010;Win 8.1} (beide vorhanden; meistens 2010 verwendet)

AW: Gerundete Summe ungleich Summe der Gerundeten
17.04.2015 10:20:03
Doris
Hallo Erich,
ich hätte zwar auf eine Formel gehofft, die ein automatisches Verteilen möglich macht, aber mit der Differenz komm' ich evtl. erst mal klar. Ich rechne übrigens mit Dezimalzeiten, natürlich so: =RUNDEN(A1*4;0)/4
natürlich mit der 4 nicht 24 (Tippfehler)
Die Zeiten errechnen sich prozentual aus einer anderen Tabelle, in der alle Zeiten 1/4 Stündlich sind.
Bsp.
Tabelle1
A1 = 17
A2 = 50,5
A3 = 2,5
Summe:70
Tabelle2
A1 = Tabelle1A1 + Tabelle1A2 + 10% v. Tabelle1A3 = 24,5
A2 = 20% v. Tabelle1A3 = 10
A3 = 70% v. Tabelle1A3 = 35,25
Summe: 69,75

Anzeige
AW: Gerundete Summe ungleich Summe der Gerundeten
17.04.2015 10:34:53
Doris
Tabelle1

 AB
11724,5
250,510
32,535,25
47069,75

Formeln der Tabelle
ZelleFormel
B1=A1+A3+RUNDEN(A2*10%*4;0)/4
B2=RUNDEN(A2*20%*4;0)/4
B3=RUNDEN(A2*70%*4;0)/4
A4=SUMME(A1:A3)
B4=SUMME(B1:B3)


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Anzeige
Gerundete Summe - Differenz verteilen
17.04.2015 11:20:21
Erich
Hi Doris,
so eine (oder mehrere) Verteil-Formel gibt es. Schau dir mal
http://www.excelformeln.de/formeln.html?welcher=347
an. Sicher findest du hier in der Recherche einige Threads dazu, wenn du z. B. suchst nach
summe runden 347
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

AW: Gerundete Summe - Differenz verteilen
17.04.2015 11:48:47
Doris
Hallo Erich,
das schaut zwar nicht schlecht aus, jedoch gibt es dort nicht die 1/4Stunden Rundung.
Ich habe nun für die Zellen in Spalte 1 die Differenz, damit komme ich auf gleiche Ergebnisse.
Vielen Dank Dir und liebe Grüße aus Andernach, Dori
Tabelle1

 AB
11724,75
250,510
32,535,25
47070

Formeln der Tabelle
ZelleFormel
B1=SUMME(A1:A3)-SUMME(B2:B3)
B2=RUNDEN(A2*20%*4;0)/4
B3=RUNDEN(A2*70%*4;0)/4
A4=SUMME(A1:A3)
B4=SUMME(B1:B3)


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Anzeige
Die XlFkt RUNDEN rundet stets asymmetrisch ...
17.04.2015 13:26:10
Luc:-?
…(kaufmännisch), Doris,
die vbFkt Round symmetrisch (wiss-techn, Banken). Auf dieser Basis kann man eine eigene Fkt (sog UDF) entwickeln, die dabei auch einen ganzen Zahlenbereich heranziehen kann. Damit würde das Ergebnis deinen Wünschen näher kommen, aber ihnen viell noch nicht ganz entsprechen.
Eine solche UDF befindet sich in einer vor Jahren hochgeladenen Datei im Archiv → RoundA.
Gruß, Luc :-?

AW: Die XlFkt RUNDEN rundet stets asymmetrisch ...
20.04.2015 14:31:05
Doris
Hallo Luc,
danke für den Tip, werde evtl. später mal danach schau'n, klingt zumindest auch interessant, vielleicht für andere Berechnungen.
Erich's Lösung ist für den Moment das was ich suchte.
Liebe Grüße, Dori

Anzeige
Nr. 347 mit 1/4-Rundung
17.04.2015 19:50:03
Erich
Hi Doris,
hier hab ich mal versucht, die 1/4-Rundung in die Nr. 347 einzubauen (Spalten C:D):
 ABCDEF
1 Quelldatenungerundetgerundet mit Ausgleich gerundet ohne Ausgleich
2 1724,5524,5 24,5
3 50,510,110,25 10
4 2,535,3535,25 35,25
5      
6Summen707070 69,75
7      
8 Hilf170   
9 Hilf2-1   

Formeln der Tabelle
ZelleFormel
C2=B2+B4+B3*10%
D2{=RUNDEN(4*C2;0)/4-WENN(C$9=0;0; (1-2*(C$9<0))*((1-2*(C$9<0))*(RUNDEN(4*C2;0)/4-C2+ZEILE()*10^-5)>=KGRÖSSTE((1-2*(C$9<0))* (RUNDEN(4*C$2:C$4;0)/4-C$2:C$4+ZEILE($2:$4)*10^-5); ABS(C$9)))/4)}
F2=B2+B4+RUNDEN(B3*10%*4;0)/4
C3=B3*20%
D3{=RUNDEN(4*C3;0)/4-WENN(C$9=0;0; (1-2*(C$9<0))*((1-2*(C$9<0))*(RUNDEN(4*C3;0)/4-C3+ZEILE()*10^-5)>=KGRÖSSTE((1-2*(C$9<0))* (RUNDEN(4*C$2:C$4;0)/4-C$2:C$4+ZEILE($2:$4)*10^-5); ABS(C$9)))/4)}
F3=RUNDEN(B3*20%*4;0)/4
C4=B3*70%
D4{=RUNDEN(4*C4;0)/4-WENN(C$9=0;0; (1-2*(C$9<0))*((1-2*(C$9<0))*(RUNDEN(4*C4;0)/4-C4+ZEILE()*10^-5)>=KGRÖSSTE((1-2*(C$9<0))* (RUNDEN(4*C$2:C$4;0)/4-C$2:C$4+ZEILE($2:$4)*10^-5); ABS(C$9)))/4)}
F4=RUNDEN(B3*70%*4;0)/4
B6=SUMME(B2:B4)
C8=RUNDEN(4*SUMME(C2:C4); 0)/4
C9=4*(SUMMENPRODUKT(RUNDEN(4*C2:C4;0)/4)-C8)
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen

Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich und: Ein schönes Wochenende allerseits!

Anzeige
AW: Nr. 347 mit 1/4-Rundung
20.04.2015 14:26:09
Doris
Hallo Erich,
wunderbar, genau so etwas brauche ich! :)
Ich habe die Formeln in meiner Tabelle angepasst, allerdings... an 3 Stellen funktioniert sie leider nicht so, wie sie soll... hab schon einen Knoten im Hirn! :D
Wenn Du magst, kannst Du ja mal reinschau'n, vielleicht findest Du den Fehler?! Die Fehler-Ergebnisse sind rot markiert.
Vielen Dank!
https://www.herber.de/bbs/user/97177.xlsx
Liebe Grüße, Dori

Fehler gefunden
20.04.2015 20:21:37
Erich
Hi Doris,
da hat sich durch das Transponieren ein Fehler eingeschlichen. In der alten Formel kommt an einer Stelle
ZEILE() vor. Der Wert ist die Zeilennummer, in der die Formel (und der Quellwert!) steht.
Nun kann daraus nicht einfach SPALTE() werden, weil der Quellwert in Spalte G, H oder I steht, die Formel
aber in Spalte K. L oder M.
Außerdem habe ich der Formel in K:M noch ein paar Dollarzeichen spendiert.
Jetzt lässt sie sich nach rechts (von K nach L:M) und nach unten kopieren:
 EFGHIJKLMN
18141,25152,37569,12519,75141,2552,56919,75141,25
19          
20102,75140,87548,12513,75102,75414813,75102,75

Formeln der Tabelle
ZelleFormel
E18=RUNDEN(4*SUMME(G18:I18); 0)/4
F18=WENN(ISTFEHLER(4*(SUMMENPRODUKT(RUNDEN(4*G18:I18;0)/4)-E18)); "-"; 4*(SUMMENPRODUKT(RUNDEN(4*G18:I18;0)/4)-E18))
G18=WENN(ISTFEHLER(SVERWEIS($D18;Januar!$C$2:$G$26;3;FALSCH)); "-"; SUMME(SVERWEIS($D18;Januar!$C$2:$G$26;3;FALSCH); SVERWEIS($D18;Januar!$C$2:$G$26;5;FALSCH); (SVERWEIS($D18;Januar!$C$2:$G$26;4;FALSCH)*10%)))
H18=WENN(ISTFEHLER(SVERWEIS($D18;Januar!$C$2:$L$24;4;FALSCH)*70%); "-"; SVERWEIS($D18;Januar!$C$2:$L$24;4;FALSCH)*70%)
I18=WENN(ISTFEHLER(SVERWEIS($D18;Januar!$C$2:$L$24;4;FALSCH)*20%); "-"; SVERWEIS($D18;Januar!$C$2:$L$24;4;FALSCH)*20%)
J18=SUMME(G18:I18)
K18{=WENN(G18="-";"-";RUNDEN(4*G18;0)/4-WENN($F18=0;0;(1-2*(F18<0))*((1-2*(F18<0))* (RUNDEN(4*G18;0)/4-G18+SPALTE(G18)*10^-5)>= KGRÖSSTE((1-2*($F18<0))*(RUNDEN(4*$G18:$I18;0)/4-$G18:$I18+ SPALTE($G:$I)*10^-5); ABS($F18)))/4))}
L18{=WENN(H18="-";"-";RUNDEN(4*H18;0)/4-WENN($F18=0;0;(1-2*(G18<0))*((1-2*(G18<0))* (RUNDEN(4*H18;0)/4-H18+SPALTE(H18)*10^-5)>= KGRÖSSTE((1-2*($F18<0))*(RUNDEN(4*$G18:$I18;0)/4-$G18:$I18+ SPALTE($G:$I)*10^-5); ABS($F18)))/4))}
M18{=WENN(I18="-";"-";RUNDEN(4*I18;0)/4-WENN($F18=0;0;(1-2*(H18<0))*((1-2*(H18<0))* (RUNDEN(4*I18;0)/4-I18+SPALTE(I18)*10^-5)>= KGRÖSSTE((1-2*($F18<0))*(RUNDEN(4*$G18:$I18;0)/4-$G18:$I18+ SPALTE($G:$I)*10^-5); ABS($F18)))/4))}
N18=SUMME(K18:M18)
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen

Ich hoffe, ich habe nicht zu viel verschlimmbessert... :-)
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

Anzeige
Korrektur: mehr Dollarzeichen
21.04.2015 09:19:56
Erich
Hi Doris,
so ganz klappte das mit dem Kopieren der Formel (Spalten K, L, M) doch noch nicht.
Vor dem "F18" fehlten noch Dollarzeichen. So sollte es besser sein:
 EFGHIJKLMN
18141,25152,37569,12519,75141,2552,56919,75141,25
19          
20102,75140,87548,12513,75102,75414813,75102,75

Formeln der Tabelle
ZelleFormel
E18=RUNDEN(4*SUMME(G18:I18); 0)/4
F18=WENN(ISTFEHLER(4*(SUMMENPRODUKT(RUNDEN(4*G18:I18;0)/4)-E18)); "-"; 4*(SUMMENPRODUKT(RUNDEN(4*G18:I18;0)/4)-E18))
G18=WENN(ISTFEHLER(SVERWEIS($D18;Januar!$C$2:$G$26;3;FALSCH)); "-"; SUMME(SVERWEIS($D18;Januar!$C$2:$G$26;3;FALSCH); SVERWEIS($D18;Januar!$C$2:$G$26;5;FALSCH); (SVERWEIS($D18;Januar!$C$2:$G$26;4;FALSCH)*10%)))
H18=WENN(ISTFEHLER(SVERWEIS($D18;Januar!$C$2:$L$24;4;FALSCH)*70%); "-"; SVERWEIS($D18;Januar!$C$2:$L$24;4;FALSCH)*70%)
I18=WENN(ISTFEHLER(SVERWEIS($D18;Januar!$C$2:$L$24;4;FALSCH)*20%); "-"; SVERWEIS($D18;Januar!$C$2:$L$24;4;FALSCH)*20%)
J18=SUMME(G18:I18)
K18{=WENN(G18="-";"-";RUNDEN(4*G18;0)/4-WENN($F18=0;0;(1-2*($F18<0))*((1-2*($F18<0))* (RUNDEN(4*G18;0)/4-G18+SPALTE(G18)*10^-5)>= KGRÖSSTE((1-2*($F18<0))*(RUNDEN(4*$G18:$I18;0)/4-$G18:$I18+ SPALTE($G:$I)*10^-5); ABS($F18)))/4))}
L18{=WENN(H18="-";"-";RUNDEN(4*H18;0)/4-WENN($F18=0;0;(1-2*($F18<0))*((1-2*($F18<0))* (RUNDEN(4*H18;0)/4-H18+SPALTE(H18)*10^-5)>= KGRÖSSTE((1-2*($F18<0))*(RUNDEN(4*$G18:$I18;0)/4-$G18:$I18+ SPALTE($G:$I)*10^-5); ABS($F18)))/4))}
M18{=WENN(I18="-";"-";RUNDEN(4*I18;0)/4-WENN($F18=0;0;(1-2*($F18<0))*((1-2*($F18<0))* (RUNDEN(4*I18;0)/4-I18+SPALTE(I18)*10^-5)>= KGRÖSSTE((1-2*($F18<0))*(RUNDEN(4*$G18:$I18;0)/4-$G18:$I18+ SPALTE($G:$I)*10^-5); ABS($F18)))/4))}
N18=SUMME(K18:M18)
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen

Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

Anzeige
AW: Korrektur: mehr Dollarzeichen
21.04.2015 10:48:16
Doris
Supi Erich! Jetzt klappt's!!!
Die festen Bezüge habe ich in den Spalten K:M gelassen, danach aber wieder entfernt, so kann ich die kompletten Spalten in die Folgemonate kopieren.
Vielen, vielen Dank nochmal!
Und nun befasse ich mich mal mit Funktionen, die bei mir bisher noch nicht zum Einsatz kamen.. (Spalte(), Zeile() etc...) und dann endlich mal mit Matrizen! ;-)
Liebe Grüße, Dori

Beliebteste Forumthreads (12 Monate)

Anzeige
Jetzt das Excel-Portal bewerten: Deine Stimme zählt!

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige