Suche mit Index verfeinern

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo zusammen,
@Werner
leider klappt das überhaupt nicht.
=WENNFEHLER(INDEX(INDIREKT(A$203&"!D:D");
AGGREGAT(15;6;ZEILE(A$1:A$999)/(INDIREKT(A$203&"!A$1:A$999")="Test");ZEILE(A1)));"")
1. Müsste es nicht Spalte statt Zeile heißen?
2. ZEILE(A$1:A$999) müsste doch ZEILE(A$203&"!A$1:A$999) heißen,oder?
@WF
auch mit dieser Formel hat es nicht geklappt
=WENNFEHLER(INDEX(INDIREKT(A$203&"!D:D");KKLEINSTE(WENN(A$1:A$999="Test";ZEILE(X$1:X$999));ZEILE(X1) ));"")
1. Auch hier, warum Zeile und nicht Spalte?
2. WENN(A$1:A$999="Test" müsste eigentlich WENN(A$203&"!A$1:A$999="Test" sein. Das gibt mir dann aber einen Fehler aus.
Ich nehme mal an, dass die Formeln auch über 999 hinaus funktionieren.
Habt ihr noch eine Idee?
Vielen Dank & Viele Grüße

Hallo Peter,
... dazu sieh auch meine nachfolgende Beispielaufstellung, in der die aufgezeigten Formeln nach unten kopiert sind. In B2 steht meine erste Formel und in C2 die 2. Formel von WF. Meine erweiterte 2. Formel steht in E2.
Wenn in A203 anstelle z.B. "Datenwerte" z.B. "Daten 2017" steht, weil ein Tabellenblatt z.B. so heißt, ergibt wegen dem Sonderzeichen im Blattnamen (hier das Leerzeichen) nur die Formel in Spalte E die korrekten Ergebniswerte und dies sogar ohne den spez. Formelabschluss, den eine klasische Matrixformel wie z.B. die in C2 benötigt. Diese Formel könnte alerdings allerdings auch anaolog erweitert werden, wie die zwischen B2 und E2.
Zu ZEILE(...) hat Dir ja WF bereits geschrieben. SPALTE() würde benötigt werden, wenn Du die Ergebniswerte nicht in einer Spalte sondern in einer Zeile gelistet haben möchtest, weil Du dann die Formeln ja nach rechts kopieren müsstest.
Auswert

	A	B	C	D	E
1	Test	Ergebniswerte
2		Erg_3	Erg_3		Erg_3
3		Erg_5	Erg_5		Erg_5
4		Erg_11	Erg_11		Erg_11
5
6
7
8
9
202
203	Datenwerte
204

Formeln der Tabelle

Zelle	Formel
B2	=WENNFEHLER(INDEX(INDIREKT(A$203&"!D:D"); AGGREGAT(15;6;ZEILE(A$1:A$999)/(INDIREKT(A$203&"!A$1:A$999")=A$1); ZEILE(A1))); "")
C2	{=WENNFEHLER(INDEX(INDIREKT(A$203&"!D:D"); KKLEINSTE(WENN(INDIREKT(A$203&"!A$1:A$999")=A$1; ZEILE(X$1:X$999)); ZEILE(X1))); "")}
E2	=WENNFEHLER(INDEX(INDIREKT("'"&A$203&"'!D:D"); AGGREGAT(15;6;ZEILE(A$1:A$999)/(INDIREKT("'"&A$203&"'!A$1:A$999")=A$1); ZEILE(A1))); "")

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Datenwerte

	A	B	C	D
1	Texte			Ergebniswerte
2	eins			Erg_1
3	zwei			Erg_2
4	Test			Erg_3
5	drei			Erg_4
6	Test			Erg_5
7	vier			Erg_6
8	abc			Erg_7
9	cba			Erg_8
10	def			Erg_9
11	ein Test			Erg_10
12	Test			Erg_11
13	Ende			Erg_12
14

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...

Beliebteste Forumthreads (12 Monate)

9 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

9
Beiträge zum Forumthread

Beiträge zu diesem Forumthread