Daten einer geschlossenen Excel-Datei

Hallo zusammen,
zu meinem Problem:
Ich habe einen Ordner mit vielen xlsm.-Dateien. Nun benötige ich aus jeder Excel-Datei ein paar Informationen, die immer in den gleichen Zellen zu finden sind. Diese Informationen sollen in einer weiteren Excel-Datei gesammelt werden. Ziel ist es in der neuen Excel-Datei in Spalte A die Dateinamen der Excel-Dateien aus dem Ordner stehen zu haben. In Spalte B dann der erste extrahierte Wert zu der jeweiligen Excel-Datei, in Spalte C der zweite extrahierte Wert usw.
Ich habe es bisher geschafft mit den Ordnerinhalt als Liste in Excel ausgeben zu lassen über einen Button. Nun schaffe ich es jedoch nicht aus diesen Listeneinträgen variable Pfade zu den einzelnen Excel-Dateien herzustellen, um dann die Zellinformation zu bekommen.
Am Ende würde ich gerne nur diesen Button drücken, der den Ordner nach neuen Dateien untersucht, diese in die Liste übernimmt und sich automatisiert die Werte aus den zugehörigen Excel-Dateien nimmt.
Vielen Dank für eure Hilfe!
Viele Grüße
Dominic

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Dominic,
Modul Modul1

Option Explicit 
 
Sub TestGetValue() 
  Dim strFile As String, strPath As String, strWBook As String, strSheet As String 
  Dim varRange As Variant 
  Dim lngIndex As Long, lngCell As Long, rng As Range 
  Dim lngRow As Long, lngCol As Long 
   
  Const conPath     As String = "D:\Forum\"         'Pfad mit "\" am Ende! 
  Const conSheet    As String = "Request Table"     'Tabellenname 
  Const conRef      As String = "G4,G6,G8,J4,Q18"   'Zelladressen 
 
  varRange = Split(conRef, ",") 
   
  lngRow = 1 
   
  strWBook = Dir(conPath & "*.xls*", vbNormal) 
   
  Do While strWBook <> "" 
    lngRow = lngRow + 1 
    lngCol = 1 
    Cells(lngRow, lngCol) = strWBook 
    For lngIndex = 0 To Ubound(varRange) 
      lngCol = lngCol + 1 
      Cells(lngRow, lngCol) = GetValue(conPath, strWBook, conSheet, varRange(lngIndex)) 
    Next 
    strWBook = Dir 
  Loop 
   
End Sub 
 
Private Function GetValue(ByVal FilePath As String, ByVal FileName As String, ByVal SheetName As String, ByVal TargetAddress As String) As Variant 
  Dim Argument As String 
 
  On Error GoTo ErrorHandler 
 
  If Right(FilePath, 1) <> "\" Then FilePath = FilePath & "\" 
  Argument = "'" & FilePath & "[" & FileName & "]" & SheetName & "'!" & Range(TargetAddress).Range("A1").Address(, , xlR1C1) 
  GetValue = ExecuteExcel4Macro(Argument) 
  Exit Function 
ErrorHandler: 
  GetValue = CVErr(xlErrRef) 
End Function 

VBA/HTML-CodeConverter, AddIn für Office 2002-2016 - in VBA geschrieben von Lukas Mosimann. Projektbetreuung:RMH Software & Media
Code erstellt und getestet in Office 16 - mit VBAHTML 12.6.0

	A	B	C	D	E	F
1	Gruß Sepp
2
3

Sub test() Dim Datei As String Dim Pfad As String Pfad "C:\Ordern...\" Datei = Dir(Pfad & "*.xlsm") Do While Datei "" If WorksheetFunction.CountIf(Columns(1), Datei) = 0 Then With Cells(Rows.Count, 1).End(xlUp).Offset(1, 0) .Offset(0, 0).Value = Datei .Offset(0, 1).Formula = "='" & Pfad & "[" & Datei & "]Tabelle1'!A1" .Offset(0, 2).Formula = "='" & Pfad & "[" & Datei & "]Tabelle1'!B1" .Offset(0, 3).Formula = "='" & Pfad & "[" & Datei & "]Tabelle1'!C1" End With End If Datei = Dir() Loop End Sub

Beliebteste Forumthreads (12 Monate)

Daten einer geschlossenen Excel-Datei

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

52 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Daten einer geschlossenen Excel-Datei

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

52 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread