Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1484to1488
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Projektnr aus Projekt auslesen

Projektnr aus Projekt auslesen
08.04.2016 08:28:43
Alesandro
Liebe Forumsgemeinde,
ich komme bei der Ermittlung der Projektnr aus meinen Projekten nicht weiter.
Ich habe in der Spalte B meine Projekte (Daten kommen von extern).
Aus diesen möchte ich in der Spalte A die Projektnr ermitteln.
Die Projektnr darf nur dann geschrieben werden wenn sich am Ende der Zeichenkette
zwischen zwei Klammern eine Zeichenlänge von 5 Zeichen befindet.
Mit der Formel die ich verwende funktioniert das leider nur zum Teil (grün markiert)
Wäre toll wenn mir jemand weiterhelfen könnte.
Es darf jedoch kein VBA-Lösung sein.
https://www.herber.de/bbs/user/104839.xlsx
Danke,
lg Alesandro

17
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Projektnr aus Projekt auslesen
08.04.2016 08:40:11
UweD
Hallo
=WENN(SUCHEN(")";$B2)-SUCHEN("(";$B2)-1=5;TEIL($B2;SUCHEN("(";$B2)+1;5);"")

Gruß UweD

AW: Projektnr aus Projekt auslesen
08.04.2016 08:53:14
Steve
Hallo Uwe,
da erwischt du aber B10 nicht mit, weil da zwei Klammern vorkommen. Ist auch gerade mein Knackpunkt.
lg Steve

AW: Projektnr aus Projekt auslesen
08.04.2016 08:59:40
Steve
Jetzt aber,
vorausgesetzt die Projektnummer steht immer in der letzten Klammer:
B2: =WENNFEHLER(WENN(VERWEIS(9^9;FINDEN(")";B4;SPALTE($1:$1)))-VERWEIS(9^9;FINDEN("(";B4;SPALTE($1:$1)))=6;TEIL(B4;VERWEIS(9^9;FINDEN("(";B4;SPALTE($1:$1)))+1;5);"");"")
lg Steve

AW: mit AGGREGAT() ...
08.04.2016 09:12:23
...
Hallo Alesandro,
... so:
=WENNFEHLER(TEIL(B2;AGGREGAT(15;6;SPALTE($1:$1)/(TEIL(B2;SPALTE($1:$1);1)="(")/(TEIL(B2;SPALTE(G1:AZ$1);1)=")");1)+1;5);"")
Gruß Werner
.. , - ...

Anzeige
OT: @Werner und Steve
08.04.2016 09:23:37
UweD
Hi
erklärt mir doch mal bitte die Verwendung von Spalte($1:$1)
Ergibt die immer 1. Oder?
LG UweD

AW: dazu ...
08.04.2016 09:27:18
...
Hallo Uwe,
... SPALTE(1:1) ergibt eine Wertematrix der Spaltenzahlen von SPALTE(A1) bis SPALTE(XFD) also {1.2.3.... 16384}
Gruß Werner
.. , - ...

AW: Ok. Danke owT
08.04.2016 09:45:13
UweD

AW: OT: @Werner und Steve
08.04.2016 09:29:23
Alesandro
Hier wird einem richtig geholfen.
Danke für Eure Bemühungen.
Ich habe die Formel von UweD genommen und nur noch #WERT! abgefangen und jetzt macht es genau das was es soll.
=WENN(ISTFEHLER(WENN(SUCHEN(")";$B2)-SUCHEN("(";$B2)-1=5;TEIL($B2;SUCHEN("(";$B2)+1;5);""));""; WENN(SUCHEN(")";$B2)-SUCHEN("(";$B2)-1=5;TEIL($B2;SUCHEN("(";$B2)+1;5);""))
Vielen Dank nochmals.
lg Alesandro

Anzeige
AW:damit hast Du aber keine Pro.-Nr Nr in A10 owT
08.04.2016 09:35:38
...
Gruß Werner
.. , - ...

AW: AW:damit hast Du aber keine Pro.-Nr Nr in A10 owT
08.04.2016 09:46:46
Alesandro
Uups, da hast du Recht.
Könnte man das in der Formel von UweD noch abfangen?
Die anderen sind mir etwas zu kompliziert (schäm)
lg Alesandro

AW: AW:damit hast Du aber keine Pro.-Nr Nr in A10 owT
08.04.2016 09:54:25
Alesandro
So, ich verwende jetzt die Formel von Werner und wie es scheint funzt das auch bei grossen Datenmengen.
Zumindest habe ich über einen Vergleich von 300 DS keinen Fehler gesehen.
Danke nochmals an Alle!!!
lg Alesandro

AW: na, dann ist es ja jetzt ok owT
08.04.2016 11:04:00
...
Gruß Werner
.. , - ...

mit SUCHEN und Joker
08.04.2016 12:18:09
Josef
Hallo
Oder so:
=WENNFEHLER(TEIL(B2;SUCHEN("(?)";B2)+1;5);"")
die Lösung von Werner und mir versagen, z. B. bei "ALLIANCE HC Stuttgart (CSdrt) (D056M)"
Da wird "CSdrt" angezeigt.
Gruss Sepp

Anzeige
AW: logisch und schön kurz :-) ... doch ...
08.04.2016 13:07:09
...
Hallo Sepp,
... ist Dein Vorschlag wie so oft.
Der Spezialfall den Du aufgezeigt hast, dürfte wohl wohl kaum relevant sein. Doch ich kann meine Formel einfach nach Schema F erweitern, um auch dann die richtige Nr auszugeben:
In A2 dann so:
=WENNFEHLER(TEIL(B2;AGGREGAT(15;6;SPALTE($1:$1)/(TEIL(B2;SPALTE($1:$1);1)="(")/
(TEIL(B2;SPALTE(G$1:AZ$1);1)=")")/ISTZAHL(--TEIL(B2;SPALTE(C$1:AZ$1);1));1)+1;5);"")
Gruß Werner
.. , - ...

Da du VBA ausgeschlossen hast, kommt ja ...
08.04.2016 13:53:56
Luc:-?
…auch keine UDF infrage, Alessandro,
ansonsten wäre es recht einfach:
 ABC
1PROJEKTNRPROJEKT 
2A015CHERBA Innsbruck (A015C) 
3 DIREKTKOSTEN fuer Kostenstellen (0500) 
4C003MVOIGT AG Romanshorn (C003M) 
5G006GUNICHEM Croydon (G006G) 
6 Alliance Healthcare (Distribution) Ltd. 
7U088BWINDMILL Clear Lake (U088B)  
8 MULTIPHARMA Brüssel (CS)  
9 La Farmaceutica S.p.A. (CS) 
10D056MALLIANCE HC Stuttgart (CS) (D056M) 
11 Releasepflege WJ 15/16 
12 Customer Service () 
13   
14A2[:A12]:=WENN(LÄNGE(MaskOn(RECHTS([@PROJEKT];8);"mrk()"))=7;MaskOn(MaskOn(RECHTS([@PROJEKT];8);"mrk()");"anu");"")
MaskOn (von 2005, beschädigt) ist im Archiv (Neueinstellung 2014, OK) zu finden.
Gruß, Luc :-?
Besser informiert mit …

Anzeige
Übrigens, mit der U088B-Zeile stimmt was ...
08.04.2016 15:35:14
Luc:-?
…nicht, Alessandro,
bei RECHTS([@PROJEKT];7) würde die führende ( fehlen, weil am Ende der Zeile noch ein Tabulator­Zeichen steht.
Luc :-?

AW: Projektnr aus Projekt auslesen
08.04.2016 14:16:03
Daniel
Hi
wenn die Projektnummer immer am Ende steht, dann so:
=WENN(ZÄHLENWENN(B2;"*(?)");TEIL(B2;LÄNGE(B2)-5;5);"")
funktioniert auch, wenn vor der Projektnummern ein Klammernpaar steht (sogar wenn dieses auch 5 Zeichen umschließt.
Einschränkung: die Texte in Spalte B dürfen nicht länger als 256 Zeichen sein.
Gruß Daniel

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige