VBA andere Datei öffnen, durchsuchen und schließen

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Hauke,
ich gehe mal von den folgenden zusätzlichen Bedingungen aus:
1. Die beiden gesuchten Begriffe müssen im gleichen Tabellenblatt vorkommen. Anderenfalls ist das Suchergebnis negativ.
2. Bei der anzuzeigenden Farbe handelt es sich um die Schriftfarbe.
3. Die beiden gesuchten Begriffe werden über deine UserForm eingegeben. Ich nehme sie fest ins Programm.
Unter diesen dreiBedingungen kannst du das mit dem folgenden Programm machen:

Sub Begriffe_suchen()
Dim Begriff(1 To 2) As String
Dim begriffVorhanden(1 To 2) As Boolean
Dim datSuch As String   ' Name der Datei in der gesucht wird
Dim ergebnisZelle(1 To 2) As Range
Dim farbe(1 To 2) As Long
Dim i As Long
Dim pfad As String
Dim suchErgebnis As Object
Dim wbSuch As Workbook
Dim ws As Worksheet
datSuch = "Datei in der gesucht wird.xlsx"
Begriff(1) = "xyz"
Begriff(2) = "uvw"
' Arbeitsmappe öffnen
pfad = ThisWorkbook.Path & "\"
On Error Resume Next
Workbooks(datSuch).Close SaveChanges:=False
On Error GoTo 0
If Dir(pfad & datSuch) = "" Then
MsgBox pfad & datSuch & " existiert nicht"
Exit Sub
End If
Set wbSuch = Workbooks.Open(Filename:=pfad & datSuch)
For Each ws In wbSuch.Worksheets
For i = 1 To 2
begriffVorhanden(i) = False
Set suchErgebnis = ws.Cells.Find(What:=Begriff(i))
If Not suchErgebnis Is Nothing Then
begriffVorhanden(i) = True
Set ergebnisZelle(i) = suchErgebnis
farbe(i) = ergebnisZelle(i).Font.Color
End If
Next i
If begriffVorhanden(1) And begriffVorhanden(2) Then
Exit For
End If
Next ws
If begriffVorhanden(1) And begriffVorhanden(2) Then
MsgBox "Begriffe gefunden in Blatt " & ws.Name & vbNewLine & _
Begriff(1) & " in " & ergebnisZelle(1).Address(False, False) & _
" Farbe: " & farbe(1) & vbNewLine & _
Begriff(2) & " in " & ergebnisZelle(2).Address(False, False) & _
" Farbe: " & farbe(2)
Else
MsgBox "Es existiert kein Blatt, in dem beide Begriffe vorhanden sind"
End If
wbSuch.Close
End Sub

Viele Grüße
Dieter

Hallo Dieter,
vielen Dank schonmal für deine ausführliche Antwort.
Ich hatte leider einen Denkfehler in der Suchvorgabe und komme nochmal rein:
- Ich habe die Datei "Suchen". In dieser Datei sind 2 Zellen mit den Suchvorgaben. Diese muss der User selbst eintragen, zum einen ein Datum (in A1) und zum anderen eine Zahl (in A3).
- Es gibt für jeden Monat eine eigene Datei die durchsucht werden soll. (Okay das entsprechende Makro kann ich ja mit Case ausführen. Gibt man also ein Datum im Oktober ein, soll die Datei 10-2016 durchsucht werden.)
- In der Liste 10-2016 stehen in der Spalte A immer das Datum und in Spalte C immer die Zahl. Das ist in jeder Monatsdatei gleich.
- Es muss geprüft werden ob die Vorgabe 1 in der Spalte A und die Vorgabe 2 in der Spalte C in der gleichen Zeile stehen. Alle Zeilen sind entweder grün, rot, blau oder haben keine Farbe. Wenn Vorgabe 1 in der Spalte A und die Vorgabe 2 in der Spalte C in der gleichen Zeile stehen, dann soll die Hintergrundfarbe der Zeile (es reicht ja eine Zelle, z.B. der A Spalte) und das Ergebnis in einer msgbox dargestellt werden a la "Ergebnis ist GRÜN/ROT/BLAU/BLANKO".
- Sind die Vorgabe 1 in der Spalte A und die Vorgabe 2 in der Spalte C auf KEINEM der Arbeitsblätter in 10-2016, dann soll die Rückmeldung lauten: "Ergebnis nicht auf Liste".
Schön wäre es, wenn die Datei 10-2016 und die Prüfung im Hintergrund erfolgen und die Msgbox einfach in der Datei "Suchen" aufplobbt.
Ist das so evtl auch machbar? :)
LG,
Hauke

Beliebteste Forumthreads (12 Monate)

VBA andere Datei öffnen, durchsuchen und schließen

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

97 Forumthreads zu ähnlichen Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

VBA andere Datei öffnen, durchsuchen und schließen

6 Beiträge zum Forumthread Beiträge zu diesem Forumthread

97 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread