Live-Forum - Die aktuellen Beiträge
Datum
Titel
29.03.2024 13:14:12
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1696to1700
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Alphanumerischen Wert aus Text auslesen

Alphanumerischen Wert aus Text auslesen
07.06.2019 11:25:32
Markus
Hallo liebe Excelfreunde,
ich würde gern einen Wert im Format ala "B1546" aus einem Text auslesen:
Beispiel:
"blablabla 154 blabla C4584 blabla blablabla"
Hier brauche ich "C4584" die einzigen Konstanten sind das Wort beinhaltet immer vier Zahlen und davor steht ein Buchstabe. Es kann davor und danach Text vorkommen und auch Zahlen! Jedoch steht mein gesuchter Wert immer im selben Format und davor und danach kommt ein Leerzeichen.
Gibt es eine Möglichkeit sowas auszulesen?
Danke schonmal und viele Grüße!
Markus

28
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Probiere es mal so...
07.06.2019 11:41:37
Markus
Danke perfekt :)!!!!
AW: alternativ eine Formellösung ...
07.06.2019 11:48:15
neopa
Hallo Markus,
... so:
Arbeitsblatt mit dem Namen 'Tabelle7'
 AB
1"blabla9876 12345 1545b blabla C4584 1234a 98765 blablabla"C4584

ZelleFormel
B1=TEIL(A1;AGGREGAT(15;6;ZEILE(A1:A99)/ISTZAHL((RECHTS(TEIL(A1;ZEILE(A1:A99);7);5)+0)/(LINKS(TEIL(A1;ZEILE(A1:A99);7);1)=" ")/(RECHTS(TEIL(A1;ZEILE(A1:A99);7);1)=" ")/ISTFEHL(TEIL(TEIL(A1;ZEILE(A1:A99);7);2;1)+0));1)+1;5)
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Gruß Werner
.. , - ...
Anzeige
AW: alternativ eine Formellösung ...
07.06.2019 11:50:54
Markus
auch top :) danke euch echt !!
kommt es nicht auch auf den Großbuchstaben an ?
07.06.2019 16:16:51
WF
Hi,
"blabla b2345 1545 blabla C4584 1234a 98765"
ergibt bei Dir b2345 und nicht C4584 ?
WF
AW: war so nicht vorgegeben, aber wenn doch ...
07.06.2019 16:36:37
neopa
Hallo WF,
... so gewünscht sein sollte, dann würde meine Formel nur um eine Bedingung länger, siehe E1.
Mal sehen wie es lupo löst.
Arbeitsblatt mit dem Namen 'AGGR_190607_2'
 ABCDE
1"blabla9876 b1234 1545b blabla C4584 1234a 98765 blablabla"b1234b1234 C4584

ZelleFormel
B1=TEIL(A1;AGGREGAT(15;6;ZEILE(A1:A99)/ISTZAHL((RECHTS(TEIL(A1;ZEILE(A1:A99);7);5)+0)/(LINKS(TEIL(A1;ZEILE(A1:A99);7);1)=" ")/(RECHTS(TEIL(A1;ZEILE(A1:A99);7);1)=" ")/ISTFEHL(TEIL(TEIL(A1;ZEILE(A1:A99);7);2;1)+0));1)+1;5)
C1{=GLÄTTEN(TEIL(WECHSELN(A1;" ";WIEDERHOLEN(" ";99));VERGLEICH(1;(LÄNGE(GLÄTTEN(TEIL(WECHSELN(A1;" ";WIEDERHOLEN(" ";99));SPALTE(A1:Z1)*99-98;99)))=5)*(ISTZAHL(--RECHTS(GLÄTTEN(TEIL(WECHSELN(A1;" ";WIEDERHOLEN(" ";99));SPALTE(A1:Z1)*99-98;99));4)))*(1-ISTZAHL(--LINKS(GLÄTTEN(TEIL(WECHSELN(A1;" ";WIEDERHOLEN(" ";99));SPALTE(A1:Z1)*99-98;99)))));)*99-98;99))}
E1=TEIL(A1;AGGREGAT(15;6;ZEILE(A1:A99)/ISTZAHL((RECHTS(TEIL(A1;ZEILE(A1:A99);7);5)+0)/(LINKS(TEIL(A1;ZEILE(A1:A99);7);1)=" ")/(RECHTS(TEIL(A1;ZEILE(A1:A99);7);1)=" ")/(64CODE(TEIL(TEIL(A1;ZEILE(A1:A99);7);2;1)))/(91>CODE(TEIL(TEIL(A1;ZEILE(A1:A99);7);2;1))));1)+1;5)
Achtung, Matrixformel enthalten!
Die geschweiften Klammern{} werden nicht eingegeben.
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Gruß Werner
.. , - ...
Anzeige
das passt
07.06.2019 17:05:51
WF
.
Passt leider nur bedingt!
07.06.2019 21:48:19
Luc:-?
Tja, Werner & Walter (& Markus);
inzwischen haben wir dank Vorgabe und Fmln 4 verschiedene BspTexte:
Vorgabe: blablabla 154 blabla C4584 blabla blablabla
Werner1: blabla9876 12345 1545b blabla C4584 1234a 98765 blablabla
Text_WF: blabla b2345 1545 blabla C4584 1234a 98765
Werner2: blabla9876 b1234 1545b blabla C4584 1234a 98765 blablabla
Werner, Du hast wohl nicht mit dem originalen VorgabeText gearbeitet, denn der ergibt mit allen AGGREGAT-Fmln #ZAHL!, mit der MatrixFml #NV, wenn man ihn direkt auf A1 kopiert. Nur wenn man ihn in die Zelle kopiert, wdn die in ihm enthaltenen Zeichen160 in Zeichen32 gewandelt (Xl14/2010). Diesen Effekt hatte ich bereits früher schon mal feststellen müssen.
Da im OriginalText sowohl normale als auch scheinbare Leerzeichen enthalten sind, muss wohl davon ausgegangen wdn, dass das auch in den zu bearbeitenden Daten der Fall sein wird oder kann. Damit müsste dann auch Daniels UDF-Fml erweitert wdn, nicht aber meine und für diesen Fall auch nicht die von Case. Allerdings versagt seine bei den anderen 3 Texten, weil der formulierte, fest vorgegebene reguläre Ausdruck wohl nicht ausreichend genug differenziert.
Fazit: Nur mit meiner UDF-Fml liegt eine fertige Lösung vor, die aus allen 4 Texten einen Ausdruck aus 1 GBst und mindestens 4 nach­folgenden Ziffern richtig extrahiert. Sollen es immer genau 4 Ziffern sein, kann man das leicht so einstellen:
=TEIL(A1;VLike(A1;"*[A-Z]####[!0-9]*";-1);5)
Will man den Fehlerwert bei nicht-vorhandenem Vglsbegriff vermeiden, kann man folgende Fml verwenden:
=WENNFEHLER(TEIL(A1;VLike(A1;"*[A-Z]####[!0-9]*";-1);5);"")
Allerdings muss dem Vglsbegriff dann noch mindestens 1 Zeichen folgen, sonst wird er nicht gefunden. Das gilt aber auch für die ande­ren Fmln (außer der von Case), bei denen es ein normales (oder wandelbares) Leerzeichen sein muss. Bei meiner Fml dürfen allerdings keine ungültigen Begriffe direkt am TextAnfang stehen, denn die wdn ggf (gekürzt) als richtig erkannt. Außerdem darf bei allen Fmln nur ein passender Begriff im Text auftreten, sonst wird nur einer (mit VLike der 1. oder der letzte) gefunden.
Eine „normale“ Fml ohne UDF(s) dürfte noch länger wdn, wenn auch dieser Fall noch berücksichtigt wdn muss. In der letzten AGGRE­GAT-Fml kommt 6× A1 vor. Das müsste jedesmal durch WECHSELN(A1;ZEICHEN(160);" ") ersetzt wdn. Dann wäre zumindest dafür eine benannte Fml angesagt. Bei Daniels UDF-Fml wäre das natürlich bequemer zu erreichen, da nur 1× A1 ersetzt wdn müsste, um in allen mittlerweile 10 getesteten Fällen ein richtiges Ergebnis zu erhalten.
Gruß, Luc :-?
Anzeige
AW: sitzt, passt, wackelt und hat Luft! owT
07.06.2019 22:21:01
neopa
Gruß Werner
.. , - ...
Hast du geWECHSELNt, ...
08.06.2019 01:49:15
Luc:-?
…Werner,
oder bist Du bei Deinen Texten, die vom Original abweichen, geblieben? Der OriginalText enthält 3 normale und 2 geschützte Leerzeichen, die sich an den Positionen 21 und 27 befinden. Damit wird bei Heranziehen nur der normalen Leerzeichen der entscheidende TextTeil als größere Einheit behandelt, nämlich blabla C4584 blabla. Das ergibt dann natürlich keinen Treffer.
Hinweis: Kopie nicht in, sondern auf die Zelle kopieren!
Morhn + FroPf, Luc :-?
AW: nein, weil (bei mir) nicht notwendig, ...
08.06.2019 08:33:13
neopa
Hallo Luc,
... weil ich keine "geschützten" Leerzeichen vorgefunden hatte/habe und es solche im Text von Markus gemäß seinen Angaben auch nicht gibt. Natürlich hatte/hab ich auch mit dem Originaltext getestet.
Wieso Du welche vorgefunden hast erschließt sich mir nicht. Offensichtlich hat zumindest Case auch keine solche Zeichen im von ihm (mit großer Wahrscheinlich lediglich) einkopierten Originaltext.
Gruß Werner
.. , - ...
Anzeige
ich kann neopa bestätigen, denn auch bei mir ...
08.06.2019 11:22:07
lupo1
... ergab das Stringkopieren in eine Zelle keine Leerzeichenanomalien.
Ich auch, aber nur mit FF u.MS-Edge, ...
08.06.2019 19:40:39
Luc:-?
…sowie mit G-Chrome beim Einkopieren, Leute;
kopiert man aber den OriginalText aus G-Chrome auf eine Zelle, wdn die Leerzeichen vor und nach der Fettschrift von Xl als geschützte fehlinterpretiert. Das wird wohl daran liegen, dass G-Chrome kein sauberes Standard-HTML verwendet, sondern eine merkwürdige Son­derCodierung, die dann von Xl14/2010 unter Win7 so gedeutet wird.
Das beweist wieder mal, dass bei einigen Anbietern ein Trend um sich greift, internationale Standards zum eigenen Vorteil umzudeuten. Das kann man ja auch immer noch bei Verlaufsfarben sehen, die für jeden Browser etwas unterschiedlich notiert wdn müssen.
Danke Google! :-[
Gruß & FroPf, Luc :-?
Anzeige
meine UDF passt da schon, deine Lösung nicht.
07.06.2019 23:26:21
Daniel
wenn geschützte Leerzeichen vorhanden sind, die wie normale Leerzeichen als Worttrenner betrachtet werden sollen, dann muss man diese eben vorher mit WECHSLEN austauschen, bevor man meine UDF anwendet.
Am der Code der UDF muss man da nichts ändern.
=xxx(wechseln(A1;Zeichen(160);Zeichen(32));"[A-Z]####")
hingegen hat deine Lösung das Problem, dass sie auch Wörter, die aus einem Buchstaben und mehr als 4 Ziffern als Treffer erkennt und zusammen mit dem Text:
"xxx A12345 yyy B1234 zzz C12345 xxx" nicht das korrekte B1234 als Ergebnis ausgibt, sondern C1234!
Da müsstest du nochmal nachbessern.
Gruß Daniel
Anzeige
Den WECHSELN-Vorschlag hatte ich bereits ...
08.06.2019 01:34:32
Luc:-?
…gemacht, Daniel,
auch für deine UDF-Formel, nicht für deine UDF! Dann ist die Trennung bei Leerzeichen sogar günstiger als die Suche im GesamtText.
Dass meine UDF anders sucht und ihre Beschränkungen in einem GesamtText hatte ich ebenfalls erwähnt. Richtig fktioniert sie aber in den 4 vorgestellten Texten (der 1. im Original mit 2 geschützten Leerzeichen an entscheidender Stelle). Die Fml hatte ich deshalb bereits nachgebessert, genauer das 2.Argument von VLike und zusätzlich ein WENNFEHLER für gänzlich fehlende gültige Ausdrücke verwendet. C1234 ergibt nur die alte Fml, die am TextEnde beginnt. Die andere Variante (vom TextAnfang an) käme auf A1234. Mit der neuen Fml ergibt sich aber B1234 und ebenfalls mit ihrer Alternative:
=WENNFEHLER(TEIL(A1;VLike(A1;"*[A-Z]####[!0-9]*";1)-5;5);"")
Da hier ein Zeichen mehr relevant ist, das in die Positionsermittlung des SuchwortEndes eingeht, müssen bei dieser Variante 5 statt sonst 4 Zeichen abgezogen wdn. Das ist natürlich bei der zuvor von mir verwendeten anderen Variante nicht erforderlich, da hier der SuchwortAnfang ermittelt wird. Fehler können dabei nur dann entstehen, wenn am TextAnfang ein ungültiger Ausdruck wie bspw BC1234 steht. Wenn ein gültiger Ausdruck stets durch Zeichen(32) oder (160) eingeschlossen ist, kann man das auch so schreiben:
=WENNFEHLER(TEIL(A1;VLike(" "&A1&" ";"*[ "&ZEICHEN(160)&"][A-Z]####[ "&ZEICHEN(160)&"]*";-1);5);"-") oder …
=WENNFEHLER(TEIL(A1;VLike(" "&A1&" ";"*[ "&ZEICHEN(160)&"][A-Z]####[ "&ZEICHEN(160)&"]*";1)-6;5);"-")
Wobei [ "&ZEICHEN(160)&"] natürlich auch durch [  ] ersetzt wdn kann. Das fktioniert dann auch für führende ungültige und endende gültige Ausdrücke.
Morhn, Luc :-?
Anzeige
AW: Den WECHSELN-Vorschlag hatte ich bereits ...
08.06.2019 11:06:56
Daniel
Sorry Luc, mein Fehler
aber da siehst du mal, wie deine Abkürzerei zu verwirrung sorgen kann, wenn du damit Menschen taktierst, die nicht gewoht sind, sowas zu lesen.
zu dem Zeichen 160 Problem könnte man ja auch folgendes einwenden:
wenn in einem Text Zeichen 32 und Zeichen 160 gemischt vorkommen, dann könnte das auch ein Zeichen dafür sein, dass in diesem Fall das Zeichen 160 tatsächliche Funktion wahrnimmt, nämlich anzuzeigen, dass ihr zwar ein Leerzeichen steht, aber keine Worttrennung vorliegt, dh die Zeichenfolge links und rechts des Zeichens 160 gehören zum selben Wort.
Gruß Daniel
Anzeige
Ja, das Letztgenannte wäre normal, ...
08.06.2019 19:55:36
Luc:-?
…Daniel;
allerdings hat sich nun herausgestellt, dass das ein Xl-Interpretationsfehler war. Offensichtlich kann Xl nicht jeden BrowserCode in jedem Fall richtig übersetzen, wofür hier primär wohl Google verantwortlich zu machen wäre. Man kann sich also kaum mehr darauf ver­lassen, dass eine einfache TextKopie aus dem Internet in jedem Fall richtig in ein anderes Medium übertragen wird. Das ist doch irre und konterkariert sämtliche Standardisierungsbemühungen!
Übrigens, meine Abkürzungen bist du doch inzwischen gewohnt, sind doch immer die gleichen. Oder… ;-]
FroPf, Luc :-?
Anzeige
AW: Ja, das Letztgenannte wäre normal, ...
09.06.2019 01:13:19
Daniel
Da sonst keiner so schreibt, sehe ich auch keinen Anlass, mich daran zu gewöhnen.
UDF ist ja noch üblich, aber wenn man "Formel" meint, gibt es keinen notwendigen Grund, nicht auch "Formel" zuschreiben. So bin ich halt davon ausgegangen, dass du eben UDF meinst, sonst hättest du ja geschrieben, dass die Formel geändert werden muss.
was die Zeichen 160 angeht, so ist ja immer auch damit zu rechnen, dass jemand die Beispieltexte nicht kopiert, sondern einfach abschreibt (oder selber ähnliche Texte zum Testen entwirft), dann spielt der Browser überhaupt keine Rolle.
Gruß Daniel
Zum Letzten
09.06.2019 11:11:09
Luc:-?
Deshalb zeigt G-Chrome wohl auch nicht einfach das DOM an wie bspw FF. Was ggf angezeigt wird, sieht aus wie die SuchAnfragen­Dar­stellung (voller %-Zeichen), wenn man sie woanders hin kopiert.
Was Fml und UDF betrifft, ist die Verwendung von Ausdrücken als Argument bei (alten) Xl-Fktt und meinen UDFs Standard, sofern nicht zwingend auf Bereiche eingeschränkt wdn muss. Ein Datentyp String bedeutet dagg nur Einschränkung auf einen Einzelwert, der ja auch aus einem Ausdruck ermittelt wdn könnte. So etwas sehe ich natürlich, zumal ja meist unnötigerweise auf Range eingeschränkt wird.
Luc :-?
Hier lupo1 (Änderung Großbuchstaben)
08.06.2019 11:33:53
lupo1
aus
=
GLÄTTEN(TEIL(WECHSELN(A1;" ";WIEDERHOLEN(" ";99));VERGLEICH(1;(LÄNGE(
GLÄTTEN(TEIL(WECHSELN(A1;" ";WIEDERHOLEN(" ";99));SPALTE(A1:Z1)*99-98;99)))=5)*(ISTZAHL(--RECHTS(
GLÄTTEN(TEIL(WECHSELN(A1;" ";WIEDERHOLEN(" ";99));SPALTE(A1:Z1)*99-98;99));4)))*(1-ISTZAHL(--LINKS(
GLÄTTEN(TEIL(WECHSELN(A1;" ";WIEDERHOLEN(" ";99));SPALTE(A1:Z1)*99-98;99)))));)*99-98;99))

wird
=
GLÄTTEN(TEIL(WECHSELN(A1;" ";WIEDERHOLEN(" ";99));VERGLEICH(1;(LÄNGE(
GLÄTTEN(TEIL(WECHSELN(A1;" ";WIEDERHOLEN(" ";99));SPALTE(A1:Z1)*99-98;99)))=5)*(ISTZAHL(--RECHTS(
GLÄTTEN(TEIL(WECHSELN(A1;" ";WIEDERHOLEN(" ";99));SPALTE(A1:Z1)*99-98;99));4)))*(ABS(CODE(
GLÄTTEN(TEIL(WECHSELN(A1;" ";WIEDERHOLEN(" ";99));SPALTE(A1:Z1)*99-98;99)))-77,5)&lt13);)*99-98;99))
Die Änderung auf xx kann man leicht selbst machen, da ich den Ersetzungsteil immer nach dem Umbruch in der Formel habe.
Anmerkung: Vorher waren sowohl bei neopa als auch bei mir statt eines Groß- oder Kleinbuchstabens auch andere Nichtzahlen möglich.
AW: hier muss man "um die Ecke denken" können owT
08.06.2019 12:20:52
neopa
Gruß Werner
.. , - ...
Intervallnormierung mache ich seit 2007 :-)
08.06.2019 13:43:10
lupo1
http://xxcl.de/0058.htm
Genau hier kann man ihren Nutzen erkennen, da der lange Vergleichausdruck nur einmal statt zweimal nötig ist.
Klassische Matrixformel (ab xl2007): 204 Zeichen
08.06.2019 16:25:16
lupo1
B1: {=TEIL(A1;1/MAX(WENNFEHLER((
TEIL(" "&A1;ZEILE($1:$99);1)=" ")*(
TEIL(A1&" ";ZEILE($1:$99)+5;1)=" ")*(ABS(CODE(
TEIL(A1;ZEILE($1:$99);1))-77,5)&lt13)*ISTZAHL(-
TEIL(A1;ZEILE($1:$99)+1;4))/ZEILE($1:$99);));5)
}
(in Excel 365 jedoch kein Matrixformelabschluss nötig)
neopa's Formel: 265 Zeichen
AW: Alphanumerischen Wert aus Text auslesen
07.06.2019 12:10:35
Daniel
Hi
bei VBA gut auch so, falls RegEx nicht bekannt ist:
Function xxx(Txt as string, SuchWert as string) as string
dim Erg
for each Erg in Split(txt, " ")
if Erg like Suchwert then
xxx = Erg
Exit function
end if
next
End Sub
in der Formel dann: =xxx(A1;"[A-Z]####")
oder auch: =xxx(A1;"?####")

(# ist bei LIKE der Platzhalter für eine Ziffer)
hat den Vorteil, dass du hier die Suche über die Formel anpassen kannst, ohne in den Code eingreifen zu müssen.
Außerdem finde die Definition des Suchbegriffs für LIKE etwas einfacher verständlich als für RegEx.
Gruß Daniel
AW: Alphanumerischen Wert aus Text auslesen
07.06.2019 12:44:53
Markus
Hi Daniel,
auch praktisch Danke dir :)
vG
Noch'n Gedicht (Formel auch vor xl2010)
07.06.2019 13:08:31
lupo1
B1: =
GLÄTTEN(TEIL(WECHSELN(A1;" ";WIEDERHOLEN(" ";99));VERGLEICH(1;(LÄNGE(
GLÄTTEN(TEIL(WECHSELN(A1;" ";WIEDERHOLEN(" ";99));SPALTE(A1:Z1)*99-98;99)))=5)*(ISTZAHL(--RECHTS(
GLÄTTEN(TEIL(WECHSELN(A1;" ";WIEDERHOLEN(" ";99));SPALTE(A1:Z1)*99-98;99));4)))*(1-ISTZAHL(--LINKS(
GLÄTTEN(TEIL(WECHSELN(A1;" ";WIEDERHOLEN(" ";99));SPALTE(A1:Z1)*99-98;99)))));)*99-98;99))

________________________________________________________________________
lässt sich mit benannter Formel in B1:
xx: =GLÄTTEN(TEIL(WECHSELN(A1;" ";WIEDERHOLEN(" ";99));SPALTE(A1:Z1)*99-98;99))
auch als
=GLÄTTEN(TEIL(WECHSELN(A1;" ";WIEDERHOLEN(" ";99));VERGLEICH(1;(LÄNGE(xx)=5)*(ISTZAHL(--RECHTS(xx;4)))*(1-ISTZAHL(--LINKS(xx)));)*99-98;99))
abkürzen. Dies ist für xl2003- sogar nötig (nur 8 Ebenen für Funktionen).
Achtung: Da ich nur noch xl365 verwende, hier noch die Anmerkung, dass in älteren xl-Versionen um den Suchbereich von VERGLEICH herum ein INDEX(...;) notwendig sein kann/wird. Oder die Eingabe als Matrixformel.
Deine Fml liefert die gleichen Ergebnisse ...
08.06.2019 02:13:45
Luc:-?
…wie Werners 1.Fml, Lupo;
das würde für das OriginalBsp bei Dir aber #NV ergeben.
Lies bitte mal oben nach!
Morhn + FroPf, Luc :-?
Noch'ne UDF (multi-usable), ...
07.06.2019 15:10:14
Luc:-?
…Markus,
in folgender Fml: =TEIL(A1;VLike(A1;"*[A-Z]####*";-1);5) für A1=auszuwertenderText
Die UDF VLike ergibt mit nur den ersten 2 Argumenten stets WAHR oder FALSCH, mit wie hier allen 3 entweder die Anfangsposition (-1 → von hinten gesucht) oder die Endposition des Suchtextes (1 → von vorne gesucht).
Die UDF befindet sich schon seit Jahren im hiesigen Archiv:
VLike (Vs1.2 o.VPairs) https://www.herber.de/cgi-bin/callthread.pl?index=1247144#1247699
Gruß, Luc :-?
„Der beste Beweis für intelligentes Leben im Universum ist, dass noch niemand versucht hat, Kontakt mit uns aufzunehmen.“ H.Lesch, 2018, Sonneberg
Deshalb Intelligenz steigern mit …

321 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige