Anzeige
Archiv - Navigation
1432to1436
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Excel Formel die Inhalt in Klammern zusammen zählt

Excel Formel die Inhalt in Klammern zusammen zählt
07.07.2015 15:12:01
eninaj
Hallo zusammen,
ich habe folgendes Problem und hoffe, dass mir jemand weiterhelfen kann:
Ich habe in aufeinanderfolgenden Zellen einige Namen stehen. Diese Namen sind gefolgt von Zahlen in runden und eckigen Klammern. Bspw. Geiger (2) [1]
Jetzt suche ich nach einer Formel, die mir sobald eine runde Klammer in den Zellen seht, die Zahlen in der runden Klammer zusammen zählt.
Dasselbe benötige ich für die eckigen Klammern.
Ist das noch mit einer Formel möglich oder muss ich da an VBA ran?
Liebe Grüße,
eninaj

14
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
nachgefragt ...
07.07.2015 15:27:02
der
Hallo,
... steht in jeder Zelle nur ein Zahlenwert mit jeweils einem Klammerpaar oder mehrere und auch verschiedenen Klammerpaaren?
Gruß Werner
.. , - ...

AW: nachgefragt ...
07.07.2015 15:34:38
eninaj
Hallo Werner,
der Inhalt der Zellen ist immer derselbe: Name (Zahl) [Zahl]
Liebe Grüße

mit AGGREGAT() auch ohne MATRIXformel ...
07.07.2015 16:02:59
der
Hallo,
... auf die Schnelle so (geht sicher auch noch etwas kürzer)
 BCD
1Namen()[]
2 999
3Müller (3) [5]  
4Meier (94) [-6]  
5   
6Schulze (2) [10]  
7   

Formeln der Tabelle
ZelleFormel
C2=SUMMENPRODUKT(AGGREGAT(14;6;--LINKS(TEIL(B3:B99;FINDEN("(";B3:B99)+1;99); FINDEN(")";TEIL(B3:B99;FINDEN("(";B3:B99)+1;99))-1); ZEILE(A1:INDEX(B:B;ANZAHL2(B3:B99)))))
D2=SUMMENPRODUKT(AGGREGAT(14;6;--LINKS(TEIL(B3:B99;FINDEN("[";B3:B99)+1;99); FINDEN("]";TEIL(B3:B99;FINDEN("[";B3:B99)+1;99))-1); ZEILE(A1:INDEX(B:B;ANZAHL2(B3:B99)))))


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...

Anzeige
AW: mit AGGREGAT() auch ohne MATRIXformel ...
07.07.2015 16:23:09
eninaj
Hallo Werner,
danke dir für die schnelle Antwort. Ich habe gerade noch das Problem, dass mein Excel die Formel mit englischen Begriffen genötigt. Versuche sie also zu "übersetzen" und melde mich dann, ob es bei mir funktioniert. :)

für Deine engliche Excel-Version ...
07.07.2015 16:25:07
der
Hallo,
... so:
 BCD
1Namen()[]
2 999
3Müller (3) [5]  
4Meier (94) [-6]  
5   
6Schulze (2) [10]  

Formeln der Tabelle
ZelleFormel
C2=SUMPRODUCT(AGGREGATE(14,6,--LEFT(MID(B3:B99,FIND("(",B3:B99)+1,99),FIND(")",MID(B3:B99,FIND("(",B3:B99)+1,99))-1),ROW(A1:INDEX(B:B,COUNTA(B3:B99)))))
D2=SUMPRODUCT(AGGREGATE(14,6,--LEFT(MID(B3:B99,FIND("[",B3:B99)+1,99),FIND("]",MID(B3:B99,FIND("[",B3:B99)+1,99))-1),ROW(A1:INDEX(B:B,COUNTA(B3:B99)))))


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...

Anzeige
AW: für Deine engliche Excel-Version ...
08.07.2015 09:21:38
eninaj
Hallo Werner,
Danke dir für die schnelle "Übersetzung". Ich kann soweit ganz gut nachvollziehen, was die Formel macht. Allerdings muss irgendwo noch ein Fehler sein, da es nicht alle Zahlen zusammenzählt.
Kannst du dir das nochmal anschauen?
Userbild
Userbild
Grüße, eninaj

in der von Dir angepassten Formel ...
08.07.2015 13:29:15
Dir
Hallo,
... hast Du den INDEX()-Formelteil nicht richtig eingesetzt, deshalb erhältst Du fehlerhafte Ergebnisse.
Nachstehend zeige ich Dir in B4:B5 die Formeln richtig auf. Zusätzlich dann noch zwei kürzere Formeln ohne SUMMENPRODUKT() dafür diesmal mit SUMME() in Kombination mit einem weiteren INDEX() und wieder ohne {}.
 ABCDEFG
1 123456
2NamenMüller (4) [2]Meier (1) [5]Schulze (3) [1]Baur (5) [2]  
3       
4()1313    
5[]1010    

Formeln der Tabelle
ZelleFormel
B4=SUMPRODUCT(AGGREGATE(14,6,--LEFT(MID(B2:G2,FIND("(",B2:G2)+1,99),FIND(")",MID(B2:G2,FIND("(",B2:G2)+1,99))-1),ROW(A1:INDEX(A:A,COUNTA(B2:G2)))))
C4=SUM(INDEX(AGGREGATE(14,6,--MID(B2:G2,FIND("(",B2:G2)+1,FIND(")",B2:G2)-FIND("(",B2:G2)-1),ROW(A1:INDEX(A:A,COUNTA(B2:G2)))),))
B5=SUMPRODUCT(AGGREGATE(14,6,--LEFT(MID(B2:G2,FIND("[",B2:G2)+1,99),FIND("]",MID(B2:G2,FIND("[",B2:G2)+1,99))-1),ROW(A1:INDEX(A:A,COUNTA(B2:G2)))))
C5=SUM(INDEX(AGGREGATE(14,6,--MID(B2:G2,FIND("[",B2:G2)+1,FIND("]",B2:G2)-FIND("[",B2:G2)-1),ROW(A1:INDEX(A:A,COUNTA(B2:G2)))),))


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...

Anzeige
Nee, musste nicht unbedingt selbst, aber evtl ...
07.07.2015 15:31:40
Luc:-?
…nutzen, eninaj;
kann man sicher auch mit mehr oder weniger langer Fml mittels XlStandardFktt lösen. Ich würde allerdings VBA-gestützte UDFs favorisieren, die die Fml kurz halten. Allerdings kommt's dann darauf an, unter welchen Bedingungen und wie „zusammengezählt“ wdn soll. Dazu hast du nichts geschrieben.
Fall (): =--MaskOn(MaskOn(A1;"mrk()");"num")
Fall []: =--MaskOn(MaskOn(A1;"mrk[]");"num")
Damit erhältst du alles in den entsprd Klammern in der Zelle als echte Zahl, wenn es sich um Zahlen handelt, sonst einen Fehler. Die UDF ist allerdings nur sehr bedingt matrixfml-fähig, d.h., ihr 1.Argument muss ein Einzelwert sein. Anderenfalls muss man eine andere Lösung finden. Aber dafür solltest du erst mal den FolgeAblauf präzisieren. Dann folgen ggf auch entsprd Links.
Gruß, Luc :-?
Besser informiert mit …

Anzeige
AW: Nee, musste nicht unbedingt selbst, aber evtl ...
08.07.2015 09:31:21
eninaj
Hallo Luc,
was sind denn UDFs?
In den Klammern stehen immer nur natürliche Zahlen. Diese sollen dann alle addiert werden.
Das Ergebnis soll in einer Zelle dargestellt werden und wird nicht weiterverwendet.
Was für Informationen benötigst du noch?
Lg, eninaj

Werte in Klammern zuammenzählen
07.07.2015 15:51:41
Daniel
Hi
wenns jeder Klammertyp ("()" oder "[]") nur einmal in der Zelle vorkommt, kannst du den Wert, der in der Klammer steht, so extrahieren:
=WENNFEHLER(--TEIL(A1;FINDEN("(";A1)+1;FINDEN(")";A1)-FINDEN("(";A1)-1);"") bzw dann für die Eckigen Klammern:
=WENNFEHLER(--TEIL(A1;FINDEN("[";A1)+1;FINDEN("]";A1)-FINDEN("[";A1)-1);"")

wenn du damit einen Zellbeeich aufsummieren willst, dann geht das auch, dies ist aber eine Matrixfomel, dh du musst die eingabe immer mit STRG+SHIFT+ENTER abschließen.
die folgende Matrixformel bildet die summe über alle Werte in runden Klammern im Bereich A1:A99
=SUMME(WENNFEHLER(--TEIL(A1:A99;FINDEN("(";A1:A99)+1;FINDEN(")";A1:A17)-FINDEN("(";A1:A99)-1);"")) 

wenn in einer Zelle mehrere Werte in runden Klammern vorkommen ("abc (1) def (2)") so nimmt diese Formel immer die erste Klammer.
Gruß Daniel

Anzeige
AW: Werte in Klammern zuammenzählen
08.07.2015 09:54:24
eninaj
Hallo Daniel,
welche Eingabe muss ich mit STRG+SHIFT+ENTER abschließen?
Da jeder Klammertyp nur einmal vorkommt, dürfte es keine Probleme geben.
Grüße eninaj

AW: Werte in Klammern zuammenzählen
08.07.2015 10:31:15
daniel
Hi
wenn du die Formel eingegeben hast drückst du nicht einfach nur ENTER (oder TAB oder klick auf Häkchen) sondern du drückst STRG+SHIFT+ENTER.
Excel weiss dann, dass es nicht einfach nur Summieren soll, sondern vor dem Summieren erst noch den Formelteil innerhalb der Summe berechnen soll um dann die Ergebnisse dieses Formelteils zu summieren.
das mit dem STRG+SHIFT+ENTER musst du immer machen, auch wenn du an dieser Formel was änderst.
Gruß Daniel

Anzeige
Problem mit Formel
08.07.2015 10:55:01
eninaj
Hi Daniel,
Alles klar, dass hab ich soweit verstanden.
Meine Formel sieht momentan so aus:
=SUM(IFERROR(--MID(B2:S2, FIND('(',B2:S2)+1,FIND(')',B2:S2)-FIND('(',B2:S2)-1),''))
Allerdings akzeptiert Excel die Formel nicht und sagt es gäbe ein Problem - das ich leider nicht finde :/
Kannst du mir sagen, wo das Problem liegt?
Lg, eninaj

AW: Problem mit Formel
08.07.2015 11:03:06
daniel
HI
keine Ahnung, ich kenne deine Daten nicht und hab auch keine englische Sprachversion.
allerdings wird normalerweise in jeder Sprachversion das doppelte Hochkomma " verwendet, um Texte zu kennzeichnen und nicht nur das einfache '.
das einfache ' wird nur bei Zellbezügen verwendet, wenn der Tabellenblattname ein Sonderzeichen enthält.
Gruß Daniel
Anzeige

314 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige