AW: Makro öffnen, Verknüpfung entfernen, speichern
18.03.2018 19:41:01
fcs
Hallo Stefan,
versuche dein Glück mal mit dem folgenden Makro.
Gruß
Franz
Sub EntfernenVerknuepfungen_in_xls_speichern()
Dim varOrdner, varZiel
Dim strDatei As String, wkb As Workbook
Dim varLink, varLinks
With Application.FileDialog(msoFileDialogFolderPicker)
.Title = "Bitte Ordner mit den xls-Dateien auswählen"
If .Show = -1 Then
varOrdner = .SelectedItems(1)
Else
Exit Sub
End If
.Title = "Bitte Ziel-Ordner für die xls-Dateien ohne Verknüpfung auswählen/anlegen"
If .Show = -1 Then
varZiel = .SelectedItems(1)
Else
Exit Sub
End If
End With
strDatei = Dir(varOrdner & "\*.xls")
Application.ScreenUpdating = False
Do Until strDatei = ""
Set wkb = Application.Workbooks.Open( _
Filename:=varOrdner & "\" & strDatei, _
UpdateLinks:=True, _
ReadOnly:=True)
Application.DisplayAlerts = False
varLinks = wkb.LinkSources(xlLinkTypeExcelLinks)
If Not IsEmpty(varLinks) Then
For Each varLink In varLinks
wkb.BreakLink Name:=varLink, Type:=xlLinkTypeExcelLinks
Next
End If
wkb.SaveAs Filename:=varZiel & "\" & strDatei, FileFormat:=xlExcel8
wkb.Close savechanges:=True
Application.DisplayAlerts = True
strDatei = Dir
Loop
Application.ScreenUpdating = False
End Sub