Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1592to1596
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Doppelte Daten an bestimmten Datum nur einmal zähl

Doppelte Daten an bestimmten Datum nur einmal zähl
21.11.2017 11:00:37
Olaf
Hallo,
ich habe folgende Problemstellung: Ich habe eine ID , die mehrfach vorkommen kann, die ich aber nur einmal zählen möchte, dies bekommt ich mit =SUMME(WENN(HÄUFIGKEIT(C2:C16;C2:C16)>0;1)) gut hin. Nun habe ich aber eine Spalte mit Tagesdatum und ich möchte das Zählen nur an einem bestimmtem Datum einschränken, da komme ich nicht weiter. Hier mal meine Beispieltabelle:
id Sale creation (date)
23980 02.01.17
23983 02.01.17
23983 02.01.17
23987 02.01.17
23988 02.01.17
23989 02.01.17
23990 02.01.17
23993 02.01.17
23997 02.01.17
23998 02.01.17
23999 02.01.17
24002 02.01.17
24003 02.01.17
24003 02.01.17
24004 03.01.17
Bei Häufigkeit kommt nun 13 raus, da aber die ID 24004 am 03.01.17 ist, müsste hier 12 stehen.
Hat einer eine Idee?

6
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Doppelte Daten an bestimmten Datum nur einmal zähl
21.11.2017 11:17:02
ransi
HAllo Olaf,
Teste mal ausgiebig:
Tabelle1

 ABCDEFG
1id(date)  1202.01.2017 
22398002.01.2017     
32398302.01.2017     
42398302.01.2017     
52398702.01.2017     
62398802.01.2017     
72398902.01.2017     
82399002.01.2017     
92399302.01.2017     
102399702.01.2017     
112399802.01.2017     
122399902.01.2017     
132400202.01.2017     
142400302.01.2017     
152400302.01.2017     
162400403.01.2017     
17       

Formeln der Tabelle
ZelleFormel
E1{=SUMME(WENN(B1:B16=F1;VERGLEICH(A1:A16&"-" &B1:B16;A1:A16&"-" &B1:B16;0)=ZEILE(A1:A16))*1)}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
ransi
Anzeige
AW: Doppelte Daten an bestimmten Datum nur einmal zähl
21.11.2017 11:34:34
Olaf
Vielen Dank auch dir
AW: erst dann wird WENN() sinnvoll ...
21.11.2017 11:18:15
...
Hallo Olaf,
... denn für die Deine bisherige Ermittlung würde =SUMME(N(HÄUFIGKEIT(C2:C19;C2:C19)>0)) reichen.
Dein eigentliches Anliegen ist mE noch nicht eindeutig.
Wenn Du die Duplikatfreie Anzahl für ein bestimmtes Datum (hier z.B. den 02.01.17) ermitteln willst, dann folgende klassische Matrixformel:
{=SUMME(N(HÄUFIGKEIT(WENN(D2:D99=D2;C2:C99);C2:C99)>0))}
Die {} nicht eingeben sondern Formeln mit StrG+Shift+Enter abschließen.
Gruß Werner
.. , - ...
AW: erst dann wird WENN() sinnvoll ...
21.11.2017 11:32:25
Olaf
Vielen Dank Werner, deine Lösung funktioniert super.
Anzeige
AW: Doppelte Daten an bestimmten Datum nur einmal zähl
22.11.2017 10:17:26
Olaf
Nachdem die Formeln von RANSI UND NEOPA C funktionieren, benötige ich noch eine Erweiterung. Und zwar habe ich noch 2 weitere Einschränkungen, nämlich Channel 1 und Channel 2, also "Inbound" oder "Outbound" und "Call oder "Ticket". Eine weitere Wenn Abfrage vor die Formel von Neopra C funktioniert bei mir nicht, wahrscheinlich ein Denkfehler meinerseits. Leider kann ich die Exceldatei nicht hochladen.
id Channel 1 Channel 2 Sale creation (date)
23980 Inbound Call 02.01.17
23980 Inbound Call 02.01.17
23999 Inbound Call 02.01.17
24002 Inbound Call 02.01.17
24003 Outbound Call 02.01.17
24003 Outbound Call 02.01.17
24004 Inbound Ticket 03.01.17
24004 Inbound Ticket 03.01.17
Channel 1 Channel 2 Datum Anzahl
Inbound Call 02.01.17 3
Outbound Call 02.01.17 1
Inbound Ticket 03.01.17 1
Anzeige
AW: dann wird die Formellösung komplexer ...
22.11.2017 14:38:38
...
Hallo Olaf,
... die Grundlage dazu hab ich mir erst gestern in einem anderen thread (hier: https://www.herber.de/forum/archiv/1592to1596/t1592704.htm) erarbeitet.
Formel F2 nach rechts bis H2 und dann diese Formeln und Formel I2 nach unten kopieren.
 ABCDEFGHI
1idChannel 1Channel 2Date Channel 1Channel 2DateAnzahl
223980InboundCall02.01.2017 InboundCall02.01.20173
323980InboundCall02.01.2017 OutboundCall02.01.20171
423999InboundCall02.01.2017 InboundTicket03.01.20171
524002InboundCall02.01.2017     
624003OutboundCall02.01.2017     
724003OutboundCall02.01.2017     
824004InboundTicket03.01.2017     
924004InboundTicket03.01.2017     
10         

Formeln der Tabelle
ZelleFormel
F2=WENNFEHLER(INDEX(B:B;AGGREGAT(15;6;ZEILE(A$2:A$99)/ISTFEHLER(VERGLEICH($B$2:$B$99&$C$2:$C$99&$D$2:$D$99;$F$1:$F1&$G$1:$G1&$H$1:$H1;0))/($A$2:$A$99<>""); 1)); "")
I2=WENN(F2="";"";SUMME(INDEX((VERGLEICH((B$1:B$99=F2)*(C$1:C$99=G2)*(D$1:D$99=H2)&A$1:A$99;(B$1:B$99=F2)*(C$1:C$99=G2)*(D$1:D$99=H2)&A$1:A$99;0)=ZEILE(A$1:A$99))*(B$1:B$99=F2)*(C$1:C$99=G2)*(D$1:D$99=H2); )))


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...
Anzeige

319 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige