Datum suchen und Text vergleichen

Hallo zusammen
Ich habe eine grössere Herausforderung bei der ich nicht weiter komme, oder besser gesag nicht weiss wie ich beginnen soll. Ich hoffe das ich dass Problem verständlich schildern kann.
Ich habe in einem Workbook zwei Sheets, auf dem 1. Sheet habe ich eine Liste mit Datum und einer 8stelligen Nummer, diese wird fortlaufend ergänzt mit Datum und Nummer.
Auf dem zweiten Sheet habe ich diese 8stelligen Nummern in einer Spalte und als überschrift in anderen Spalten den Monat.
Jetzt die Herausforderung, ich möchte wenn ich auf dem 1.sheet die 8stellige Nummer eintrage diese auf dem 2.Sheet suchen und dann beim richtigem Monat +1 zählen.
Beim entsprechendem monat soll gezählt werden wieviel mal diese Nummer vorkommt.
Sollte eine VBA lössung sein.
Vielen dank für eure Hilfe.
https://www.herber.de/bbs/user/119030.xlsx
Gruss Philip

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Philip,
hier eine Makro-Lösung
Die werden im "Tabelle2" neu berechnet, wenn das Blatt aktiviert wird.
Das Makro fügt Formeln ein, die nach Neuberechnung durch ihre Werte ersetzt werden.
Gruß
Franz

'Code unter dem Code-Modul von Blatt "Tabelle2"
Private Sub Worksheet_Activate()
'Anzahl Proben aktualisieren
Call ProbenZahl_aktualisieren(Me, Worksheets("Probenahme"))
End Sub
Private Sub Test_ProbenZahl_aktualisieren()
Call ProbenZahl_aktualisieren(Me, Worksheets("Probenahme"))
End Sub
Sub ProbenZahl_aktualisieren(wksMG As Worksheet, wksPN As Worksheet)
Dim ZeilePN1 As Long, ZeilePNL As Long
Dim ZeileMG As Long, ZeileMG1 As Long, ZeileMGL As Long, SpalteMG As Long
Dim strFormel As String
Dim StatusCalc As Long
With wksPN
ZeilePN1 = 4
ZeilePNL = .Cells(.Rows.Count, 1).End(xlUp).Row
End With
With wksMG
ZeileMG1 = 4
ZeileMGL = .Cells(.Rows.Count, 1).End(xlUp).Row
strFormel = "=SUMPRODUCT((RC1='" & wksPN.Name & "'!R" & ZeilePN1 & "C6:R" _
& ZeilePNL & "C6)*(RC1"""")*(TEXT('" & wksPN.Name _
& "'!R" & ZeilePN1 & "C2:R" & ZeilePNL & "C2,""MMMM"")=R2C)*1)"
With Application
StatusCalc = .Calculation
.Calculation = xlCalculationManual
.ScreenUpdating = False
End With
For SpalteMG = 6 To 28 Step 2 'Monat Januar bis Dezember
With .Range(.Cells(ZeileMG1, SpalteMG), .Cells(ZeileMGL, SpalteMG))
.FormulaR1C1 = strFormel
End With
Next
.Calculate
For SpalteMG = 6 To 28 Step 2 'Monat Januar bis Dezember
With .Range(.Cells(ZeileMG1, SpalteMG), .Cells(ZeileMGL, SpalteMG))
.Value = .Value
End With
Next
For ZeileMG = ZeileMG1 To ZeileMGL
If .Cells(ZeileMG, 1) = "" Then
.Rows(ZeileMG).ClearContents
End If
Next
With Application
.Calculation = StatusCalc
.ScreenUpdating = True
End With
End With
End Sub

Beliebteste Forumthreads (12 Monate)

Datum suchen und Text vergleichen

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

307 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Datum suchen und Text vergleichen

6 Beiträge zum Forumthread Beiträge zu diesem Forumthread

307 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread