Hallo Zusammen,
gibt es eine Möglichkeit die Matrix innerhalb eines SVERWEIS dynamisch zu ersellen?
SVERWEIS(Suchkriterium;Matrix;Spaltenindex;Bereich_Verweis)
Ich rechne aus einer Liste ,bei der die Matrix sich monatlich um 50 Zeilen verschiebt.
Vorab vielen Dank
Hier ist ein Beispiel
=SVERWEIS($15;'Tabelle1'!$A$5:$AL$50;10;FALSCH)
Der Matrixbereich (hier im Beispiel 5 und 50 ) verändert sich monatlich, deswegen möchte ich den Matrixbereich dynamisch halten
Nächsten Monat muss die Funktion so aussehen:
=SVERWEIS($15;'Tabelle1'!$A$51:$AL$100;10;FALSCH)
Usw.
Am liebsten hätte ich, wenn ich über eine separate Tabelle diesen Bereich festlegen kann. Daraufhin soll sich die Funktion anhand meine Eingaben anpassen.
z.B
Monat -- Matrixbereich von -- Matrixbereich bis
Januar -- 5 -- 50
Februar -- 51 -- 100
Anzeige
AW: Dynamische Matrix im sverweis erstellen
02.03.2017 13:40:09
ChrisL
Hi Sven
z.B. mit Indirekt()
=SVERWEIS($15; INDIREKT("'Tabelle1'!$A$5:$AL$" & Tabelle2!A1) ;10;FALSCH)
Nachteil: Indirekt ist eine volatile Formel http://www.online-excel.de/excel/singsel.php?f=171
Vermutlich könnte man es noch besser lösen, wenn man eine konkrete Beispieldatei hätte. Ist der Monat gekennzeichnet? Sind es je Monat immer gleich viele Zeilen die hinzukommen?
cu
Chris
Index & Vergleich
02.03.2017 15:39:49
Michael
Hi,
das Indirekt läßt sich durch Index/Vergleich ersetzen.
Anbei Testdatei mit zwei Formelvarianten: https://www.herber.de/bbs/user/111900.xlsx
Die "eigentliche" Formel in Formel!C10 lautet:
=INDEX(Tabelle1!J:J;J10-1+VERGLEICH($B$13;INDEX(Tabelle1!A:A;J10):INDEX(Tabelle1!A:A;K10);0))
wobei J10 und K10 die Zellen aus Deinem skizzierten "Matrix-Bereich" sind.
Letzteren habe ich mit einem extra Index ausgestattet, weil sich die Formeln dann übersichtlicher schreiben lassen.
SVerweis durchsucht ja nur eine Spalte (A:A) und gibt in Deiner Formel das Ergebnis aus Spalte 10, nämlich J:J zurück: mit Index braucht man auch nur diese beiden Spalten in der Formel anzugeben.
Schöne Grüße,
Michael
Anzeige
AW: Index & Vergleich
02.03.2017 18:27:34
ChrisL
Hi Michael
Danke. An Index habe ich zwar gedacht, allerdings beschränkte sich mein Horizont auf eine Zelle. Dass man damit einen Bereich bilden kann, war mir nicht bekannt.
INDEX(Tabelle1!A:A;J10):INDEX(Tabelle1!A:A;K10)
In dem Fall ginge auch...
=SVERWEIS(C6;INDEX(Tabelle1!A:A;J10):INDEX(Tabelle1!J:J;K10);10;0)
cu
Chris
@chrisL
03.03.2017 11:00:13
Michael
Hi Chris,
das hatte ich irgendwo bei excelformeln aufgeschnappt...
"In dem Fall" schreibt sich der SVerweis sicher griffiger - danke auch.
Na denn, gute Zeit & Gruß,
Michael