Probleme mit selection, with und end with

Sub Makro2() Dim i As Integer For i = 1 To 5000 If Cells(i, 45) = "z" Then 'Spalte Cells(i, 17).Interior Destination:=Cells(i, 17) With Selection.Interior .Pattern = xlSolid .PatternColorIndex = xlAutomatic .ThemeColor = xlThemeColorAccent1 .TintAndShade = 0.599993896298105 .PatternTintAndShade = 0 End With End If Next i End Sub

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Ben!
Hier mal zwei Varianten, die Dir hoffentlich beim Verständnis der With-Konstruktion helfen (bezogen auf Deine Aufgabenstellung):

Sub a()
Dim Mappe As Workbook: Set Mappe = ThisWorkbook
Dim TabBlatt As Worksheet: Set TabBlatt = Mappe.ActiveSheet
Dim i As Long
For i = 1 To 5000
With TabBlatt
If .Cells(i, 45) = "z" Then
With .Cells(i, 17).Interior
.Pattern = xlSolid
.PatternColorIndex = xlAutomatic
.ThemeColor = xlThemeColorAccent1
.TintAndShade = 0.599993896298105
.PatternTintAndShade = 0
End With
End If
End With
Next i
Set Mappe = Nothing: Set TabBlatt = Nothing
End Sub

Sub b()
Dim Mappe As Workbook: Set Mappe = ThisWorkbook
Dim TabBlatt As Worksheet: Set TabBlatt = Mappe.ActiveSheet
Dim Spalte As Range, Zelle As Range
With TabBlatt
Set Spalte = .Range(.Cells(1, 17), .Cells(.Rows.Count, 17).End(xlUp))
For Each Zelle In Spalte
If Zelle.Offset(, 28) = "z" Then
With Zelle.Interior
.Pattern = xlSolid
.PatternColorIndex = xlAutomatic
.ThemeColor = xlThemeColorAccent1
.TintAndShade = 0.599993896298105
.PatternTintAndShade = 0
End With
End If
Next Zelle
End With
Set Mappe = Nothing: Set TabBlatt = Nothing
Set Spalte = Nothing: Set Zelle = Nothing
End Sub

LG
Michael

Hallo Ben!
...oder ist diese Dimensionierung Pflicht?
Die Deklaration von Variablen in VBA ist zumindest Best Practice, eigentlich schon Pflicht. Siehe dazu auch den sehr guten Artikel http://www.online-excel.de/excel/singsel_vba.php?f=4
Wie Du die Variablen benennst, ist aber egal. Statt "Mappe" hätte ich das Workbook-Objekt auch "Wb" nennen können, aber ich habe mich für Ersteres entschieden, damit Du Dir ggf. im Code leichter tust.
wieso erhält "i" die Dimensionierung as Long und nicht integer
Weil der Long-Datentyp einen größeren Zahlenbereich umfasst, und dies bei der mittlerweile vorhandenen Zeilen-/Zellen-Anzahl in Excel erforderlich ist (Integer ist uU "zu klein"). Du kannst mittlerweile (auch hinsichtlich Performance etc.) immer auf einen Long setzen, wenn Du einen Integer benötigst.
was bedeutet set nothing?
Ist eigentlich nicht unbedingt notwendig, aber da zunächst Objekte (Workbook, Worksheet...) deklariert wurden, werden diese Objekte am Ende des Codes ordnungsgemäß zurückgesetzt. Ist eher historisch, quasi sauberes Programmieren, aber nicht unbedingt erforderlich.
LG
Michael

Beliebteste Forumthreads (12 Monate)

Probleme mit selection, with und end with

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread