Ermittlung der Region mit größtem Wert

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Hary,
ja, ich denke, so sollte es sein! Danke!
Nicht nur Christians Lösung (mit 1) sondern auch Deine Lösung (mit X; alternativ funktioniert auch x) scheint nach ersten Testläufen von heute Morgen zu funktionieren.
Welche Lösung letztlich verwendet werden wird, weiß ich noch nicht.
Das hängt u. a. davon ab, was außerdem noch abgefragt werden muss!
Auf so eine "einfache" Lösung, die abhängig u. a. von INDEX-, LARGE-, IF-, MAX- und COLUMN-Verwendung "einfach" ist, wäre ich wohl nicht gekommen, weil ich davon außer IF und MAX wohl noch nichts verwendet habe! Bei mir wäre das vermutlich eine lange WENN-Formel geworden.
So ganz verstanden habe ich Deine Formel...
{=INDEX(E4:I4;1;LARGE(IF(E25:I25)=MAX(E25:I25);COLUMN(A1:E1));1))}
... aber noch nicht.
Vor allem verstehe ich nicht, warum dort COLUMN(A1:E1) steht, denn in A1 bis E1 (aus schmaler Zeile) steht nichts!
Dein IF steht wohl für WENN?
Von mir erwünschtes X kommt in der Formel nicht vor; dennoch funktioniert die Rechnung mit X-Eingabe! Warum ist das so?
Kannst Du mir die Formel bitte genau (also von AZ) und Formelteil für Formelteil erklären auch wofür die darin stehenden Begriffe INDEX, LARGE und COLUMN stehen! (die Bedeutungen von IF und MAX sind mir klar)
Gruß
Mike

Moin Mike
Bin nicht so der Erklaerbaer, aber versuchen wirs mal unter zur Hilfenahme der F9 Taste
=INDEX(E4:I4;1;KGRÖSSTE(WENN(E25:I25=MAX(E25:I25);SPALTE(A1:E1)); 1))
Syntax fuer Index: Index(Bereich;Zeilenummer;Spaltennummer)
INDEX(E4:I4 ist der Bereich aus dem ein Wert zurueckgeben werden soll also
INDEX{"I"."II"."III"."IV"."V"}
Da der Bereich nur aus einer Zeile besteht kommt die Zeilennummer 1
INDEX{"I"."II"."III"."IV"."V"};1
Jetzt wird die hoechste Spaltennummer mit dem Maxwert in Bereich E25:I25 ermittelt durch:
WENN und Max.
WENN({0.4.8.8.2}=MAX({0.4.8.8.2}
Ergibt:
WENN({FALSCH.FALSCH.WAHR.WAHR.FALSCH}
So trifft 3. und 4. Stelle zu. Da mit WAHR nix anzufangen ist brauche ich eine Zahl. Die vergebe ich durch: SPALTE()
In A1:E1 steht nix drin, aber es geht nur um die Spaltennummer. Diese vergebe durch Spalte(A1:E1).
Ergibt:
{1.2.3.4.5}
Dann hab ich:
WENN({FALSCH.FALSCH.WAHR.WAHR.FALSCH};{1.2.3.4.5})
Ergibt:
KGRÖSSTE({FALSCH.FALSCH.3.4.FALSCH}; 1)
Die 1 heisst ich brauche den groessten Wert also 4. Ergibt:
INDEX({"I"."II"."III"."IV"."V"};1;4)
Aus dem Index erste Zeile/ 4. Spalte ist "IV"
Und "IV" ist der Rueckgabewert.
Du kannst einzelne Formelteile markieren du dann die F9-Taste druecken. Da siehst du womit die Formel arbeitet. Rueckgaengig immer mit der ESC-Taste.
Hoffentlich einigermassen verstaendlich.
gruss hary

Beliebteste Forumthreads (12 Monate)

Ermittlung der Region mit größtem Wert

17 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

17
Beiträge zum Forumthread

Beiträge zu diesem Forumthread