Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1424to1428
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

150 Tabellenblätter

150 Tabellenblätter
25.05.2015 11:47:14
chito
Hallo zusammen,
mein Problem ist, ich habe ca 150 Tabellenblätter und möchte diese auf einmal umbenennen nach der zelle A1 in diesem Blatt.Die Tabelle mit dem Namen(Auswertung) soll dabei nicht geändert werden. also 149 Blätter ändern nach Zellbezug.
ich hoffe es kann mir jemand helfen.
Gruß
chito

2
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: 150 Tabellenblätter
25.05.2015 11:54:55
Sepp
Hallo chito,
' **********************************************************************
' Modul: Modul2 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Sub renameSheet()
  Dim objSh As Worksheet
  
  For Each objSh In ThisWorkbook.Worksheets
    If objSh.Name <> "Auswertung" And IsValidSheetName(objSh.Range("A1").Text) And Not SheetExist(objSh.Range("A1").Text) Then
      objSh.Name = objSh.Range("A1").Text
    End If
  Next
  
End Sub


Function IsValidSheetName(ByVal strName As String) As Boolean
  Dim objRegExp As Object
  
  Set objRegExp = CreateObject("vbscript.regexp")
  
  With objRegExp
    .Global = True
    .Pattern = "^[^\/\\:\*\?\[\]]{1,31}$"
    .IgnoreCase = True
    IsValidSheetName = .test(strName)
  End With
  
  Set objRegExp = Nothing
  
End Function


Function SheetExist(ByVal sheetName As String, Optional Wb As Workbook) As Boolean
  Dim wks As Worksheet
  
  On Error GoTo ERRORHANDLER
  
  If Wb Is Nothing Then Set Wb = ThisWorkbook
  
  For Each wks In Wb.Worksheets
    If LCase(wks.Name) = LCase(sheetName) Then SheetExist = True: Exit Function
  Next
  
  ERRORHANDLER:
  SheetExist = False
End Function


Gruß Sepp

Anzeige
AW: 150 Tabellenblätter
25.05.2015 12:00:02
chito
Hallo Sepp,
danke für die schnelle Antwort, hab´s ausprobiert und klappt prima Danke.
Gruß
chito

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige