Doppelte und fehlende Zahlen finden

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Chris,
... solange es keine Massendatenauswertung werden soll.
Die Formeln in F2 und I2 sind allerdings keine 0815-Formeln.
Deine Beispielvorgaben hab ich bewusst etwas abgeändert, damit die Ergebnisausgabe einfacher prüfbar sind.
Die drei Formeln alle nach unten kopieren und und F und I zusätzlich nach rechts.
Wichtig: In Spalte E (kann aber ausgeblendet werden) dürfen keine Zahlenwerte stehen:

	A	B	C	D	E	F	G	H	I	J	K	L
1	#	Nr		#		Duplikat(e)			fehlende
2	2	1		2		2	5		3	6	7
3	2	2		3					4	7	8
4	2	2		4		3			2	4	5	7
5	2	2		5					9	10
6	2	4		6
7	2	5		7
8	2	5
9	2	8
10	2	9
11	3	1
12	3	2
13	3	3
14	3	5
15	3	6
16	3	9
17	3	10
18	3	11
19	4	1
20	4	3
21	4	3
22	4	3
23	4	3
24	4	6
25	4	8
26	5	1
27	5	2
28	5	3
29	5	4
30	5	5
31	5	6
32	5	7
33	5	8
34	5	11
35	5	12
36	6	1

Formeln der Tabelle

Zelle	Formel
D2	=WENNFEHLER(AGGREGAT(15;6;A$2:A$90/(ZÄHLENWENN(D$1:D1;A$2:A$90)=0)/(A$2:A$90>0); ZEILE(A1)); "")
F2	=WENNFEHLER(AGGREGAT(15;6;$B$2:$B$99/(ZÄHLENWENNS($A$2:$A$99;$D2;$B$2:$B$99;$B$2:$B$99)>1)/(ZÄHLENWENN($E2:E2;$B$2:$B$99)=0); 1); "")
I2	=WENNFEHLER(AGGREGAT(15;6;ZEILE(A$1:A$99)/(ZÄHLENWENNS($A$2:$A$99;$D2;$B$2:$B$99;ZEILE(A$1:A$99))=0)/(ZEILE(A$1:A$99)<AGGREGAT(14;6;$B$2:$B$99/($A$1:$A$99=$D2); 1)); SPALTE(A1)); "")

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...

Hallo Cristina,
... die Nachfrage von WF "Oder müssen pro # immer die Zahlen 1 bis 12 auftauchen ?" in seinem bisher letzten Beitrag von 03.11.2017 22:10:41 ist nachvollziehbar. Ich war bisher davon ausgegangen, dass die letzte gelistete Reihenfolgen-Nr auch die wirklich letzte ist.
Was gilt also? Wenn es immer genau 12 zu jeder # sein sollen, dann wird die Auswertungsformel einfacher.
Im Weiteren müsstest Du dann aber auch noch klären, ob außer "Dopplungen" und "Fehlenden" auch noch eine falsche Reihenfolge möglich sein kann und diese zusätzlich ermittelt werden soll. Also wenn z.B. in B2:B7 folgende Reihenfolge gelistet ist: 1, 2, 3, 2, 5, 7, 6, 8, 9.
In so einem Fall würde der momentan letzte Formelvorschlag von WF die 2 nicht als Duplikat erkennen, mein bisheriger Formelvorschlag schon. In diesem hatte ich auch bewusst Zahlen die mehrfach je # vorkommen, nur einmal als Duplikat gelistet. Wenn diese Mehrfachduplikate jedoch in der Ergebnisliste auch mehrfach gelistet werden sollen/können, dann wird meine diesbzgl. Formel natürlich auch einfacher.
Wenn zusätzlich eine falsche Reihenfolgen (wie im obigen Beispiel die 7 vor der 6) auszuweisen wäre, bedarf es von Dir auch noch genauere Angaben, wie dies genau geschehen soll.
Wenn jedoch eine falsche Reihenfolge keine Rolle spielt und zu jeder # in Spalte B nie eine kleinere Zahl nach einer größeren stehen kann, dann würde ich anstelle der Matrixformel eine kürzere Formel und diese auch wieder ohne {} einsetzen.
Z..B. so:
=INDEX(A$1:A$99&" - "&B$1:B$99;AGGREGAT(15;6;ZEILE(A$3:A$99)/(A$2:A$99&B$2:B$99=A$3:A$99&B$3:B$99);ZEILE(A1))) Formel(n) nach unten kopieren
Oder noch kürzer, dafür in einer Dezimalzahlausgabe so:
=WENNFEHLER(AGGREGAT(15;6;(A$2:A$25+B$2:B$25%)/(A$2:A$25&B$2:B$25=A$3:A$25&B$3:B$25);ZEILE(A1));"")
Dann sehen wir mal, was und wie Du wirklich genau auswerten willst/musst. Bei entsprechender Rückantwort am Montag, könnte ich wohl frühestens am Montag Abend darauf reagieren.
Gruß Werner
.. , - ...

Beliebteste Forumthreads (12 Monate)

Doppelte und fehlende Zahlen finden

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

14 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Doppelte und fehlende Zahlen finden

10 Beiträge zum Forumthread Beiträge zu diesem Forumthread

14 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread