Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1620to1624
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Schlüsselwort in Exceldatei suchen
06.05.2018 08:49:29
Manfred
Hallo, wer kann mir einen Gedankenschubser geben.
Ich habe ein Feld, indem ich ein Schlüsselwort eingebe (in Userforms). Nun soll dieses Schlüsselwort in einer anderen riesengroßen Exceldatei gesucht werden. Beim finden (Das Schlüsselwort steht in der Spalte C) soll nun in der Zeile des gesuchten Wortes, die Spalten A und B ausgelesen werden und in zwei Feldern des Userforms geschrieben werden. Das öffnen und schließen der Exceldatei ist kein Problem, aber mit dem suchen und zurückschreiben habe ich Probleme.
Wäre echt dankbar, wenn mir jemand helfen könnte!!!

6
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Schlüsselwort in Exceldatei suchen
06.05.2018 09:13:50
Hajo_Zi
Set Rafound1 = Columns(3).Find("Erledigt", Range("A" & Rows.Count), xlFormulas, _
xlWhole, , xlNext)
Texbox2=Rafound-offset(0,-1)
Texbox3=Rafound-offset(0,-20

Beiträge von Werner, Luc, robert, J.O.Maximo und folgende lese ich nicht.
AW: Schlüsselwort in Exceldatei suchen
06.05.2018 17:43:01
Manfred
Danke für die Antwort, aber es wäre super wenn ich noch ein paar Infos bekommen könnte.
Ich möchte auch gerne den Code verstehen. Könntest Du mir bitte eine Erklärung mitgeben?
Wäre super!!!
AW: Schlüsselwort in Exceldatei suchen
06.05.2018 17:48:39
Sepp
Hallo Manfred,
da fehlen noch ein paar Infos.
  1. Soll immer in der selben Datei gesucht werden, oder soll die Datei per Dialog ausgewählt werden?
  2. In welchem Tabellenblatt der Datei soll gesucht werden?
  3. Wo steht das Schlüsselwort in dem UF? Textbox1?

 ABCDEF
1Gruß Sepp
2
3

Anzeige
AW: Schlüsselwort in Exceldatei suchen
07.05.2018 18:53:45
Manfred
Hallo, vielen Dank für die Nachfrage.
Also es wird immer auf die gleiche Exceldatei zugegriffen.
Das Tabellenblatt1
Das Schlüsselwort ist in einer TextBox und die beiden - noch - leeren Felder sind auch TextBoxen.
Ich möchte in der TextBox das Schlüsselwort eingeben. Dann soll eben die Exceldatei geöffnet werden
das Schlüsselwort gesucht und gefunden werden (befindet sich in Spalte C) Wird das Schlüsselwort gefunden, sollen aus dieser Zeile der Wert der Spalte A in z.B. Texbox2 und der Wert von Spalte B in Textbox3.
Der Code von Hajo ist ja schon mal was wert, aber ich würde eben auch gerne wissen was ich mache.
Daher hätte ich gerne "Gedankenschubser"
Danke schon mal im Vorraus
Anzeige
AW: Schlüsselwort in Exceldatei suchen
07.05.2018 19:05:42
Sepp
Hallo Manfred,
der Code für den Such-Button, in den Kommentaren sind die Stellen an denen du ggf. anpassen musst gekennzeichnet!
Dialog UserForm1
Option Explicit 
 
' Name des CommandButton ggf. ANPASSEN! 
Private Sub CommandButton1_Click() 
  Dim objWB As Object, objRange As Object, bolAlreadyOpen As Boolean 
 
  Const cstrFile  As String = "D:\Forum\1.xls"    'Dateiname      - ANPASSEN! 
  Const cstrTab   As String = "Tabelle1"          'Tabellenname   - ANPASSEN! 
 
  On Error GoTo ErrorHandler 
 
  With Application 
    .ScreenUpdating = False 
    .EnableEvents = False 
    .AskToUpdateLinks = False 
    .DisplayAlerts = False 
    .Calculation = xlCalculationManual 
  End With 
  ' TextBox1 = Textbox mit Suchbegriff - Name ggf. ANPASSEN! 
  If Len(Trim$(TextBox1)) Then 
    ' TextBox2 & TextBox3 = Ausgabetextboxen - Namen ggf. ANPASSEN! 
    TextBox2 = "": TextBox3 = "" 
    For Each objWB In Application.Workbooks 
      If objWB.FullName = cstrFile Then bolAlreadyOpen = True: Exit For 
    Next 
    If objWB Is Nothing Then Set objWB = Workbooks.Open(cstrFile) 
    With objWB 
      Set objRange = .Sheets(cstrTab).Columns(3).Find(What:=TextBox1, LookAt:=xlWhole, _
        LookIn:=xlValues, MatchCase:=False, SearchFormat:=False) 
         
      If Not objRange Is Nothing Then 
        TextBox2 = objRange.Offset(0, -2) 
        TextBox3 = objRange.Offset(0, -1) 
      Else 
        MsgBox "Suchbegriff nicht gefunden!" 
      End If 
      If Not bolAlreadyOpen Then .Close False 
    End With 
  Else 
    MsgBox "Suchbegriff fehlt!" 
  End If 
 
ErrorHandler: 
 
  If Err.Number <> 0 Then 
    MsgBox "Fehler in UserForm1" & vbLf & vbLf & "Prozedur:" & vbTab & "CommandButton1_Click" & vbLf & _
      "Nummer:" & vbTab & Err.Number & vbLf & "Meldung:" & vbTab & Err.Description & vbLf & _
      IIf(Erl, "Zeile:" & vbTab & Erl, ""), vbExclamation, "Fehler!" 
    Err.Clear 
  End If 
 
  With Application 
    .ScreenUpdating = True 
    .EnableEvents = True 
    .AskToUpdateLinks = True 
    .DisplayAlerts = True 
    .Calculation = xlCalculationAutomatic 
  End With 
 
  Set objWB = Nothing 
  Set objRange = Nothing 
End Sub 

VBA/HTML-CodeConverter, AddIn für Office 2002-2016 - in VBA geschrieben von Lukas Mosimann. Projektbetreuung:RMH Software & Media

Code erstellt und getestet in Office 16 - mit VBAHTML 12.6.0

TypNameEigenschaften
CommandButtonCommandButton1
Caption:CommandButton1
Height:24
Left:141
TabIndex:3
Top:42
Width:72
TextBoxTextBox1
Height:18
Left:15
TabIndex:0
Text:
Top:18
Width:72
TextBoxTextBox2
Height:18
Left:12
Text:
Top:54
Width:72
TextBoxTextBox3
Height:18
Left:18
TabIndex:2
Text:
Top:90
Width:72

 ABCDEF
1Gruß Sepp
2
3

Anzeige
AW: Schlüsselwort in Exceldatei suchen
07.05.2018 21:20:23
Manfred
Hallo Sepp, das ist ja unglaublich!!!
Vielen Dank für die Mühe. Werde ich nun in den nächsten Tagen austesten.
SUUUUUPPPERRRRR

304 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige