Leere Spalten ausblenden nach Nutzung Autofillter

Hallo,
ich finde leider ausnahmsweise mal nicht im Forum das Richtige - insofern bräuchte ich mal Eure Hilfe. Ist für Euch sicher ein "Witz": Ich nutze als erstes in einen Tabellenblatt die Filterfunktion (und blende damit praktisch bestimmte Zeilen aus). Jetzt hätte ich gerne, dass alle leeren Spalten der noch sichtbaren Zeilen des Tabellenblatts ausgeblendet werden. Sämtliche Spalten haben Spaltenköpfe bis Zeile 5, der Datenbereich beginnt also ab Zeile 6 und wird sukzessive unten mit Daten fortgeschrieben. Der betroffene Spaltenbereich geht im Moment von Spalte E bis BB, sollte aber auch nach rechts erweiterbar sein. Hoffe die Beschreibung ist verständlich. Vielen Dank im Voraus.
Herzliche Grüße
Martin

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Martin,
schreibe in eine unbenutzte Zelle deiner Tabelle außerhalb deiner Daten, folgende Formel.

=ANZAHL2($A$6:$A$3000)TEILERGEBNIS(3;$A$6:$A$3000)

Die 3000 kannst du an die maximal zu erwartende Datenmenge anpassen und die Zelle ausblenden, oder den Zellwert per Format unsichtbar machen.
In das Modul der Tabelle dann folgender Code.

' **********************************************************************
' Modul: Tabelle1  Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Worksheet_Calculate()
Dim rngC As Range, rngHide As Range

On Error GoTo ErrExit

Static CalculationMode As Long

With Application
  .ScreenUpdating = False
  .EnableEvents = False
  CalculationMode = .Calculation
  .Calculation = xlManual
  .DisplayAlerts = False
End With

If Range("A1") Then 'Zelladresse mit der Formel - Anpassen!
  For Each rngC In Me.AutoFilter.Range.Columns
    rngC.EntireColumn.Hidden = Application.Subtotal(3, rngC) = 1
  Next
Else
  Me.Columns.Hidden = False
End If

ErrExit:

With Err
  If .Number <> 0 Then
    MsgBox "Fehler in Prozedur:" & vbTab & "'Worksheet_Calculate'" & vbLf & String(60, "_") & _
      vbLf & vbLf & IIf(Erl, "Fehler in Zeile:" & vbTab & Erl & vbLf & vbLf, "") & _
      "Fehlernummer:" & vbTab & .Number & vbLf & vbLf & "Beschreibung:" & vbTab & _
      .Description & vbLf, vbExclamation + vbMsgBoxSetForeground, _
      "VBA - Fehler in Prozedur - Worksheet_Calculate"
    .Clear
  End If
End With

On Error GoTo 0

With Application
  .ScreenUpdating = True
  .EnableEvents = True
  .Calculation = CalculationMode
  .DisplayAlerts = True
  .StatusBar = False
End With

End Sub

Gruß Sepp

Beliebteste Forumthreads (12 Monate)

Leere Spalten ausblenden nach Nutzung Autofillter

12
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

312 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Leere Spalten ausblenden nach Nutzung Autofillter

12 Beiträge zum Forumthread Beiträge zu diesem Forumthread

312 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

12
Beiträge zum Forumthread

Beiträge zu diesem Forumthread