Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1660to1664
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Hyperlink per mail aus Dokument heraus?

Hyperlink per mail aus Dokument heraus?
09.12.2018 11:43:25
MaBlu
Hallo
Ich habe eine Frage, ich habe gesucht aber nichts gefunden, kann ich wenn ich eine beliebige Exceldatei offen habe, daraus per vba ein mail erstellen mit dem Hyperlink auf die Datei und ein mail senden?
Eventuell sogar von allen geöffneten Excel Dokumenten?
Eine Beispieldatei wäre toll.
Für eure Hilfe im Voraus besten Dank.
Gruss MaBlu

7
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Hyperlink per mail aus Dokument heraus?
09.12.2018 11:58:12
Sepp
Hallo MaBlu,
das geht z. B. so:
Modul Modul1
Option Explicit 
 
'Aktive Arbeitsmappe versenden 
Sub sendAktiveWorkbook() 
  Call Outlook_Mail 
End Sub 
 
'Alle offenen Arbeitsmappen versenden 
Sub sendAllWorkbooks() 
  Call Outlook_Mail(True) 
End Sub 
 
Sub Outlook_Mail(Optional ByVal AllWorkbooks As Boolean = False) 
  Dim objOL As Object, objMail As Object, objWB As Workbook 
 
  Set objOL = CreateObject("Outlook.Application") 
  Set objMail = objOL.CreateItem(0) 
 
  On Error Resume Next 
  With objMail 
    .to = "empfänger@domain.com" 
    .CC = "" 
    .BCC = "" 
    .Subject = "Hier kommt die Mail!" 
    .Body = "Hallo..." 
    If AllWorkbooks Then 
      For Each objWB In Application.Workbooks 
        If Len(Dir(objWB.FullName, vbNormal)) Then _
          .Attachments.Add objWB.FullName 
      Next 
    Else 
      If Len(Dir(ActiveWorkbook.FullName, vbNormal)) Then _
        .Attachments.Add ActiveWorkbook.FullName 
    End If 
    .Display  'or use .Send 
  End With 
  On Error GoTo 0 
 
  Set objMail = Nothing 
  Set objOL = Nothing 
End Sub 
  

VBA/HTML-CodeConverter, AddIn für Office 2002-2016 - in VBA geschrieben von Lukas Mosimann. Projektbetreuung:RMH Software & Media

Code erstellt und getestet in Office 16 - mit VBAHTML 12.6.0


 ABCDEF
1Gruß Sepp
2
3

Anzeige
AW: Hyperlink per mail aus Dokument heraus?
09.12.2018 12:08:07
MaBlu
Hallo Sepp
Danke für diesen Vorschlag, ist schon eine gute Lösung, gibt es auch eine Möglichkeit nur einen Link auf die Datei ins Mail zu bringen ohne die Datei anzuhängen?
Die Dateien sin auf einem server abgelegt, und ich möchte meinen Kollegen nur den Link darauf senden Datenmenge!
Ich hoffe du kannst mir weiterhelfen.
Vieln Dank schon mal für den ersten Vorschlag.
GLG MaBlu
AW: Hyperlink per mail aus Dokument heraus?
09.12.2018 12:33:33
Sepp
Hallo MaBlu,
Modul Modul2
Option Explicit 
 
'Aktive Arbeitsmappe versenden 
Sub sendAktiveWorkbook() 
  Call Outlook_Mail_Link 
End Sub 
 
'Alle offenen Arbeitsmappen versenden 
Sub sendAllWorkbooks() 
  Call Outlook_Mail_Link(True) 
End Sub 
 
Sub Outlook_Mail_Link(Optional ByVal AllWorkbooks As Boolean = False) 
  Dim objOL As Object, objMail As Object, objWB As Workbook 
  Dim strSignature As String, strBody As String 
 
  Set objOL = CreateObject("Outlook.Application") 
  Set objMail = objOL.CreateItem(0) 
 
  On Error Resume Next 
 
  strBody = "Hallo...,<br><br>" & "Anbei die Datei(en).<br><br>" 
   
  If AllWorkbooks Then 
    For Each objWB In Application.Workbooks 
      If Len(Dir(objWB.FullName, vbNormal)) Then _
        strBody = strBody & "<a href=""file://" & objWB.FullName & """>" & _
          objWB.Name & "</a><br>" 
    Next 
  Else 
    If Len(Dir(ActiveWorkbook.FullName, vbNormal)) Then _
      strBody = strBody & "<a href=""file://" & ActiveWorkbook.FullName & """>" & _
        ActiveWorkbook.Name & "</a><br>" 
  End If 
  With objMail 
    .GetInspector 
    strSignature = "<br><br>" & .HTMLBody 
    .To = "empfänger@domain.com" 
    .CC = "" 
    .BCC = "" 
    .Subject = "Hier kommt die Mail!" 
    .HTMLBody = strBody & strSignature 
    .Display  'or use .Send 
  End With 
   
  On Error GoTo 0 
 
  Set objMail = Nothing 
  Set objOL = Nothing 
End Sub 
 
 
 

VBA/HTML-CodeConverter, AddIn für Office 2002-2016 - in VBA geschrieben von Lukas Mosimann. Projektbetreuung:RMH Software & Media

Code erstellt und getestet in Office 16 - mit VBAHTML 12.6.0


 ABCDEF
1Gruß Sepp
2
3

Anzeige
AW: gelöst Hyperlink per mail aus Dokument heraus?
09.12.2018 12:41:47
MaBlu
Hallo Sepp
Ja genau das habe ich gesucht eine Tolle Lösung vielen herzlichen Dank!
Ich bin erstaunt wie schnell einem hier geholfen werden kann. Ich wäre da nie drauf gekommen!
Wünsche einen schönen 2. Advent
Grüsse MaBlu
PS: ich bin Happy
AW: gelöst Hyperlink per mail aus Dokument heraus?
09.12.2018 12:52:40
MaBlu
Hallo obwohl ich das schon vorschnell als gelöst geschrieben habe noch eine Frage:
wenn jetzt zwei Dateien gleich heißen kann es zu Verwirrungen führen gibt es auch die Möglichkeit nicht den Namen der Datei sondern den Pfad im Mail einzutragen? Dann wäre es Perfekt!
Ich denka auch das wisst ihr und nochmals Danke
Gruss MaBLu
Anzeige
AW: gelöst Hyperlink per mail aus Dokument heraus?
09.12.2018 13:48:25
Sepp
Hallo MaBlu,
da könntest du aber auch selber draufkommen!
Statt .Name schreibst du zweimal .FullName
 ABCDEF
1Gruß Sepp
2
3

Anzeige
AW: gelöst Hyperlink per mail aus Dokument heraus?
09.12.2018 14:00:51
MaBlu
Hallo Sepp
Danke jetzt ist es absolut Perfekt, ich habe gegoogelt aber das stand da nie?
Meine Kenntnisse sind also noch recht klein, aber ich werde mich bemühen!
Viele vielen Dank das erspart mir einiges und ich kann dieses Forum nur Empfehlen.
Grüsse Mablu

301 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige