Live-Forum - Die aktuellen Beiträge
Datum
Titel
29.03.2024 13:14:12
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1688to1692
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Datum als Text

Datum als Text
03.05.2019 09:48:55
Mangoon
Guten Morgen zusammen,
ich benötige eure Hilfe, da mein Latein am Ende ist.
Folgender Sachverhalt:
Ich ziehe Daten aus einer englischsprachigen Datei und importiere sie in Excel. Nun habe ich das Problem das die Monate (Format MMM YY) die in Englisch anders geschrieben werden nicht als Datum erkannt werden. Folglich habe ich nun zb. December 2017 als Text dort stehen. Für die Auswertung benötige ich natürlich ein Datum, das auch als Datum erkannt wird.
Ich habe mir nach tagelangem Lesen selber etwas zusammengestrickt, was aber weiß Gott nicht schick ist aber das spielt hier auch eher eine untergeordnete Rolle.
So sieht die Formel bisher aus:
=WENN(LÄNGE(B347)=5;B347;(1&"."&(WENN(B347="January";"01";WENN(B347="February";"02"; WENN(B347="March";"03";WENN(B347="May";"05";WENN(B347="June";"06";WENN(B347="July";"07"; WENN(B347="October";"10";WENN(B347="December";"12";)))))))))&"."&C347)*1)
Erklärung: Ich prüfe ob in der Spalte B das richtige Datum (z.B. Apr 19) steht, falls ja übernehmen. Die Monate die Excel nicht erkennt (z.B December 2019) teile ich derzeit per Hand mittels "Text in Spalten" in zwei Spalten. Nun ersetzt Excel December in Dezember und ich füge "Dezember" & "2019" & eine Spalte mit "1." zusammen, multipliziere es mit 1, damit Excel jetzt erkennt es ist ein Monat.
Meine Wunschvorstellung wäre, dass Excel erkennt wenn es ein Datum ist und übernimmt bzw wenn es nicht als Datum erkannt wird "automatisch" konvertiert.
Ich habe es bereits auch mit IstZahl(Finden) probiert aber da bräuchte ich eine verschachtelte Version damit Excel prüft welcher Monat und welches Jahr es ist.
Ich glaube der Knackpunkt ist, dass die Angaben keine Tagesangaben besitzen und er die Sprache nicht erkennt. Könnt Ihr mir weiterhelfen?
Vielen Dank!

20
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Datum als Text
03.05.2019 10:11:38
{Boris}
Hi,
lad mal eine Datei mit ein paar Beispieldaten hoch.
VG, Boris
AW: Datum als Text
03.05.2019 10:35:24
{Boris}
Hi,
die Formelverkürzer werden sicher gleich noch kommen - aber für den Moment in H2 (und runterkopieren):
=WENN(ISTZAHL(B2);B2;--TEXT("1."&VERGLEICH(LINKS(B2;FINDEN(" ";B2)-1);{"January";"February";"March"; "April";"May";"June";"July";"August";"September";"October";"November";"December"};)&"."&RECHTS(B2;4); "TT.MM.JJJJ"))
Das Trennen ersparst Du Dir dann. Demnach funzt das nicht für die in der Beispieldatei bereits getrennten Datümer.
VG, Boris
Anzeige
AW: Datum als Text
03.05.2019 10:53:27
Mangoon
Moin Boris,
besten Dank für die schnelle Antwort, funktioniert super . Da hätte ich mir ne Menge Arbeit sparen können aber somit habe ich immerhin Excel besser kennen gelernt.
Dank dir!
VG Niklas
AW: Datum als Text
03.05.2019 11:04:55
Mangoon
Hey Boris,
vllt nochmal eine kleine Anmerkung meinerseits. Eigentlich kommen in den Daten keine Tage vor, ich habe die nur verwendet damit ein Datum dabei heraus kommt und habe kurz versucht deine Formel entsprechend anzupassen, da ich keine Tage im Ergebnis brauche (ja über Format könnte ich es ausblenden aber das ist nicht das Ziel)
=WENN(ISTZAHL(B2);B2;--TEXT(VERGLEICH(LINKS(B2;FINDEN(" ";B2)-1);{"January";"February";"March"; "April";"May";"June";"July";"August";"September";"October";"November";"December"};)&"."&RECHTS(B2;4); "MMM JJ"))
Natürlich kommt nicht das heraus, was ich erhofft hatte. Hast du noch nen Tipp?
Anzeige
AW: Datum als Text
03.05.2019 12:12:17
{Boris}
Hi,
ist halt die Frage, was Du am Ende als Ergebnis haben möchtest: Datum oder Text.
Ich habe es so verstanden, dass Du ein Datum haben möchtest - und ein Datum enthält halt immer die Angaben Tag, Monat und Jahr. Über das Zellformat kannst Du das dann entsprechend in der Ansicht auf Deine Wünsche anpassen.
VG, Boris
AW: wenn Datumsangabe beliebig ...
03.05.2019 10:33:48
neopa
Hallo,
... also engl. oder auch deutsche Monatsbezeichnung, mit oder ohne Jahreszahl oder auch Exceldatumswert, dann z.B. mit folgender Formel für die Angabe in B1:

=WENNFEHLER((WECHSELN(WECHSELN(WECHSELN(WECHSELN(WECHSELN(WECHSELN(WECHSELN(B1;"ct";"kt");"c";"z");
"y";"i");"arzh";"ärz");"ari";"ar");"ne";"ni");"Mar";"Mrz")&WENN(ISTZAHL(RECHTS(B1;1)+0);"";
JAHR(HEUTE())))+0;"keine Datumsangabe")

Gruß Werner
.. , - ...
Anzeige
AW: sorry, war natürlich f. Mangoon vorgesehen owT
03.05.2019 10:35:21
neopa
Gruß Werner
.. , - ...
AW: Monatsangabe kann auch lang oder kurz sein owT
03.05.2019 10:39:18
neopa
Gruß Werner
.. , - ...
AW: Monatsangabe kann auch lang oder kurz sein owT
03.05.2019 10:55:44
Mangoon
Moin Werner,
vielen Dank auch deine Formel funktioniert prächtig.
Immer wieder erstaunt was Excel alles kann, wenn man Excel kann!
VG
Niklas
AW: Monatsangabe kann auch lang oder kurz sein owT
03.05.2019 13:11:31
Günther
Moin Niklas,
erst einmal von Herzen: Meine Hochachtung, du bist einer der wenigen Fragesteller, die sich wirklich Mühe gegeben habe, zu einem Ziel zu kommen! - Und Excel kann noch mehr, wenn du die vorhandenen Möglichkeiten nutzt… ;-)
Mit Power Query, ganz ohne Formel und wenigen Mausklicks: -> siehe hier: http://www.excel-ist-sexy.de/power-query-quickies-datum-zeit-us-de/
Muster-Lösung auf Nachfrage -> per PM/E-Mail oder in meiner Cloud, da ich meine Ordner-Struktur nicht wegen eines Forums umstelle ... => https://my.hidrive.com/lnk/tRgmDOV1
Gruß
Günther
Anzeige
AW: etwas genauer genommen ...
03.05.2019 14:25:27
neopa
Hallo Niklas,
... müsste in meiner Formel +0 ersetzt werden durch /(B1"") damit für evtl Leerzellen kein Datumswert ausgegeben wird.
Und wenn es nur engl. Monatsangaben sind und diese immer nur in Kurz- oder nur in Langform angegeben sind, kann man eine erheblich kürzer Formel definieren. Aber ich hatte bei Deiner Fragestellung bewusst eine allgemeinere Lösungsformel angestrebt.
Gruß Werner
.. , - ...
Einer geht noch...
03.05.2019 15:20:11
EtoPHG
Hallo,
z.B.
=DATUM(RECHTS(B1;4);FINDEN(TEIL(B1;2;2);" anebarprayunulugepctovec")/2;1)

Gruess Hansueli
Anzeige
AW: der Formelteil ist (mir) bekannt, jedoch ...
03.05.2019 17:34:07
neopa
Hallo Hansueli,
... kann man Deine Formel in dieser konkreten Definition (hab ich meiner Erinnerung nach als genau so gekürzte Variante vor längerer Zeit mal aus einer mE von Rudi eingestellten Formel abgeleitet) nur anwenden, wenn eine Jahreszahlangabe in vierstelliger Form auch wirklich vorliegt. Dies ist aber aus der Eingangsfragestellung so nicht erkennbar.
Gruß Werner
.. , - ...
Abwandlung auf 2 Jahrestellen...
03.05.2019 17:57:20
EtoPHG
ist ja ein Klacks, Werner
=DATUM(RECHTS(B1;2)+100;FINDEN(TEIL(B1;2;2);" anebarprayunulugepctovec")/2;1)

...und (p.s. hab die formel ohne Wissen von Rudi's selbst zusammengepfriemelt. Musste nur eine eindeutigen Fingerprint innerhalb englischer Monatsnamen suchen).
Gruess & bis bald in SHA
Hansueli
Anzeige
AW: so noch nicht ganz korrekt, denn ...
03.05.2019 19:04:10
neopa
Hallo Hansueli,
... ganz so einfach ist das nun auch wieder nicht, weil damit aus z.B. 1999 so 2099 wird. Ein kleines bißchen "nachsitzen" ;-) musst Du da schon noch. Aber ein schönes WE wünsche ich Dir trotzdem schon jetzt.
Gruß Werner
.. , - ...
so einfach ist es nicht und doch ist es so...
03.05.2019 22:48:01
EtoPHG
einfach, Werner
denn dieser akademische Disput erübrigt sich, mangels Stellungsnahme des TE.
Schon bezgl. der Anforderung widerspricht er sich, in dem er einmal ein Datum und dann wieder ein Text als Resultat verlangt.
Ich hätte es mir ja auch so einfach wie Du machen können und einfach das laufende Jahr in die Formel einbauen können.
Gruess Hansueli
Anzeige
AW: nun ja, nicht wirklich ...
04.05.2019 10:12:30
neopa
Hallo Hansueli,
... denn ich hatte es mir, wie ich auch geschrieben hatte, bewusst schwieriger gemacht als notwendig. In dem ich eine quasi "zwei Sprachen"-Lösung (die auf der auch für mich nicht ganz eindeutigen Vorgabe fundierte, aber zugegebener Weise wohl niemand braucht) und dies sowohl für Kurz- als auch Lang-Monatsnamen in beiden Sprachen und für 2 oder 4 stelliger Jahresangaben (nach 1900) oder auch für ohne solche Angaben (dann aktuelles Jahr) aufgestellt hatte.
Aber der TE hatte sich da ja schon den Lösungsvorschlag von Boris zugewendet.
Gruß Werner
.. , - ...
TEXT und LandesCodes
03.05.2019 20:02:57
Luc:-?
Seit Jahren sollte die Möglichkeit der Verwendung von Landescodes in der Xl-Fkt TEXT allgemein bekannt sein, Leute (& Mangoon),
nur niemand hat hier davon Gebrauch gemacht! Das sähe dann so aus, wenn man einen Text der Form mmm jj erhalten will …
1. mit singularer MatrixFml:
D2[:D45]:{=TEXT(DATUM(RECHTS(A2;4);VERGLEICH(A2;TEXT(DATUM(RECHTS(A2;4);ZEILE($1:$12);1);"[$-409]MMMM JJJJ");0);1);"MMM JJ")}
2. mit Normal-Fml:
D2[:D45]:=TEXT(DATUM(RECHTS(A2;4);VERGLEICH(A2;INDEX(TEXT(DATUM(RECHTS(A2;4);ZEILE($1:$12);1);"[$-409]MMMM JJJJ");0);0);1);"MMM JJ")
Im 2.Fall erübrigt zusätzlicher INDEX-Einsatz die MatrixFml-Form.
Soll dagg ein echtes (fiktives) Datum (Tageszähler) erstellt wdn, kann das äußere TEXT in den Fmln entfallen und sein FormatArgument direkt als ZellFormatierung verwendet wdn.
Diese Methode hat den Vorteil, dass auch Angaben in anderen Sprachen (als hier Englisch) über ihren jeweiligen Landescode ([$-…]) richtig ins Deutsche übertragen wdn können. Man muss ihn dann nur austauschen. Sind die Original-Monatstexte Kürzel, ist statt MMMM nur MMM zu verwenden. Ist die Jahreszahl nur 2stellig, ist in diesen Fällen nur das 2.Argument von RECHTS gg 2 zu tauschen. Steht die Jahreszahl zuerst, muss statt RECHTS LINKS verwendet und das Vglsformat gedreht wdn.
Gruß, Luc :-?
„Der beste Beweis für intelligentes Leben im Universum ist, dass noch niemand versucht hat, Kontakt mit uns aufzunehmen.“ H.Lesch, 2018, Sonneberg
Deshalb Intelligenz steigern mit …

Anzeige
Bsp für internationalen Gebrauch
04.05.2019 15:16:02
Luc:-?
Userbild
Luc :-?

316 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige