Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1604to1608
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

bezeichner unter dem cursor nicht erkannt

bezeichner unter dem cursor nicht erkannt
27.01.2018 12:30:26
Lucas
Hallo liebes Experten Forum,
ich versuche mich seit neuestem mit VBA und bin auf ein mir unlösbares Problem gestoßen und hoffe ihr könnt/wollt mir helfen :). Unten habe ich euch den Code hingeschrieben. Er tut bis zu einer gewissen Stelle genau was er soll. Kurzzusammenfassung:
Er nimmt Zelle (C4) und sucht diese in dem Sheet "Raumbuch" wenn er es gefunden hat kopiert er mehrere einzelne Zellen in Sheet "Raum". Nach den ersten Zellen, welche einwandfrei funktionieren muss er aber einen ganzen Bereich im Raumbuch kopieren und in dem Sheet Raum transponiert einfügen. Die Zeile Code habe ich entsprechend fett gemacht.
Ich hoffe ihr könnte mir helfen. Ihr seid meine letzte Hoffung :).
Liebe Grüße
Lucas
Private Sub ComboBox1_Change()
'Zelle (C/4) wird im Raumbuch gesucht
Application.ScreenUpdating = False
Dim Suchergebnis As Range
Dim Range As Integer
Dim SuchWert As String
Dim wksRaum As Worksheet
Dim wksRaumbuch As Worksheet
Set wksRaum = ThisWorkbook.Worksheets("Raum")
Set wksRaumbuch = ThisWorkbook.Worksheets("Raumbuch")
SuchWert = ComboBox1
With Worksheets("Raumbuch").Range("A1:A100")
Set Suchergebnis = .Find(SuchWert)
If Not Suchergebnis Is Nothing Then
'Call Raum_aufrufen_Callfunktion
'Kopfzeile
wksRaumbuch.Cells(Suchergebnis.Row, 1).Copy wksRaum.Cells(4, 3)     'Raumbezeichnung
wksRaumbuch.Cells(Suchergebnis.Row, 2).Copy wksRaum.Cells(5, 3)     'Raumbezeichnung
'Aufbau beginnend mit Wand
'
wksRaumbuch.Range(Cells(Suchergebnis.Row, 16), Cells(Suchergebnis.Row, 135)).Copy
wksRaum.Cells(11, 3).PasteSpecial Transpose:=True
Else
MsgBox "Die angebene Raumnummer ist in der Datenbank nicht vorhanden."
End If
Raumnummer.Hide
End With
End Sub

4
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: bezeichner unter dem cursor nicht erkannt
27.01.2018 15:39:16
Luschi
Hallo Lucas,
gerade Vba-Beginner machen immer wieder die selben Fehler.
Sie wollen sich in allgemeinen Beschreibungen erklären lassen warum
ihr Vba-Code nicht funktioniert.
Mache eine kleine Demodatei und ich werde aktiv.
Dim Range As Integer
With Worksheets("Raumbuch").Range("A1:A100")
Diese beiden Befehle sollten Dich schon nervös machen. Range ist eine Objekteigenschaft von
Worksheets, Du aber definierst eine Variable mit dem Namen 'Range' und machst 'ne Zahl (Integer)
draus.
Gruß von Luschi
aus klein-Paris
AW: bezeichner unter dem cursor nicht erkannt
27.01.2018 21:25:44
Werner
Hallo Lucas,
und neben dem von Luschi bereits angesprochenem haben wir in deiner fett markierten Codezeile auch noch einen Referenzierungsfehler.
With wksRaumbuch
.Range(.Cells(Suchergebnis.Row, 16), .Cells(Suchergebnis.Row, 135)).Copy
wksRaum.Cells(11, 3).PasteSpecial Transpose:=True
Application.CutCopyMode = False
End With
Und warum stellst du den gleichen Beitrag in verschiedenen Foren ein, ohne in den entsprechenden Beiträgen auf das andere Forum zu verweisen. Dass dann verschiedene Helfer doppelte Arbeit investieren, da sie nichts voneinander wissen, scheint dir egal zu sein.
Gruß Werner
Anzeige
AW: bezeichner unter dem cursor nicht erkannt
28.01.2018 03:17:50
Werner
Hallo Lucas,
hier mal dein Code abgeändert:
Private Sub ComboBox1_Change()
Dim wksRaum As Worksheet, wksRaumbuch As Worksheet
Dim strSuchWert As String, raErgebnis As Range
Set wksRaum = ThisWorkbook.Worksheets("Raum")
Set wksRaumbuch = ThisWorkbook.Worksheets("Raumbuch")
strSuchWert = ComboBox1
Application.ScreenUpdating = False
With wksRaumbuch.Range("A1:A100")
Set raErgebnis = .Find(strSuchWert)
If Not raErgebnis Is Nothing Then
'Call Raum_aufrufen_Callfunktion
'Kopfzeile
raErgebnis.Copy wksRaum.Cells(4, 3)     'Raumbezeichnung
raErgebnis.Offset(0, 1).Copy wksRaum.Cells(5, 3)    'Raumbezeichnung
'Aufbau beginnend mit Wand
raErgebnis.Offset(0, 15).Resize(, 120).Copy
wksRaum.Cells(11, 3).PasteSpecial Transpose:=True
Application.CutCopyMode = False
Else
MsgBox "Die Raumnummer " & strSuchWert & " ist in der Datenbank nicht vorhanden."
End If
Raumnummer.Hide
End With
Set wksRaum = Nothing: Set wksRaumbuch = Nothing: Set raErgebnis = Nothing
Application.ScreenUpdating = True
End Sub
Gruß Werner
Anzeige

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige